Анимация исчезновения

[MikroAcse]

после добавления сетчилдиндекс выскочила ошибка RangeError: Error #2006: The supplied index is out of bounds.

У вас stage должен быть доступным.

[Михаил Свинцов]

всмысле stage должен быть доступен, из-за чего он может быть недоступен

[MikroAcse]

Ты вообще как drawNam вызываешь?

[Михаил Свинцов]

private var drawn = new DrawName();
	drawn.drawNam();

Добавлено через 1 минуту
что-то не так с вызовом?

[Wolsh]

1) У альфы 256 делений (0-255). Изменение на 0.01 делает график неровным, и это заметно глазу. Сделайте константу 1/255.
2) 0.01 секунда это 100 изменений в секунду. Вы собираетесь установить ролику такой fps? Adobe рекомендует ставить таймер не менее 20 ms, то есть 50 fps, но и это обычно многовато и скорее всего приведет к дерганой анимации. updateAfterEvent() тоже не спасет, особенно если в это время будут происходить и другие перерисовки в окне плеера.
3) Рискую начать очередной холивар, но не пойму, при чем тут this? В классе нет ни одного геттера/сеттера и ни одного паблика. Обращение через экземпляр к приватным полям выглядит как-то нелепо и сбивает с толку. Приватные они и есть приватные, ни к каким чужим ("не this.") приватным полям Вам при всем желании не обратиться. Просто "бекоз ай кэн"? Лучше используйте this для обозначения, что обращаетесь к пабликам экземпляра. Приватные переменные удобно обозначать подчерком в начале, как рекомендует конвенция для storage variables геттеров и сеттеров.

[MikroAcse]

private var drawn = new DrawName();
addChild(drawn);
drawn.drawNam();

Казалось бы, такая сложная задача

[Wolsh]

Обалдеть. Пока писал, появилось 13 сообщений.

Добавлено через 32 секунды
14....

[Михаил Свинцов]

а я думал альфа от 0 до 1

[MikroAcse]

а я думал альфа от 0 до 1

Так и есть. Ты просто его не понял.

[КорДум]

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.TimerEvent;
	import flash.text.TextField;
	import flash.utils.Timer;
 
	/**
	 * @author KorDum
	 */
 
	public class Main extends Sprite {
		private const ALPHA_STEP:Number = 0.1;
 
		private var _timer:Timer;
		private var _textField:TextField;
 
		//---------------------------------------------------------------------------
		//
		// CONSTRUCTOR
		//
		//---------------------------------------------------------------------------
 
		public function Main():void {
			addEventListener(Event.ADDED_TO_STAGE, initHandler);
		}
 
 
		//---------------------------------------------------------------------------
		//
		// PRIVATE HANDLERS
		//
		//---------------------------------------------------------------------------
 
		private function initHandler(event:Event = null):void {
			removeEventListener(Event.ADDED_TO_STAGE, initHandler);
 
			_textField = new TextField();
			_textField.text = "text";
 
			addChild(_textField);
 
			_timer = new Timer(100, 10);
			_timer.addEventListener(TimerEvent.TIMER, timer_timerHandler);
			_timer.addEventListener(TimerEvent.TIMER_COMPLETE, timer_timerCompleteHandler);
			_timer.start();
		}
 
 
		private function timer_timerCompleteHandler(event:TimerEvent):void {
			_timer.removeEventListener(TimerEvent.TIMER, timer_timerHandler);
			_timer.removeEventListener(TimerEvent.TIMER_COMPLETE, timer_timerCompleteHandler);
			_timer = null;
 
			removeChild(_textField);
			_textField = null;
		}
 
 
		private function timer_timerHandler(event:TimerEvent):void {
			_textField.alpha -= ALPHA_STEP;
		}
	}
}

Полностью рабочий пример.