Синхронный load XML

[Kikasso]

Сообщение от milDude

А как я буду работать с данными, которые ещё не пришли?

Ну допустим у вас есть функция, которая обращается к данным. Если данные есть, она делает что-то. Если нет, она грузит, дает задание запустить себя с этими же параметрами по onLoad и прекращает работу. Это только как вариант.

[lowka]

Сообщение от milDude

... но как это можно инкапсулировать в класс?

Подойдет?

import mx.events.EventDispatcher;
import mx.utils.Delegate;

class ChannelsDAO
{
	private var _xml:XML;
	
	public var addEventListener:Function;
	public var removeEventListener:Function;
	
	private var dispatchEvent:Function;
	
	public function ChannelsDAO()
	{
		EventDispatcher.initialize(this);
	}
	
	public function getChannels():Void 
	{
		this._xml = new XML();
		this._xml.ignoreWhite = true;
		this._xml.onLoad = Delegate.create(this, this.onLoad);
		this._xml.load("channels.xml");
	}
	
	private function onLoad(success:Boolean)
	{
		if(success)
		{
			var result:Array = this.getChannelsFromXML();
			//вещаем событие.
			//result - полученных данные.
			this.dispatchEvent({type:"onResult", result: result})
		}else
		{
			this.dispatchEvent({type:"onFault"})
		}
	}
	
	private function getChannelsFromXML():Array 
	{
		var channels:Array = []
		
		//здесь извлекаем данные из загруженного xml-документа.

		return channels;
	}
}

Проверка

import mx.utils.Delegate;

class ChannelsDAOTest
{
	private var _model:Model;
	private var _dao:ChannelsDAO;
	
	public function ChannelsDAOTest()
	{
		
	}
	
	public function run():Void 
	{
		this._model = new Model();
		this._dao = new ChannelsDAO();
		
		this._dao.getChannels();
		this._dao.addEventListener("onResult", Delegate.create(this, this.resultHandler));
	}
	
	private function resultHandler(event:Object):Void 
	{
		this._model.channels = event.result;
	}
}

[udaaff]

В классе:

import mx.events.EventDispatcher;
//
class SubClass extends XML {
	/*
	*/
	private var dispatchEvent:Function;
	public var addEventListener:Function;
	public var removeEventListener:Function;
	/*
	*/
	public function SubClass() {
		super();
		this.ignoreWhite = true;
		EventDispatcher.initialize(this);
	}
	/*
	*/
	public function onLoad(success:Boolean):Void {
		if (success) {
			var eventObject:Object = {type:"onEvent", target:this};
			dispatchEvent(eventObject);
		}
	}
}

В кадре:

var subClass:SubClass = new SubClass();
//
var listener:Object = new Object();
listener.onEvent = function(eventObj:Object) {
	trace(eventObj.type)
};
subClass.addEventListener("onEvent", listener);
//
subClass.load("my_xml.xml");

[milDude]

lowka
Спасибо за код!

Понял, что просто в голове не могу привыкнуть к асинхронности. Ну вроде уже привык )).

[etc]

Привыкать придется.

lowka, зря ты туда ещё и модель запихнул. Щас вопросов миллион будет. Рано ещё.

[milDude]

this._xml.onLoad = Delegate.create(this, this.onLoad);

почему не работает вот так:

this._xml.onLoad = this.onLoad;

[etc]

Это связано с изменением области видимости при такой записи. Delegate исправляет эту проблему.

[milDude]

а в какой области видимости мы находимся?
this куда ссылается?

насчёт модели угадал ) где можно про неё почитать?

[etc]

this ссылается на XML, а не на класс.

Модель lowka воткнул, как заготовку для реализации паттерна MVC. А оно в данном случае вообще не нужно и лишнее.

[milDude]

this._xml.onLoad = Delegate.create(this, this.onLoad);

не понял:
слева от знака равенства "this" ссылается на экземпляр класса, правильно?
а справа уже нет?