Доступ к основным методам

[dimarik]

Сообщение от winbackgo

при инициализации флэш инициализирует mainApp и где-то ведь хранится ссылка на него.

А Вы создали ссылку на него? Нет ссылки - нет доступа.

про передачу this я думал но тогда привязка класса к mainApp и если потом его использовать в другом проекте то надо переделывать.

Интерфейсы спасают.

Мне вообще это нужно для создания функции дебаг и в классе проверить если она доступна то вызывать.

ApplicationDomain.hasDefinition(value:String):Boolean

А также для доступа к параметрам flashvars через loaderInfo. В mainApp доступно root.loaderInfo.parameters как до них добраться в exampleClass?

Конфигурируте ЕxampleClass необходимыми ему параметрами. Можно в конструктор передавать. а можно сеттить после создания его экземпляра.

package {
 
	import flash.display.Sprite;
 
	public class MainApp extends Sprite implements ITestable {
 
		public function MainApp() {
			super();
 
			var exampleClass:ExampleClass = new ExampleClass();
			var param:uint = parseInt(super.loaderInfo.parameters['param']);
 
			exampleClass.controller = this;
			exampleClass.param = param;
		}
 
		public function test(value:uint):void {
			trace('Tested: ' + value);
		}
	}
}

package {
 
	public class ExampleClass {
 
		public function ExampleClass() {
			super();
		}
 
		//-----------------------------
		//  controller
		//-----------------------------
		private var _controller:	ITestable;
 
		public function set controller(value:ITestable):void {
			if (this._controller == value) return;
			this._controller = value;
		}
 
		public function get controller():ITestable {
			return this._controller;
		}
 
		//-----------------------------
		//  param
		//-----------------------------
		public function set param(value:uint):void {
			if (this._controller) this._controller.test(value);
		}
 
	}
}

package {
 
	public interface ITestable {
		function test():void;
	}
 
}