Шорох при уменьшении громкости.

[Партизан]

Ну может вам это поможет. У меня прекрасно работает, без щелчков.

package
{
	import com.greensock.TweenMax;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.media.Sound;
	import flash.media.SoundChannel;
	import flash.media.SoundTransform;
	import flash.net.URLRequest;
 
 
	/**
	 * ...
	 * @author Mikhail Klabukov
	 */
	public class BackgroundSound
	{
		static public const SOUND_OFF:String = "soundOff";
		static public const SOUND_ON:String = "soundOn";
		private var sound:Sound;
		private var channel:SoundChannel
		private var played:Boolean = false;
		private var _pos:Number;
		private var st:SoundTransform;
 
		public function BackgroundSound()
		{
			sound = new Sound(new URLRequest('**********soundUrl**********'));
			sound.addEventListener(IOErrorEvent.IO_ERROR, errorSoundLoad)
			channel = sound.play(0, 10000);
			played = true;
			MainControls.self.addEventListener(MainControls.SOUND_SWITCH, switchSound);
		}
 
		private function errorSoundLoad(e:IOErrorEvent):void
		{
			trace(e)
		}
 
		private function switchSound(e:Event):void
		{
			if (TweenMax.isTweening(st))
				return;
			st = channel.soundTransform;
			if (played)
			{
				_pos = channel.position;
				TweenMax.to(st, 2, {volume: 0, onUpdate: function():void
					{
						channel.soundTransform = st;
					}, onComplete: function():void
					{
						channel.stop();
					}});
				played = false
				MainControls.self.dispatchEvent(new Event(SOUND_OFF));
			}
			else
			{
				channel = sound.play(_pos, 10000);
 
				TweenMax.to(st, 3, {volume: 1, onUpdate: function():void
					{
						channel.soundTransform = st;
					}});
				played = true;
				MainControls.self.dispatchEvent(new Event(SOUND_ON));
 
			}
		}
 
	}
 
}

[RedLizard]

Сообщение от Партизан

Ну может вам это поможет. У меня прекрасно работает, без щелчков.

В том то и дело, что щелчки так же есть. Методом научного тыка удалось установить, что щелчки при быстром изменении громкости есть всегда во флеше. Просто на некоторых звуках это заметнее. Пример, берем тот же ютуб, ищем видео где играют на пианино. http://www.youtube.com/watch?v=x9a5u4JzkLg и ползунок громкости резко двигаем вверх-вниз. И получаем тоже самое шуршание что и в моем коде.