Iwamotoscott

[banji]

Всем привет!
Подскажите пожалуйста направление для воспроизведения похожего эффекта как на сайте http://www.iwamotoscott.com/

Я так понимаю там много коротких линий которые образуют длинные линии, при наведении они меняют градус и расширяются.

Спасибо.

[-De-]

Если расстояние от курсора до центра отрезка меньше R, то повернуть отрезок на курсор.

[silin]

направление

package
{
	import flash.display.*;
 
	public class Main extends Sprite
	{
 
		public function Main():void
		{
 
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
			var d:Number = Math.SQRT2 * Line.SIZE;
			var d2:Number = d / 2;
			for (var i:int = 0; i < 20; i++)
			{
				for (var j:int = 0; j < 10; j++)
				{
					this.addChild(new Line(i * d + d2, j * d + d2));
				}
			}
 
		}
 
	}
 
}
import flash.display.*;
import flash.events.*;
 
class Line extends Sprite
{
	public static const SIZE:Number = 30;
	public static const R2:Number = 1.5e4;
	public static const RAD_GRAD:Number = 180 / Math.PI;
	public var tR:Number = 0;
 
	public function Line(x:Number, y:Number)
	{
		this.x = x;
		this.y = y;
		this.graphics.lineStyle(0, 0x808080);
		this.graphics.moveTo( -SIZE, 0);
		this.graphics.lineTo(SIZE, 0);
		this.addEventListener(Event.ADDED_TO_STAGE, this_addedToStage);
	}
 
	private function this_addedToStage(e:Event):void 
	{
		removeEventListener(Event.ADDED_TO_STAGE, this_addedToStage);
		this.addEventListener(Event.ENTER_FRAME, this_enterFrame);
	}
 
	private function this_enterFrame(e:Event):void
	{
		var dX:Number = parent.mouseX - this.x;
		var dY:Number = parent.mouseY - this.y;
		tR = dX * dX + dY * dY < R2 ? RAD_GRAD * Math.atan2(dY, dX) : 45;
		this.rotation += 0.5 * (tR - this.rotation);
	}
 
}

[NikolyA]

Силин, ты как всегда крут!!!

[tsarapkabel]

Да, подсказал направление А что за магическое "1.5e4" ?

[bav]

Экспоненциальная запись: 1.5e4 = 1.5 * 10000 = 15000

[tsarapkabel]

Ага, экспоненциальная. Спрошу по-другому: что за магическое "15000" ? Откуда оно взялось вообще?

[etc]

Сообщение от tsarapkabel

Ага, экспоненциальная. Спрошу по-другому: что за магическое "15000" ? Откуда оно взялось вообще?

Меджик намбер.

[silin]

>>Откуда оно взялось вообще?
дада Меджик намбер, обычно с потолка

чувствительность реагирования на мышь: квадрат расстояния до курсора