в Tween.onMotionFinished не видно переменную из самого твина

[hamstress]

Код класса (AS2):

import mx.transitions.Tween;
import mx.transitions.easing.*;

class Character {

	var currMc:MovieClip;
	var beginScale:Number;
	var TweenX:Tween;

	function Character(mc:MovieClip,x:Number, y:Number, scale:Number) {
		currMc = mc;
		trace("currMc: "+currMc);
		currMc._x = x;
		currMc._y = y;
		beginScale = scale;
		currMc._xscale = currMc._yscale=beginScale;
		inTweens();
	}

	function inTweens() {
		TweenX = new Tween(currMc, "_x", None.easeNone, currMc._x, currMc._x+40, 2, true);
		TweenX.onMotionFinished = function() {
			trace("currMc: "+currMc);
		};
	}
}

Экземпляр:

this.createEmptyMovieClip("characters_mc",this.getNextHighestDepth());
characters_mc.attachMovie("smokeFish","smokeFish",characters_mc.getNextHighestDepth());
var fish:Character = new Character(characters_mc.smokeFish,200, 200, 100);

в последнем

trace("currMc: "+currMc);

в коде класса выводит undefined, хотя твин первый раз срабатывает корректно.

Не могу понять почему.
если писать просто без класса. напрямую указывая MovieClip, к которому применяется Tween, работает корректно

Спасибо

[in4core]

Я тему все не прочел. Но по классу вы должны использовать Делегат чтобы было видно CurMc

import mx.transitions.Tween;
import mx.transitions.easing.*;
 
class Character {
 
	var currMc:MovieClip;
	var beginScale:Number;
	var TweenX:Tween;
 
	function Character(mc:MovieClip,x:Number, y:Number, scale:Number) {
		currMc = mc;
		trace("currMc: "+currMc);
		currMc._x = x;
		currMc._y = y;
		beginScale = scale;
		currMc._xscale = currMc._yscale=beginScale;
		setTimeOut(mx.utils.Delegate.create(this,inTweens),10);
	}
 
	function inTweens() {
		TweenX = new Tween(currMc, "_x", None.easeNone, currMc._x, currMc._x+40, 2, true);
		TweenX.onMotionFinished = function() {
			trace("currMc: "+currMc);
		};
	}
}

Не обещаю что прокатит, просто я не помню как подгружать делагт класс без всего

[udaaff]

import mx.transitions.Tween;
import mx.transitions.easing.*;
import mx.utils.Delegate;
 
class Character
{
 
	private var currMc:MovieClip;
	private var beginScale:Number;
	private var tweenX:Tween;
 
	public function Character(mc:MovieClip, x:Number, y:Number, scale:Number)
	{
		currMc = mc;
		trace("currMc: " + currMc);
		currMc._x = x;
		currMc._y = y;
		beginScale = scale;
		currMc._xscale = beginScale;
		currMc._yscale = beginScale;
		inTweens();
	}
 
	private function inTweens():Void
	{
		tweenX = new Tween(currMc, "_x", None.easeNone, currMc._x, currMc._x + 40, 2, true);
		tweenX.onMotionFinished = Delegate.create(this, onMotionFinishedHandler);
	}
 
	private function onMotionFinishedHandler():Void
	{
		trace("currMc: " + currMc);
	}
}

[in4core]

Во удаф это все понятно! А как запустит делагат подругому можно? Типа просто mx.utils.Delegate.create(this,f) разве нельзя ? Или тока сославшись на новую функцию, от внтурненнй можно?

[udaaff]

Типа просто mx.utils.Delegate.create(this,f) разве нельзя ?

Можно и так конечно. Просто полное имя класса обычно пишется для того, чтобы точно указать на класс, например, когда существует еще один класс с таким же именем, но в другом пакете.

Или тока сославшись на новую функцию, от внтурненнй можно?

Этот вопрос не понял.

[in4core]

Не !
Ты не понял. Я имел ввиду другой вопрос

public function Character(mc:MovieClip, x:Number, y:Number, scale:Number)
	{
		currMc = mc;
		trace("currMc: " + currMc);
		currMc._x = x;
		currMc._y = y;
		beginScale = scale;
		currMc._xscale = beginScale;
		currMc._yscale = beginScale;
		mx.utils.Delegate.create(this,inTweens);
	}

Вот что я имел ввиду, как таким образом можно запустить!

[udaaff]

Тут без разницы, что с делегатом, что без делегата, метод inTweens() вызывается в области видимости объекта Character. А вложенная функция вызывается в области видимости TweenX, поэтому и currMc flash ищет в TweenX. Поэтому не годится такой вариант.

[in4core]

Ну вот именно это я и спрашивал, как типа такое сделать можно без родительской функции

[hamstress]

Спасибо огромное.
Сама бы не нашла ответ