Как передать параметр в фунцию, вызванную addEventListener'ом?

[mickfallout]

можно попробовать сделать так:

package {
	import flash.display.MovieClip;
	import flash.events.*;
	public class Main extends MovieClip {
		private var myArray:Array;			
		public function Main() {
			super();
			myArray = new Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10);			
			var myVar:uint = 4;			
			addEventListener(Event.ENTER_FRAME, function(event:Event):void { traceNumEnterFrame(event, myVar); } );
		}
		public function traceNumEnterFrame(event:Event, myVar:int):void {
			trace(myArray[myVar]);
		}
	}
}

только вроде использование анонимных функций - плохой стиль программирования.

[MidnightOne]

Сколько людей уже задавались этим вопросом!

Есть ещё одно решение, оно "как бы" не через задний проход.
создать функцию, которая потом будет вызывать нужную уже с параметрами, и вписать её в ивент лисенер.

addEventListener(MouseEvent.CLICK, BlablaCaller);
 
function BlablaCaller (e:MouseEvent){ // В скобки вообще можно вставить заглушку Null (обязательно с большой), если передаваемые лисенером данные не нужны. 
    Blabla (Arg, e); // Но е можно и не передавать, это зависит от надобности.
}
 
function Blabla (arg, e:MouseEvent){
 
}

Но в этом случае придётся делать переменную полем класса. А, собственно, почему нет?

[mickfallout]

Сообщение от MidnightOne

Есть ещё одно решение, оно "как бы" не через задний проход.
создать функцию, которая потом будет вызывать нужную уже с параметрами, и вписать её в ивент лисенер.

addEventListener(MouseEvent.CLICK, BlablaCaller);
 
function BlablaCaller (e:MouseEvent){ // В скобки вообще можно вставить заглушку Null (обязательно с большой), если передаваемые лисенером данные не нужны. 
    Blabla (Arg, e); // Но е можно и не передавать, это зависит от надобности.
}
 
function Blabla (arg, e:MouseEvent){
 
}

Мне кажется что создавать обработчик события который невозможно отключить - плохая идея. function BlablaCaller доступна только внутри функции, придется или писать removeEventListener внутри того же вызова функции, или не писать нигде.

[MidnightOne]

Сообщение от mickfallout

Мне кажется что создавать обработчик события который невозможно отключить - плохая идея. function BlablaCaller доступна только внутри функции, придется или писать removeEventListener внутри того же вызова функции, или не писать нигде.

Нет. Он не внутри функции.

removeEventListener(MouseEvent.CLICK, BlablaCaller); можно написать где угодно.

[mickfallout]

Сообщение от MidnightOne

Нет. Он не внутри функции.

не понимаю... тогда зачем вторая функция? не проще ли вместо

addEventListener(MouseEvent.CLICK, BlablaCaller);
 
function BlablaCaller (e:MouseEvent){ // В скобки вообще можно вставить заглушку Null (обязательно с большой), если передаваемые лисенером данные не нужны. 
    Blabla (Arg, e); // Но е можно и не передавать, это зависит от надобности.
}
 
function Blabla (arg, e:MouseEvent){
 /*тут описывать что надо делать*/
}

использовать

addEventListener(MouseEvent.CLICK, Blabla);
 
function Blabla (e:MouseEvent, arg = Arg){
  /*тут описывать что надо делать*/
}

P.S. лучше писать полностью весь код, например так:

package {
    import flash.display.MovieClip;
    import flash.events.*;
    public class Main extends MovieClip {
        private var arg:String="Argument";
        public function Main() {
            super();
            stage.addEventListener(MouseEvent.CLICK, blabla);
        }
 
        private function blabla (e:MouseEvent, stringArgument:String = null):void {
            if (stringArgument == null)
                stringArgument = arg;
            trace(arg + " received");
            /*тут описывать что надо делать*/
        }
    }
}

[Artic]

мне когда лениво поднимать кастомный класс я делаю так

private var hash:Dictionary = new Dictionary();
...
var someButt:Sprite = new Sprite();
someButt.graphics.beginFill(0xff0000);
someButt.graphics.drawRect(0,0,50,50);
someButt.graphics.endFill();
addChild(someButt);
var thumbs:InteractiveObject = someButt as InteractiveObject;
thumbs.addEventListener(MouseEvent.CLICK,doIt);
hash[thumbs] = "argument"
 
private function doIt(event:Event):void
{
    var target:InteractiveObject = event.target as InteractiveObject;
    trace(hash[target]) // argument;
}

[udaaff]

MidnightOne, mickfallout, автор хочет передать параметр вместе с событием, т.е. сама переменная необязательно должна быть доступна в объекте, в котором вы подписываетесь на это событие. Событие, вообще, может, например, всплывать от какого-то ребенка, который будет передавать значение своей приватной переменной вместе с этим событием. Поэтому ваши способы не являются решением и равносильны тому, чтобы просто создать в классе дополнительное поле для хранения этого параметра.

[mickfallout]

Сообщение от udaaff

mickfallout, автор хочет передать параметр вместе с событием, т.е. сама переменная необязательно должна быть доступна в объекте, в котором вы подписываетесь на это событие.

ну в таком виде как раз локальная переменная функции(function Main) передается в обработчик. в объекте она недоступна.

package {
	import flash.display.MovieClip;
	import flash.events.*;
	public class Main extends MovieClip {
		public function Main() {
			super();
			var localArg:String = "local Argument";
			var handler:Function = function(event:Event):void { multiArgumentHandler(event, localArg, handler); };
			addEventListener(Event.ENTER_FRAME, handler);
		}
		public function multiArgumentHandler(event:Event, argument:String,handler:Function):void {
			trace("localArgument = "+ argument );
			removeEventListener(Event.ENTER_FRAME, handler);
		}
	}
}

Сообщение от gait

думал, что может быть есть простое решение (типа addEventListener(Event.ENTER_FRAME, traceNumEnterFrame(myVar))

Итого: вместо

addEventListener(Event.ENTER_FRAME, traceNumEnterFrame(myVar))

писать

var handler:Function = function(event:Event):void { traceNumEnterFrame(myVar); };
addEventListener(Event.ENTER_FRAME, handler);

и не забывать думать о том что если подписываешься на событие - скорее всего нужно будет и отписаться.

[MidnightOne]

Сообщение от mickfallout

Итого: вместо

addEventListener(Event.ENTER_FRAME, traceNumEnterFrame(myVar))

писать

var handler:Function = function(event:Event):void { traceNumEnterFrame(myVar); };
addEventListener(Event.ENTER_FRAME, handler);

и не забывать думать о том что если подписываешься на событие - скорее всего нужно будет и отписаться.

Главное не забыть объявить myVar перед тем как создать handler.


PS: Мне кажется, в любом из предложенных случаев правильнее создать глобальную переменную и не передавать её, а просто записать-прочитать. Почему? А потому, что все эти извращения (и уж тем более кастомная функция - диспетчер событий) занимают больше памяти и процессора, чем одна маленькая переменная. Про оптимизацию забывать не стоит!

[mickfallout]

Сообщение от MidnightOne

Главное не забыть объявить myVar перед тем как создать handler.

будет ошибка на этапе компиляции, ничего страшного.