[*ОТВЕТ*]Аттач мувика из внешнего swf-файла

[MerlinTwi]

Это не вопрос, это ответ В ActionScript 3.0 появилась возможность, которую очень давно ждали, возможность загрузить произвольный swf-файл и приаттачить в произвольное место мувик из библиотеки (library) этого файла. Возможность-то появилась, вот только метод совсем не очевидный, я провозился больше часа, пока получилось, а в инете нормального примера не нашел. Потому и публикую пример для потомков.

1. Создаем новый flash document под названием "avatars.fla"
2. Создаем в библиотеке новый мквиклип, назовем его "avatar", ставим галочки "Export for ActionScript" и "Export in first frame". Рисуем в мувике что-нибудь жизнеутверждающее
3. Компилим нашу библиотеку, получаем avatars.swf. Теперь задача добыть из этого файла мувик "avatar".
4. Создаем новый flash document под уже привычным названием Test.fla
5. Ставим Document class = Test
6. Пишем следующий скрипт Test.as:

package {
    import flash.display.Sprite;
    import flash.display.Loader; // загрузчик
    import flash.display.LoaderInfo; // инфа о загруженном контенте
    import flash.net.URLRequest; // для создания URL
    import flash.events.*; // всякие события

    public class Test extends Sprite {

        // конструктор
        public function Test() {
            // создаем загрузчик
            var loader:Loader = new Loader();
            // слушаем события о процессе загрузки
            // обратите внимание, нужно добавлять listeners не к 
            // loader а к loader.contentLoaderInfo !
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            // начинаем загрузку файла "avatars.swf"
            loader.load(new URLRequest("avatars.swf"));
        }

        // загрузка завершена
        private function completeHandler(event:Event):void {
            // получим инфу о загруженном контенте
            var info:LoaderInfo = event.target as LoaderInfo;
            // выведем URL загруженного файла для теста
            trace("Ok loaded: " + info.url);
            // пробуем достать нужный нам мувиклип
            // делаем это в блоке try+catch, т.к. нужного 
            // нам мувика там может и не быть (теоретически)
            try {
            	// получаем ссылку на класс нужного мувика
            	// используя LoaderInfo.applicationDomain.getDefinition
            	var a:Class = info.applicationDomain.getDefinition("avatar");
            	// создаем мувик и сразу аттачим к себе
            	addChild( new a() );
            } catch (e:ReferenceError) {
            	// напишем об ошибке, что нужный мувиклип не найден
            	trace('ERROR: '+e);
            }
        }

        // при загрузке файла произошла какая-то ошибка
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ERROR: " + event);
        }
    }
}

7. Все подробно прокомментировано. Осталось запустить Test.fla и проверить результат.

Одна деталь, так можно аттачить только мувиклипы из AS3, если загруженный .swf файл будет версии AS2 или 1, то ничего не получится.

Этот пример в аттаче.