Как удалить ссылку на приемник события

[HardCoder]

Вопрос такой: При использовании следующего кода

			mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {
					trace("warking");
				});
			mc.removeEventListener(Event.ENTER_FRAME, function(e:Event):void {
					trace("warking");
				});

В output все время выводится "warking". Когда использую слабую ссылку и обнуляю обьект

			mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {
					trace("warking");
				}, false, 0, true);
			mc = null;

Все равно в output все время выводится "warking". Почему так? Проблема в том что сборщик мусора все еще не принялся за уничтожение? Или здесь есть нюанс немного по-серьезней?

[ChuwY]

Потому что ты подписываешься на один экземпляр функции, а отписываешься от другого.
Не используй замыканий (вложенных функций). Особенно для обработчиков.

[HardCoder]

Я знаю что их нельзя использовать и никогда так не делаю. Это так - спортивный интерес... Хочу знать, можно ли удалить такой слушатель или нет. И почему, когда делаю так:

mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {trace("warking");}, false, 0, true);
mc = null;

ничего не меняется?

[kseniya]

mc.addEventListener(Event.ENTER_FRAME, mcFunc, false, 0, true);
function mcFunc(e:Event):void {
	trace("warking");
}
mc.removeEventListener(Event.ENTER_FRAME,mcFunc);

[ChuwY]

Кроме прочего -- ты не удалил объект из дисплейлиста.
Если не удалять -- его и GC не подберет, так как ссылка на него все еще останется в паренте.

[HardCoder]

Да я его даже и не добавлял...

package {
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author Tolik
	 */
	public class NewClass extends Sprite{
		private var mc:MovieClip = new MovieClip();
 
		public function NewClass(){
			mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {
					trace("warking");
				}, false, 0, true);
			mc = null;
		}
	}
}

[Psycho Tiger]

Внутри этой функции можно.
Вот мой сниппет, часто пишу его когда надо отписаться после первого триггера события.

if (event) (event.currentTarget as IEventDispatcher).removeEventListener(event.type, arguments.callee);

[derhab]

Сообщение от ChuwY

Кроме прочего -- ты не удалил объект из дисплейлиста.
Как только ты оттуда его удалишь событие энтерфрейма перестанет диспатчиться.

с чего бы это?

[HardCoder]

Нашел еще один вариант:

mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {trace("warking");}, false, 0, true);
mc = null;
System.gc();

[ChuwY]

Сообщение от derhab

с чего бы это?

Моя неправда.
Но если удалить в ту же фазу, что и добавляем, то не будет диспатча.
Меня это всегда сбивает с толку.

Добавлено через 1 минуту

Сообщение от HardCoder

Нашел еще один вариант:

mc.addEventListener(Event.ENTER_FRAME, function(e:Event):void {trace("warking");}, false, 0, true);
mc = null;
System.gc();

Это будет работать только в дебаге, потому не стоит на то полагаться.
К тому же экстренный запуск GC не есть хорошо.