Нахождение координат мыши

[badun]

package  
{
	import flash.display.BlendMode;
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.KeyboardEvent;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	
	/**
	* ...
	* @author Oleg Kucherenko
	*/
	public class DrawCurve extends Sprite
	{
		private var newPoint:Point;
		private var anchorPoint:Point;
		private var controlPoint:Point;
		private var dots:Sprite;
		
		public function DrawCurve() 
		{
			graphics.lineStyle(0);
			
			dots = new Sprite();
			addChild(dots);
			
			stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
			
			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
		}
		
		private function onKeyDown(e:KeyboardEvent):void 
		{
			dots.visible = !dots.visible;
		}
		
		private function onMouseDown(e:MouseEvent):void 
		{
			stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
			anchorPoint = new Point(e.localX, e.localY);
			controlPoint = anchorPoint.clone();
			graphics.moveTo(anchorPoint.x, anchorPoint.y);
		}
		
		private function onMouseUp(e:MouseEvent):void 
		{
			stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
		}
		
		private function onMouseMove(e:MouseEvent):void 
		{
			newPoint = new Point(e.localX, e.localY);
			
			// draw dot
			var shape:Shape = new Shape();
			shape.graphics.beginFill(0);
			shape.graphics.drawCircle(0, 0, 2);
			shape.graphics.endFill();
			dots.addChild(shape);
			shape.x = anchorPoint.x;
			shape.y = anchorPoint.y;
			//*/
			
			if (newPoint.subtract(anchorPoint).length > 10) 
			{
				controlPoint = anchorPoint.subtract(controlPoint);
				controlPoint.normalize(newPoint.subtract(anchorPoint).length / 4);
				controlPoint = anchorPoint.add(controlPoint);

				anchorPoint = newPoint;
				graphics.curveTo(controlPoint.x, controlPoint.y, anchorPoint.x, anchorPoint.y);
			}
			
		}
		
	}
	
}

Это пример как рисовать кривые по точкам. Тут на самом деле все не очень хорошо, конкретно вот это место controlPoint.normalize(newPoint.subtract(anchorPoint).length / 4);. Вот эта /4 выбрана эксперементально, т.е. без мозгов )). Изначльно /2 было для правильной гладкости, но там кривые в колебание уходили. Вообще надо рисовать не по точкам, которые мышка выдает. По точкам мыши надо формировать другие точки, которые сглаживают ошибки, а по ним уже кривые рисовать.
У меня с теорией по этой теме туго, но я уверен что в инете подходящей инфы валом, т.к. это не только flash'a касается.