как во Flash создать ссылку на внешний сайт

[agent008]

Друзья подскажите, как во Flash создать ссылку на внешний сайт

[KiL33]

Обычная ссылка

getURL("http://www.flasher.ru/forum", "_blank", "GET");

Ссылка в ТекстФилде с использованием Стилей

// Создаем текстовый блок и задаем его параметры
this.createTextField("txt", 1, 175, 100, 200, 1);
txt.border = true;
txt.autoSize = true;
txt.multiline = true;
txt.wordWrap = true;
txt.borderColor = 0x333333;
txt.html = true;
// Создаем объект StyleSheet для хранения таблицы стилей
var myStyle:TextField.StyleSheet = new TextField.StyleSheet();
function parse(CSS:String) {
	if (myStyle.parseCSS(CSS)) {
		txt.styleSheet = myStyle;
	}
	else {
		trace("Ошибка при анализе строки CSS: " + CSS);
	}
}
// Переменная для хранения строки со стилем для разметки маркированного списка
var bulletedList:String = "li{font-family:Arial, _sans; font-size:14}";
// Переменная для хранения строки со стилем для разметки гиперссылки
var hyperlink:String = "a:link{color:#000088;text-decoration:Underline} a:hover{color:#0000FF;text-decoration:underline}a:active{color: #0000FF;text-decoration:none}";
// Добавляем стили в таблицу стилей myStyle
parse(bulletedList);
parse(hyperlink);
// Переменные, содержащие фрагменты HTML-текста, предназначенного для вывода
var header = "<p align = 'center'><font face = '_sans' size = '20' color = '#CC3333'><b>Flash-ресурсы</b></font></p>";
var link1 = "<a href= 'http://www.flasher.ru' target = '_blank'>www.flasher.ru</a>";
var link2 = "<a href= 'http://www.flasher.ru' target = '_blank'>www.flasher.ru</a>";
var link3 = "<a href= 'http://www.flasher.ru' target = '_blank'>www.flasher.ru</a>";
var link4 = "<a href= 'http://www.flasher.ru' target = '_blank'>www.flasher.ru</a>";
var link5 = "<a href= 'http://www.flasher.ru' target = '_blank'>www.flasher.ru</a>";
// Вывод отформатированного текста в поле txt
txt.htmlText = header;
for (var i = 1; i < 6; i++) {
	txt.htmlText += "<li>" + this["link" + i]+ "</li>";
}
// Ура!!

[nOobCrafter]

my_button.onPress = function(){
getURL("http://www.any_site.com", "_self");
}

В методе getURL, первым параметром указываем строку - адрес сайта, вторым параметром: строку - целевое окно.
Здесь:
"_self" - текущий фрейм в текущем окне
"_blank " - новое окно
"_parent " - родительский фрейм, по отношению к текущему
"_top " - фрейм самого верхнего уровня, по отношению к текущему.

[agent008]

Что то не помогает. Вот смотрите есть кнопка "Button1", для нее прописываю
on (release) {getURL("http://www.flasher.ru/forum", "_blank", "GET");

}
и ничего не выходит, не переходит по адресу.
Где ошибка подскажите!:

[KiL33]

Все работает.
..возможно, вы код не в кнопку поместили