localconnection для одной флэшки

[Jex]

Здравствуйте!
На одной странице подгружаются несколько одинаковых флешек с проигрывателем музыки. Для каждой из флешек с помощью flashvars передаются ссылки на треки. После окончания проигрывания трека на одной из флешкек должен начать проигрываться трек на другой.
Я сейчас пытаюсь с помощью localconnection просто включить трек, но увы.

var channel:SoundChannel = new SoundChannel();
var vol:SoundTransform = new SoundTransform(0, 0);
var sound:Sound = new Sound(new URLRequest(track_url));
 
var receiving_lc:LocalConnection = new LocalConnection();
receiving_lc.connect("lc_name");
function play_next():void
{
	channel = sound.play(0, 1, vol);
}
 
play_button.addEventListener (MouseEvent.MOUSE_DOWN, onPlayButton);
function onPlayButton (event:MouseEvent):void
{
	var sending_lc:LocalConnection = new LocalConnection();
	sending_lc.send("lc_name", "play_next");
}

Кто-нибудь сталкивался с подобной задачей?

[Цветкофф]

var channel:SoundChannel = new SoundChannel();
var vol:SoundTransform = new SoundTransform(0, 0);
var sound:Sound = new Sound(new URLRequest(track_url));
 
var receiving_lc:LocalConnection = new LocalConnection();
receiving_lc.connect("lc_name");
receiving_lc.play_next = function():void
{
	channel = sound.play(0, 1, vol);
}
 
play_button.addEventListener (MouseEvent.MOUSE_DOWN, onPlayButton);
function onPlayButton (event:MouseEvent):void
{
	var sending_lc:LocalConnection = new LocalConnection();
	sending_lc.send("lc_name", "play_next");
}

не проверял, но на мой взгляд так должно работать

[Jex]

Не работает (

[silin]

не очень понятно, что вы пытаетесь делать

receiving_lc.connect("lc_name");

это какбы попытка всех повесить на одно LC
к "lc_name" подсоединится только первая флешка, только она и получит send("lc_name", "play_next"), т.е. походу она сама себе же и шлет
чтобы такое реализовать для нескольких флешек, каждая из них должна подсоединиться к уникальному lc_name, ну и если нужно именно ей скомандовать что-то, то на ее lc_name и слать
уникальные id можно раздать, например, через те же флешварсы, ну и список всех участников тоже..

[Jex]

Дык она даже сама от себя ничего не принимает. Даже если она одна на странице. Мне бы хотелось для начала с этим разобраться)
Можете написать несколько работающих строк?)

[silin]

дык г_вопрос
вот работающий пример, сделай чтоб перестало - будем разбираться

package
{
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
 
 
	public class Main extends Sprite
	{
		private var lc:LocalConnection;
		private var lcName:String = "blabla";
 
		public function Main():void
		{
 
			lc = new LocalConnection();
			lc.client = this;// м.б. в этом дело?
 
 
			try
			{
				lc.connect(lcName);
			}
			catch (err:Error)
			{
				// вторая не сумееет уже
				trace( "err : " + err );
 
			}
			// на клике смотрим
			stage.addEventListener(MouseEvent.CLICK, stage_click);
		}
 
 
		private function stage_click(e:MouseEvent):void
		{
			lc.send(lcName, "lcCommand");
		}
 
		public function lcCommand():void
		{
			// сама себе шлет..
			// точно также пошлет и соседу, если тот подключен, канеш
			trace( "Main.lcCommand" );
 
		}
	}
 
}

[Jex]

lc.client = this;// м.б. в этом дело?

Да, спасибо!) Я не знал.

Делаю чтоб перестало дальше)