CheckBox в DataGrid

[sangle]

Если же тебе нужно более универсальное решение (в отличие от предыдущего решения, где было известно, что значение хранится в свойстве checked), то вот расширенный пример.

<?xml version="1.0" encoding="utf-8"?>
<mx:Canvas
    xmlns:mx="http://www.adobe.com/2006/mxml"
    implements="mx.controls.listClasses.IDropInListItemRenderer">
<mx:Script>
<![CDATA[
    import mx.controls.dataGridClasses.DataGridListData;
    import mx.controls.listClasses.BaseListData;
    
    override public function set data(value: Object): void {
        if(value != null) {
            super.data = value;
            var fieldName: String = DataGridListData(listData).dataField;
            checkBox.selected = value[fieldName];
        }
    }
    
    private var _listData:BaseListData = null;

    [Bindable(event="dataChange")]
    public function get listData():BaseListData {
        return _listData;
    }
    
    public function set listData (value:BaseListData):void {
        _listData = value;
    }
    
    private function onChange(event: Event): void {
        var fieldName: String = DataGridListData(listData).dataField;
        super.data[fieldName] = checkBox.selected;
    }
]]>
</mx:Script>
    <mx:CheckBox id="checkBox" change="onChange(event)"/>
</mx:Canvas>