Указание типа возвращаемых данных у функций

[goodguy]

Неужели? Object динамический.

Не спорю, но, вот тебе пример, когда со звездочкой все нормально сработает, а с Object нет (просто недавно столкнулся с этим, раньше тоже думал, что без разницы):
есть какой-либо интерфейс:

package  
{
	public interface IDisposable {
		function dispose():void;
	}
 
}

класс, реализующий его

package {
	import flash.display.Sprite;
	public class ToDispose extends Sprite implements IDisposable {
 
		public function ToDispose() {}
		public function dispose():void {
			trace("disposal");
		}
	}
}

Ну и, собственно сам тест:

package  
{
	import flash.display.Sprite;
 
	public class ObjectTest extends Sprite
	{
 
		public function ObjectTest() {
 
			var someVal:Object = new ToDispose() as IDisposable;
			someValue	= someVal;
 
		}
		public function set someValue(value:IDisposable):void {
			value.dispose();
		}
	}
}

В этом случае компиляция завершается ошибкой

C:\Users\Konstantin\Flash\DifferentTests\src\ObjectTest.as(11): col: 16 Error: Implicit coercion of a value with static type Object to a possibly unrelated type IDisposable.

Меняем объект на звездочку, и все работает без проблем.

package  
{
	import flash.display.Sprite;
 
	public class ObjectTest extends Sprite
	{
 
		public function ObjectTest() {
 
			var someVal:* = new ToDispose() as IDisposable;
			someValue	= someVal;
 
		}
		public function set someValue(value:IDisposable):void {
			value.dispose();
		}
	}
}

C классами проблем нет, но интерфейсы - другой случай.