Обращение к переменным экземпляра.

[engineer_f_R]

Есть класс А и класс Б. В экземпляре класса А (ЭА) создаются переменные. Как в классе Б обратиться к переменным экземпляра класса А (ЭА)?

[Gaen]

Передать методу Б ссылку на ЭА и обратиться через неё

[engineer_f_R]

А подскажите пожалуйста синтаксис этой беды или где про это почитать.

[Artic]

В экземпляре класса А (ЭА) создаются переменные

как создаются ? если где то в методах то не как

а вобще

package
{
    public class A
    {
         public var someVar:String = "varClassA";
         public function A()
         {
 
         }
     }
}
 
package
{
    public class B
    {
         public function B(linkClassA:A)
         {
               trace(linkClassA.someVar) // "varClassA"
         }
     }
}
 
package
{
    public class Main
    {
         public function Main()
         {
               var classA:A = new A();
               var classB:B = new B(classA);
         }
     }
}

можно через статик сделать

package
{
    public class A
    {
         public static var someVar:String = "varClassA";
         public function A()
         {
 
         }
     }
}
 
package
{
    public class B
    {
         public function B()
         {
               trace(A.someVar) // "varClassA"
         }
     }
}
 
package
{
    public class Main
    {
         public function Main()
         {
               var classB:B = new B();
         }
     }
}

но запомните, что static определяет переменную/функцию, как принадлежащей КЛАССУ ! а не экземпляру

[engineer_f_R]

Я делаю так:

package 
{
	import flash.display.*;
	import flash.events.*;
	public class MainClass extends MovieClip
	{
		public var keyboardControl:KeyboardControl = new KeyboardControl ();
		var hero:HeroBase = new HeroBase();
		var heroM:HeroMove = new HeroMove();
 
		public function MainClass ()
		{
			stage.addChild(keyboardControl);
			keyboardControl.addEvents();
 
			stage.addChild(hero);
			hero.setCoordinates(50,50);
 
			stage.addChild(heroM);
			heroM.addEvents();
		}
}
 
}

package {
	import flash.display.*;
	import flash.ui.*;
	import flash.events.*;
	import flash.events.KeyboardEvent;
 
	public class KeyboardControl extends MovieClip {
 
		public var leftKeyIsDown:Boolean=false;
		public var rightKeyIsDown:Boolean=false;
		public var upKeyIsDown:Boolean=false;
		public var downKeyIsDown:Boolean=false;
		var keyPressed:int;
		var keyReleaseCode:int;
 
		public function KeyboardControl():void {
 
 
		}
 
		public function addEvents(){
			stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressFunction);
			stage.addEventListener(KeyboardEvent.KEY_UP, keyReleaseFunction);
 
		}
 
 
 
		public function keyPressFunction(e:KeyboardEvent):void {
 
			keyPressed=e.keyCode;
 
			if (keyPressed==Keyboard.RIGHT) {
				rightKeyIsDown=true;
			}
			if (keyPressed==Keyboard.LEFT) {
				leftKeyIsDown=true;
			}
			if (keyPressed==Keyboard.UP) {
				upKeyIsDown=true;
			}
			if (keyPressed==Keyboard.DOWN) {
				downKeyIsDown=true;
			}
		}
 
 
		function keyReleaseFunction(e:KeyboardEvent):void {
			keyReleaseCode=e.keyCode;
			if (keyReleaseCode==Keyboard.RIGHT) {
				rightKeyIsDown=false;
			}
			if (keyReleaseCode==Keyboard.LEFT) {
				leftKeyIsDown=false;
			}
			if (keyReleaseCode==Keyboard.UP) {
				upKeyIsDown=false;
			}
			if (keyReleaseCode==Keyboard.DOWN) {
				downKeyIsDown=false;
			}
		}
	}
 
}

package 
{
	import flash.display.*;
	import flash.ui.Keyboard;
	import flash.events.*;
 
	public class HeroMove extends MovieClip
	{
		public function HeroMove()
		{
 
		}
 
		public function addEvents(){
			stage.addEventListener(Event.ENTER_FRAME, everyFrame)
 
		}
 
 
		public function everyFrame(){
 
			if( keyboardControl.leftKeyIsDown){}
			if( keyboardControl.rightKeyIsDown){}
			if( keyboardControl.upKeyIsDown){}
			if( keyboardControl.downKeyIsDown){}
 
		}
 
	}
 
}

и при компиляции мне ругаются что keyboardControl.leftKeyIsDown - неизвестное свойство. Как мне его сделать известным?

[Artic]

package 
{
	import flash.display.*;
	import flash.events.*;
	public class MainClass extends MovieClip
	{
		public var keyboardControl:KeyboardControl = new KeyboardControl ();
		private var hero:HeroBase = new HeroBase();
		private var heroM:HeroMove;
 
		public function MainClass ()
		{
                        heroM  = new HeroMove(keyboardControl);
 
			stage.addChild(keyboardControl);
			keyboardControl.addEvents();
 
			stage.addChild(hero);
			hero.setCoordinates(50,50);
 
			stage.addChild(heroM);
			heroM.addEvents();
		}
}
 
}
 
package 
{
	import flash.display.*;
	import flash.ui.Keyboard;
	import flash.events.*;
 
	public class HeroMove extends MovieClip
	{
                private var keyboardControl:KeyboardControl
		public function HeroMove(kControl:KeyboardControl)
		{
                       keyboardControl = kControl;
		}
 
		public function addEvents(){
			stage.addEventListener(Event.ENTER_FRAME, everyFrame)
 
		}
 
 
		public function everyFrame(){
 
			if( keyboardControl.leftKeyIsDown){}
			if( keyboardControl.rightKeyIsDown){}
			if( keyboardControl.upKeyIsDown){}
			if( keyboardControl.downKeyIsDown){}
 
		}
 
	}
 
}