3d Rotation Menu

mysBer · 28.10.2009, 21:28

Пожалуйста:

Код AS3:

import mx.utils.Delegate;
 
var numOfItems:Number;
var radiusX:Number = 400;
var radiusY:Number = 100;
var centerX:Number = Stage.width/2;
var centerY:Number = Stage.height/2;
var speed:Number = 0.05;
var perspective:Number = 130;
var home:MovieClip = this;
 
var tooltip:MovieClip = this.attachMovie("tooltip", "tooltip", 10000);
tooltip._alpha = 0;
 
var xml:XML = new XML();
xml.ignoreWhite = true;
 
xml.onLoad = function() {
	var nodes = this.firstChild.childNodes;
	numOfItems = nodes.length;
	for (var i = 0; i<numOfItems; i++) {
		var t = home.attachMovie("item", "item"+i, i+1);
		t.angle = i*((Math.PI*2)/numOfItems);
		t.onEnterFrame = mover;
		t.toolText = nodes[i].attributes.tooltip;
		t.icon.inner.loadMovie(nodes[i].attributes.image);
		t.r.inner.loadMovie(nodes[i].attributes.image);
		t.icon.onRollOver = over;
		t.icon.onRollOut = out;
		t.icon.link = nodes[i].attributes.link;
		t.icon.onRelease = function() {
			getURL(this.link, "_self");
		};
	}
};
 
function over() {
	home.tooltip.tipText.text = this._parent.toolText;
	home.tooltip._x = this._parent._x;
	home.tooltip._y = this._parent._y-this._parent._height/2;
	home.tooltip.onEnterFrame = Delegate.create(this, moveTip);
	home.tooltip._alpha = 100;
}
 
function out() {
	delete home.tooltip.onEnterFrame;
	home.tooltip._alpha = 0;
}
 
function moveTip() {
	home.tooltip._x = this._parent._x;
	home.tooltip._y = this._parent._y-this._parent._height/2;
}
 
xml.load("icons.xml");
 
function mover() {
	this._x = Math.cos(this.angle)*radiusX+centerX;
	this._y = Math.sin(this.angle)*radiusY+centerY;
	var s = (this._y-perspective)/(centerY+radiusY-perspective);
	this._xscale = this._yscale=s*100;
	this.angle += this._parent.speed;
	this.swapDepths(Math.round(this._xscale)+100);
}
 
this.onMouseMove = function() {
	speed = (this._xmouse-centerX)/2500;
};

xml документ имеет вид:

Цитата: