CMD из-под air

[MaxP]

При компиляции ошибок нет. Но с двойными слэшами тоже не работает.

import flash.utils.*;
import flash.events.*;
import flash.desktop.*;
import flash.display.*;
import flash.filesystem.*;
 
if(NativeProcess.isSupported){
 
	var process:NativeProcess = new NativeProcess();
	var info:NativeProcessStartupInfo = new NativeProcessStartupInfo();
	var processArg:Vector.<String> = new Vector.<String>();
 
	processArg.push("md", "C:\Users\user\Desktop\test_cmd");
	info.executable = new File("C:/Windows/System32/cmd.exe");
	info.arguments = processArg;
	process.start(info);
 
	process.addEventListener("standardOutputData", onOutput);
	process.addEventListener("standardErrorData", onError);
	function onOutput(event:ProgressEvent):void{
		var process:NativeProcess = event.target as NativeProcess;
		var data:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
		trace(data)
	}
	function onError(event:ProgressEvent):void{
		var process:NativeProcess = event.target as NativeProcess;
		var data:String = process.standardError.readUTFBytes(process.standardError.bytesAvailable);
		trace(data);
	}
 
}else{
    trace('Add <supportedProfiles>extendedDesktop</supportedProfiles> first!');
}

Запустил air-приложения с правами админа. Тоже не работает.

[ShockWave512]

собрал тестовый проект
папку создает через батник без проблем
флешдевелоп, вин10х64
кстати параметры еще можно передавать создавая временный батник и вызывая его из первого

processArg.push("/c"); 
processArg.push("t.bat"); // md Directory
info.executable = File.applicationDirectory.resolvePath("cmd.exe");
info.arguments = processArg;
info.workingDirectory = File.applicationDirectory;
process.start(info);

на всякий случай выставлял админские права adl.exe

[alexcon314]

package 
{
	import flash.desktop.NativeProcess;
	import flash.desktop.NativeProcessStartupInfo;
	import flash.display.Sprite;
	import flash.filesystem.File;
	import flash.events.*;
	/**
	 * ...
	 * @author 
	 */
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
			if(NativeProcess.isSupported){
 
				var info:NativeProcessStartupInfo = new NativeProcessStartupInfo();
					info.executable = new File("C:/Windows/System32/cmd.exe");
 
				var processArg:Vector.<String> = new Vector.<String>();
					processArg.push("/c");
					processArg.push("md");
					processArg.push("d:\\temp\\cmdtest");
					info.arguments = processArg;
 
				var process:NativeProcess = new NativeProcess();
					process.addEventListener("standardOutputData", onOutput);
					process.addEventListener("standardErrorData", onError);
					process.start(info);
 
			}else{
				trace('Add <supportedProfiles>extendedDesktop</supportedProfiles> first!');
			}
		}
		public function onOutput(event:ProgressEvent):void{
			var process:NativeProcess = event.target as NativeProcess;
			var data:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
			trace("out:" + data);
		}
		public function onError(event:ProgressEvent):void{
			var process:NativeProcess = event.target as NativeProcess;
			var data:String = process.standardError.readUTFBytes(process.standardError.bytesAvailable);
			trace("err:" + data);
		}
	}
 
}

и еще раз - умвр.
как положено в onError трейсится ошибка, если что-то не так (правда кракозябрами). В т.ч. и в случае, если путь в исходнике записан без двойных слэшей - ошибка.
С двойными слэшами - тишина и папка создается по месту назначения.

Попробуй с echo:

var processArg:Vector.<String> = new Vector.<String>();
processArg.push("/c");
processArg.push("echo");
processArg.push("cmdtest");
info.arguments = processArg;

будет трейсы в onOutput кидать? у меня кидает.

[MaxP]

Сработало! Просто не хотел писать на диск C... хз почему. Куда угодно еще пишет, а на Ц - нет