Сортировка глубины по диагонали

[Tetraeon]

Облазил весь форум и интернет, но не нашел как отсортировать объекты по координатам x и y одновременно т.е. по диагонали. Вот как я это делаю по оси y:

        public function sortChildrenByY(container:MovieClip):void
		{
			var i:int;
			i = container.numChildren;
			while (i--)
			{
				objArr[i] = container.getChildAt(i);
			}
			objArr.sortOn("y", Array.NUMERIC);
			i = container.numChildren;
			while (i--)
			{
				if (objArr[i] != container.getChildAt(i))
				{
					container.setChildIndex(objArr[i], i);
				}
			}
		}

Что тут можно добавить чтобы получился желаемый результат? (применение сортировка объектов изометрической сетки по вертикали)

[in4core]

for(var i:int = 0; i < container.numChildren; i++)
{
     var mc:DisplayObject = container.getChildAt(i) as DisplayObject;
     arr.push([mc.x,mc.y]);
}

И сортируешь уже по массивам. или по объектам кому как удобно, но лучше вообще вектором делать, там возможностей больше

[silin]

как вариант

public function sortChildrenByXY(container:DisplayObjectContainer):void
{
	var i:int;
	var propArr:Array = [];
	var objArr:Array = [];
	for (i = 0; i < container.numChildren; i++) 
	{
		var obj:DisplayObject = container.getChildAt(i);
		propArr.push(obj.x * obj.x + obj.y * obj.y);
		objArr.push(obj);
	}
	var indxArr:Array =  propArr.sort(Array.NUMERIC | Array.RETURNINDEXEDARRAY);
	for (i = 0; i < indxArr.length; i++)
	{
		container.addChild(objArr[indxArr[i]]);
	}
}

[Tetraeon]

Спасибо большое !
silin ваш вариант подошел.