Как изменить курсор на объекте?

[vvvvvvf]

Доброго времени суток.
Делаю кнопку полностью через AC и возникла такая проблема при наведении на саму кнопку как можно сделать так чтобы курсор мышьки изменялся например на такой как при наведении на ссылку?

Вот код безымянного класса

package {
	import flash.display.*;
	import flash.events.*;
	import Battle.*;
 
	public class Battle extends Sprite {
		public function Battle():void {
			addChild(new BattleButton('Кнопка', 100, 100));
		}
	}
}

Вот код класса BattleButton

package Battle{
	import flash.display.*;
	import flash.events.*;
	import flash.text.*;
 
	public class BattleButton extends Sprite {
		private var rect:Shape = new Shape();
		private var label:TextField;
		private var format:TextFormat;
 
		public function BattleButton(Message:String, MyX:int = 0, MyY:int = 0):void {
			/***********************************/
			// Фон
			/***********************************/
 
			rect.graphics.beginFill(0x36638E, 1);
			rect.graphics.drawRect(0, 0, 95, 20);
			addChild(rect);
 
			/***********************************/
			// Текст
			/***********************************/
 
			configLabel();
			setLabel(Message);
 
			/***********************************/
			// Координаты
			/***********************************/
 
			x = MyX;
			y = MyY;
 
			/***********************************/
			// События
			/***********************************/
 
			addEventListener(MouseEvent.ROLL_OVER, onOver);
			addEventListener(MouseEvent.ROLL_OUT, onOut);
		}
 
		/***********************************/
		// При наведении курсора мышьки изменяется цвет
		/***********************************/
 
		private function onOver(e:MouseEvent):void {
			label.textColor = 0xDAE1E8;
		}
 
		/***********************************/
		// Меняем цвет обратно
		/***********************************/
 
		private function onOut(e:MouseEvent):void {
			label.textColor = 0xFFFFFF;
		}
 
		/***********************************/
		// Добавить текст
		/***********************************/
 
		public function setLabel(str:String):void {
			label.text = str;
		}
 
		/***********************************/
		// Конфигурация текста
		/***********************************/
 
		private function configLabel():void {
			label = new TextField();
			label.autoSize = TextFieldAutoSize.LEFT;
			label.selectable = false;
 
			format = new TextFormat();
			format.font = 'Tahoma';
			format.color = 0xFFFFFF;
			format.size = 11;
 
			label.defaultTextFormat = format;
			addChild(label);
		}
 
	}
}

[Яски]

buttonMode = true;
useHandCursor = true;

[vvvvvvf]

пробовал при наведении на фон все ок но при наведении на TextField курсор снова стоновится стрелкой =((

[BlooDHounD]

mouseChildren = false;

[vvvvvvf]

отлично все работает спасибо =)

такой вопрос а этот mouseChildren какую он функцию делает?

[Lecosson]

Делает объекты, содержащиеся в спрайте, нечувствительными, "прозрачными" для мышки.