Прелоудер для внешней SWF

[Firekeeper]

Здравствуйте уважаемые флеш-программисты. У меня небольшой вопросик.
Есть свф файл, назову его «главная свфка» у этой «главной свфки» есть прелоудер
Ну вобщем не сложный и понятный :
На первом кадре

_root.zagruzheno=int(i)+"%"; \\ _root.zagruzheno – это имя динамического текста выражаемого в процентах так же как и _root.vsego 
_root.vsego=_root.getBytesTotal();
i = ((_root.getBytesLoaded()/_root.getBytesTotal())*100)
_root.Load._width = 3*i;

и предположим на 4 кадре стоит код

if (_root.getBytesLoaded()<>_root.getBytesTotal()) {
	gotoAndPlay(1);
} else {
	gotoAndStop(5);
}

тоже вроде все понятно и ясно. Так вот ставлю симуляцию загрузки все нормально загружается весь файл.. Если выложить в Интернет тоже все в порядке прелоудер работает.
Так вот дальше по ходу проигрывания «главной свфки» есть момент когда в нее подгружается другая свфка. Тоже вроде ничего сложного, я создал мувик с именем menu1
И скриптик

menu1.loadMovie("menu1.swf");

Проблема заключается в следующем, в подгружаемо свфке стоит такойже прелоудер как и в главно свфке, но в Интернете прелоудер подгружаемой свфки не работает.
Подскажите пожалуйста какой скрипт должен быть в подгружаемой свфке?
Или прелоудер для подгружаемой свфки должен лежать в главной свфке? Если да, то как должен выглядеть такой скриптик?
Заранее огромное спасибо

[AlexDesinger]

прелоадер должен быть в том файле, куда вы подгружаете мувик.
Если вы публикуете свай файл для плеера версии 7.0 или выше используйте метод MovieClipLoadeer с помощью него ваш лоадер будет отображать проценты более адекватно.

Пример из хелпа

//create clips to hold your content
this.createEmptyMovieClip("progressBar_mc", 0);
progressBar_mc.createEmptyMovieClip("bar_mc", 1);
progressBar_mc.createEmptyMovieClip("stroke_mc", 2);
//use drawing methods to create a progress bar
with (progressBar_mc.stroke_mc) {
   lineStyle(0, 0x000000);
   moveTo(0, 0);
   lineTo(100, 0);
   lineTo(100, 10);
   lineTo(0, 10);
   lineTo(0, 0);
}
with (progressBar_mc.bar_mc) {
   beginFill(0xFF0000, 100);
   moveTo(0, 0);
   lineTo(100, 0);
   lineTo(100, 10);
   lineTo(0, 10);
   lineTo(0, 0);
   endFill();
   _xscale = 0;
}
progressBar_mc._x = 2;
progressBar_mc._y = 2;
// load progress
var mclListener:Object = new Object();
mclListener.onLoadStart = function(target_mc:MovieClip) {
   progressBar_mc.bar_mc._xscale = 0;
};
mclListener.onLoadProgress = function(target_mc:MovieClip, bytesLoaded:Number, bytesTotal:Number) {
   progressBar_mc.bar_mc._xscale = Math.round(bytesLoaded/bytesTotal*100);
};
mclListener.onLoadComplete = function(target_mc:MovieClip) {
   progressBar_mc.removeMovieClip();
};
mclListener.onLoadInit = function(target_mc:MovieClip) {
   target_mc._height = 500;
   target_mc._width = 700;
};
//Create a clip to hold the image.
this.createEmptyMovieClip("image_mc", 100);
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
/* Load the image into the clip.
You can change the following URL to a SWF or another image file. */
image_mcl.loadClip("http://www.helpexamples.com/flash/images/gallery1/images/pic3.jpg", image_mc);

[Firekeeper]

спасибо =) сейчас попробую