JSON -> XML ?

[Mur4ik]

Не изобретайте велосипед, гляньте на класс SimpleXMLEncoder, вполне способен справится с Вашей задачей.

private function objectToXML(object:Object, rootNode:String = "root"):XML
{
	import mx.rpc.xml.SimpleXMLEncoder;
 
	var xmlDocument:XMLDocument = new XMLDocument();
	var xmlEncoder:SimpleXMLEncoder = new SimpleXMLEncoder(xmlDocument);
	xmlEncoder.encodeValue(object, new QName(rootNode), xmlDocument);
 
	return new XML(xmlDocument.toString());
}

Правда в чистом виде он тащит за собой около 20Кб флексовых классов, но это не проблема, я когда то делал из него независимую версию, вышло что то около 5Кб по итогу. Если нужно попробую отрыть и прикреплю тут.

[mikhailk]

о, на что-то такое я и надеялся
буду смотреть

Добавлено через 1 час 18 минут
все работает

возможно, кому понадобится полностью (оформил как простой код, поскольку в AS3 перекодируется JSON):

package 
{
	import flash.display.*;
	import flash.events.*;
	import flash.xml.*;
	import mx.rpc.xml.SimpleXMLEncoder;
	import com.adobe.serialization.json.*;	
	
	public class Main extends Sprite 
	{
		
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		private function init(e:Event = null) : void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			
			var stringJSON:String = '{"param1":"1","param2":"</blabla","param3":"blabla]]>",'
	                               +'"paramArray":[{"id":"1","value":"111"},{"id":"2","value":"222"}]}';

			var objXML:XML = jsonToXML(stringJSON);
			trace(objXML);
		}
		
		private function jsonToXML(stringJSON:String) : XML
		{
			var obj:Object = JSON.decode(stringJSON); 
			var objXML:XML = objectToXML(obj);
			
			return(objXML);
		}
		
		private function objectToXML(object:Object, rootNode:String = "root") : XML
		{
			var xmlDocument:XMLDocument = new XMLDocument();
			var xmlEncoder:SimpleXMLEncoder = new SimpleXMLEncoder(xmlDocument);
			xmlEncoder.encodeValue(object, new QName(rootNode), xmlDocument);
		 
			return new XML(xmlDocument.toString());
		}
	}
	
}

вывод:

<root>
  <param1>1</param1>
  <param2>&lt;/blabla</param2>
  <param3>blabla]]&gt;</param3>
  <paramArray>
    <item>
      <id>1</id>
      <value>111</value>
    </item>
    <item>
      <id>2</id>
      <value>222</value>
    </item>
  </paramArray>
</root>