Синхронный load XML

[milDude]

class Class1
{
	function selectedChannels():Array
	{

		var flooring:XML = new XML();
 
		flooring.onLoad = function(success)
		{
			// обработка массива "a"
		     return(a);	
		}
		
		flooring.load("bla.xml");	
	}
}

import Class1;

var a:Class1 = new Class1();
var b:Array = new Array();

b = a.selectedChannels();

Мне _etc уже успел объяснить что ActionScript работает асинхронно. Я понимаю почему вышеприведённый код не работает, но я не знаю как эту задачу в итоге реализовать.


Желательно конечно изменить класс, а не основной код.

[etc]

Надо изменить свой собственный подход к решению задачи, а не идти по заранее гиблому пути.
В приведенном варианте задача решения не имеет, такое невозможно во Flash.

[milDude]

Сообщение от __etc

Надо изменить свой собственный подход к решению задачи, а не идти по заранее гиблому пути.
В приведенном варианте задача решения не имеет, такое невозможно во Flash.

Каким тогда путём идти? Желательно чтобы код оставался ясным.

[Eric Gurt]

я пробывал грузить сразу 10 хмл в чате, и в результате получались странные коллизии - чиался один файл, а возвращалось содержимое другого.
Я решил эту проблему, запрашивая рнр файл, который склеивал несколько хмл-ек и возвращал результат.

[etc]

Отказаться от синхронности.
Выполнять действия по событиям.

[milDude]

Получается, что классы для загрузки данных сделать не получится?

[etc]

Получится. Используя все ту же событийную модель.

[milDude]

Сообщение от __etc

Получится. Используя все ту же событийную модель.

Не можете привести коротенький пример. Никак не укладывается как это можно сделать. То есть я понимаю, что такое события, делегаты там итырым ... но как это можно инкапсулировать в класс?

Сообщение от Eric Gurt

я не пойму, в чем заключается необходимость синхронной загрузки хмл?

А как я буду работать с данными, которые ещё не пришли? Ну понятно, что через onLoad. Только ведь некрасиво у меня получается. Может у кого получается красиво.

[lowka]

Сообщение от milDude

... но как это можно инкапсулировать в класс?

Подойдет?

import mx.events.EventDispatcher;
import mx.utils.Delegate;

class ChannelsDAO
{
	private var _xml:XML;
	
	public var addEventListener:Function;
	public var removeEventListener:Function;
	
	private var dispatchEvent:Function;
	
	public function ChannelsDAO()
	{
		EventDispatcher.initialize(this);
	}
	
	public function getChannels():Void 
	{
		this._xml = new XML();
		this._xml.ignoreWhite = true;
		this._xml.onLoad = Delegate.create(this, this.onLoad);
		this._xml.load("channels.xml");
	}
	
	private function onLoad(success:Boolean)
	{
		if(success)
		{
			var result:Array = this.getChannelsFromXML();
			//вещаем событие.
			//result - полученных данные.
			this.dispatchEvent({type:"onResult", result: result})
		}else
		{
			this.dispatchEvent({type:"onFault"})
		}
	}
	
	private function getChannelsFromXML():Array 
	{
		var channels:Array = []
		
		//здесь извлекаем данные из загруженного xml-документа.

		return channels;
	}
}

Проверка

import mx.utils.Delegate;

class ChannelsDAOTest
{
	private var _model:Model;
	private var _dao:ChannelsDAO;
	
	public function ChannelsDAOTest()
	{
		
	}
	
	public function run():Void 
	{
		this._model = new Model();
		this._dao = new ChannelsDAO();
		
		this._dao.getChannels();
		this._dao.addEventListener("onResult", Delegate.create(this, this.resultHandler));
	}
	
	private function resultHandler(event:Object):Void 
	{
		this._model.channels = event.result;
	}
}

[Eric Gurt]

я не пойму, в чем заключается необходимость синхронной загрузки хмл?