Внутренний прелоадер в AS3

[shaman4d]

http://shaman4d.blogspot.com/2010/08...s-d-fense.html - недавно написал как раз про настройку с прелоадером

[Relliart]

У кого Flash CS5, вот схема прикручивания простого прелоадера. Пробовал для actionscript 3.0.

[arkadattx]

Извиняюсь за очередной подъем старой темы.
Как можно реализовать внутренний прелоадер без участия IDE? Исключительно AS3 проект с компиляцией во FlexSDK без mxml.

[alatar]

package 
{
	import flash.display.DisplayObject;
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.utils.getDefinitionByName;
 
 
	public class Preloader extends MovieClip 
	{
 
		public function Preloader() 
		{
			if (stage) {
				stage.scaleMode = StageScaleMode.NO_SCALE;
				stage.align = StageAlign.TOP_LEFT;
			}
			addEventListener(Event.ENTER_FRAME, checkFrame);
			loaderInfo.addEventListener(ProgressEvent.PROGRESS, progress);
			loaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioError);
 
			// TODO show loader
		}
 
		private function ioError(e:IOErrorEvent):void 
		{
			trace(e.text);
		}
 
		private function progress(e:ProgressEvent):void 
		{
			// TODO update loader
		}
 
		private function checkFrame(e:Event):void 
		{
			if (currentFrame == totalFrames) 
			{
				stop();
				loadingFinished();
			}
		}
 
		private function loadingFinished():void 
		{
			removeEventListener(Event.ENTER_FRAME, checkFrame);
			loaderInfo.removeEventListener(ProgressEvent.PROGRESS, progress);
			loaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, ioError);
 
			// TODO hide loader
 
			startup();
		}
 
		private function startup():void 
		{
			var mainClass:Class = getDefinitionByName("Main") as Class;
			addChild(new mainClass() as DisplayObject);
		}
 
	}
 
}

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
 
	[Frame(factoryClass="Preloader")]
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
		}
 
	}
 
}

[arkadattx]

alatar,
почему Preloader extends MovieClip, это обязательно?
Preloader always Compile?
что есть [Frame(factoryClass="Preloader")] ?

[alatar]

почему Preloader extends MovieClip, это обязательно?

Обязательно. Main будет встроен во второй фрейм

что есть [Frame(factoryClass="Preloader")] ?

Мета-тег для компилятора.

[arkadattx]

а где это в коде видно, что он во 2м кадре?
и вообще что есть кадры и пр.

[alatar]

[Frame(factoryClass="Preloader")]

Вот тут и видно. Этот мета-тег сообщает компилятору, что этот класс надо встроить во второй кадр для класса Preloader.

[arkadattx]

Немного не понимаю. А почему не в 3й, не в 15й?
Как мне можно будет вставить что-то в, к примеру, 4й кадр?

[alatar]

Немного не понимаю.

Что вам не понятно?

А почему не в 3й, не в 15й?

Зачем? Для прелоадера достаточно 2-х кадров.

Как мне можно будет вставить что-то в, к примеру, 4й кадр?

Воспользуйтесь FlashIDE. Flex SDK не предоставляет возможностей для полноценного создания и редактирования MovieClip.