Странности с ресайзом

[imdogma]

Всем привет! Решил полностью перейти на AS3, и вот столкнулся с такой проблемой с ресайзом. Собственно, вот код:

package com {
 
	import flash.display.MovieClip;
	import flash.events.*;
	import caurina.transitions.*;
 
	public class prototype extends MovieClip {
 
		var __putContent:MovieClip = new __Content();
 
		public function prototype():void {
 
 
		addChild(__putContent);
 
		__putContent.x = Math.round(stage.stageWidth - __putContent.width)/2;
		__putContent.y = Math.round(stage.stageHeight - __putContent.height)/2;
 
		stage.addEventListener(Event.RESIZE,ResizeItems);
 
		}
 
		private function ResizeItems(e:Event):void {
 
		var __newContentX:Number = Math.round(stage.stageWidth - __putContent.width)/2;
		var __newContentY:Number = Math.round(stage.stageHeight - __putContent.height)/2;
 
		Tweener.addTween(__putContent,{x:__newContentX, y:__newContentY, time:1, transition:"easeOutElastic"});
 
		}
 
	}
 
}

Все работает, да только вот почему то при ресайзе сдвигаемый объект почему-то едет не в центр, а куда то к краю Хотя по той же форумле в АС2 все работало. Помогите пжалуста

[flash33]

Потому что точка регистрации клипа в левом верхнем углу. Ваш __Content должен быть расположен симметрично своему началу координат, тогда и ресайзится будет симметрично

[divinus]

public class Test extends Sprite {
 
		public function Test() {
 
			super.stage.scaleMode = StageScaleMode.NO_SCALE;
			super.stage.align = StageAlign.TOP_LEFT;
 
			this._ball = new Shape();
			with (this._ball.graphics) {
				lineStyle(0, 0, 0);
				beginFill(0);
				drawCircle(50, 50, 50);
				endFill();
			}
			super.addChild(this._ball);
 
			this._ball.x = (super.stage.stageWidth-this._ball.width)>>1;
			this._ball.y = (super.stage.stageHeight-this._ball.height)>>1;
 
			super.stage.addEventListener(Event.RESIZE, this.handler_stageResize);
		}
 
		private var _ball:Shape;
 
		private function handler_stageResize(event:Event):void {
			this._ball.x = (super.stage.stageWidth-this._ball.width)>>1;
			this._ball.y = (super.stage.stageHeight-this._ball.height)>>1;
		}
	}

[imdogma]

super.stage.scaleMode = StageScaleMode.NO_SCALE;
	super.stage.align = StageAlign.TOP_LEFT;

вот что помогло divinus,flash33 спасибо за помощь

[divinus]

imdogma, ну я собственно так и думал...

[iNils]

А кто вас надоумил назвать класс prototype?

[Distorn]

а что, разве prototype в AS3 ключевое слово?
Единственное что с верхнего регистра нужно было называть

[divinus]

Distorn, названия надо давать такие, чтобы через год посмотреть и понять что это за класс. думаю название класса Prototype явно выбивается из этого правила

[BlooDHounD]

к тому же оно псевдоключевое. у любой функции/класса, есть такое свойство.

[imdogma]

Переименовал))