Flash MX: myMovieClip.onData

[john]

Проблема в том что мувик с подгруженым содержанием уже "другой swf" и тут не registerClass не onData не onLoad не помогают,

единственный выход это вызвать действие из подгружаемого SWF.

либо делать устаревшими методами....

[john]

Смешное решение, но что то в этом есть

a = new Sound();
a.onLoad = function()
{
	trace(this.getBytesLoaded());
	myMovie_mc.loadMovie("load.jpg");
	delete this;
};
a.loadSound("load.jpg");

сейчас смувиками попробую

[john]

немного оформилась идея, вот что могу предложить,

создаем некий объект который загружает данные (SWF, JPG или MP3), кеширует данные, которы после загрузки можно уже использовать.

работа основывется на использовании объекта Sound.
ему как показала практика что загрузать, стрим он и есть стрим.

название Image взял из JS как бы понятно. Удобнее чем пользовать Preloader например

//-------------------------------------------------------------------------
//	создание класса image
//-------------------------------------------------------------------------
_global.Image = function(src)
{
	this.data = new Sound();
	this.data.root = this;
	if (src != undefined) {
		this.tmp_interval = setInterval(this,"load",20,src)// это чтобы успеть создать эвент onLoad
	}
};
Image.prototype.load = function(src)
{
	clearInterval(this.tmp_interval);
	
	this.data.onLoad = function()
	{
		this.root.onLoad();
	};
	this.data.loadSound(src);
};
Image.prototype.getBytesLoaded = function()
{
	return this.data.getBytesLoaded();
};
Image.prototype.getBytesTotal = function()
{
	return this.data.getBytesTotal();
};
ASSetPropFlags(_global, "Image", 7);
//-------------------------------------------------------------------------
//	использование 1
//-------------------------------------------------------------------------
img = new Image("load.jpg");
img.onLoad = function()
{
	myMovie_mc.loadMovie("load.jpg");
};
//-------------------------------------------------------------------------
//	использование 2
//-------------------------------------------------------------------------
img = new Image();
img.onLoad = function()
{
	myMovie_mc.loadMovie("load.jpg");
};
img.load("load.jpg")

вот такие дела

[john]

Вот это я думаю это уже окончательный релиз

//*************************************************************************
//-------------------------------------------------------------------------
//	class image
//-------------------------------------------------------------------------
_global.Image = function(src,mc)
{
	this._targetMovie = mc;
	this.data = new Sound();
	this.data.root = this;
	if (src != undefined) 
	{
		this.tmp_interval = setInterval(this,"load",20,src)// for onLoad creat
	}
}
Image.prototype.load = function(src,mc)
{
	clearInterval(this.tmp_interval);
	
	this._targetMovie = mc||this._targetMovie;
	this._src = src;
	
	this.data.onLoad = function()
	{
		this.root.onLoad();
	}
	this.data.loadSound(src);
}
Image.prototype.getBytesLoaded = function()
{
	return this.data.getBytesLoaded();
}
Image.prototype.getBytesTotal = function()
{
	return this.data.getBytesTotal();
}
Image.prototype.onLoad = function()
{
	if(this._targetMovie != undefined )this._targetMovie.loadMovie(this._src);
}

Image.prototype.addProperty("src",function()
{
	return this._src;
},Image.prototype.load)

ASSetPropFlags(_global, "Image", 7);

//*************************************************************************
//-------------------------------------------------------------------------
//	usage 1
//-------------------------------------------------------------------------
img = new Image("load.jpg");
img.onLoad = function()
{
	myMovie_mc.loadMovie("load.jpg");
}
//-------------------------------------------------------------------------
//	usage 2
//-------------------------------------------------------------------------
img = new Image();
img.onLoad = function()
{
	myMovie_mc.loadMovie("load.jpg");
}
img.load("load.jpg")
//-------------------------------------------------------------------------
//	usage 3
//-------------------------------------------------------------------------
img = new Image();
img.onLoad = function()
{
	myMovie_mc.loadMovie("load.jpg");
}
img.src = "load.jpg";
//-------------------------------------------------------------------------
//	usage 4
//-------------------------------------------------------------------------
img = new Image();
img.load("load.jpg",myMovie_mc);
//-------------------------------------------------------------------------
//	usage 5
//-------------------------------------------------------------------------
img = new Image("load.jpg",myMovie_mc);

[john]

вот пример загрузки картинки (JPG),

http://www.3wgraphics.net/tmp/load/test_load.html

SWF то же самое, лень выкладывать пример.

[john]

ну как?

[Baltika]

мудрено
%)