Ваша реализация MVC

[terbooter]

etc, поясни пожалуста.
Правильно ли я понял, что для дерева объектов входящих в модель вы реализовали
собственный механизм баблинга?

[etc]

terbooter, да, правильно.

[Psycho Tiger]

etc, всегда он был интересен, как вы его реализовали. Кроме как

while (parent) parent.dispatchEvent

мне ничего на ум не лезет.

[Котяра]

А что в этом плохого? Я также делал.
as2 вариант:

	public function dispatchEvent(event:Event):Void 
	{
 
		event.target = this;
		event.currentTarget = this;
		var i:Number = 0;
		var l:Number = _eventListeners.length;
		for (i = 0; i < l; i++)
		{
			if (event.type != _eventListeners[i].e)	continue;
			_eventListeners[i].f.apply(_eventListeners[i].o, [event.clone()]);	
		}
		dispatchBubblesEvent(event);
		delete event;
	}
 
	// всплытие событий
	public function dispatchBubblesEvent(event:Event):Void 
	{
			if (event.bubbles && this["eventParent"].dispatchEvent) 
			{			
				var bubblesEvent:Event = event.clone();
				bubblesEvent.currentTarget = this["eventParent"];
				this["eventParent"].dispatchEvent(bubblesEvent);
			}
			delete event;	
	}

может немного нелогично показаться просто в сеттерах target и currentTarget стоят проверки на "уже определённость"

[Psycho Tiger]

Я не говорил что это плохо.
Но информация о фазе и таргет безнадёжно теряется в случае с редиспатчем при бабблинге. Как вариант - переопределять геттеры для них и писать обёртку, но в моём жалком умишке это дело не проецируется красиво. Think костыльно.

[Котяра]

всё определяется целями. костыльность - сугубо ирреалистичное понятие, я бы сказал близкое к гейзенбергову пространству. пока его не трогаешь - это не костыль. )))

[expl]

this["eventParent"]

Как это получилось, что eventParent оказалось невозможным статически затипизировать?
Определяется в наследнике класса ? - но почему тогда просто не перегрузить

Котяра, ещё интересно почему надо было самому в цикле листенеры обходить а не просто вызвать super.dispatchEvent() в перегруженном методе

Просто сейчас пытаюсь свою (с немного другими целями) реализацию накатать - запнулся на том, как определить было ли вызвано stopPropagation() и ищу альтернативы.

Проехали, "as2-вариант" не увидел

[Котяра]

Насчёт ["eventParent"] - замануха вроде бы была, что я динамически назначал классы эвентДиспатчерами..
А чтоб FD не матерился - сделал в скобках.
Ну или что-то такое - не помню.
и это:
тигра: таргет у меня остаётся ( там в сеттере есть проверка на существование - если он уже есть - то посылаем в Кубу), а фазу я просто не реализовывал вообще - я и в ас3 её ни разу не использовал.

[Psycho Tiger]

Ам. А если надо событие редиспатчить — именно редиспатчить с созданием клона с изменением таргета? Или тебе такая возможность не нужна совершенно?

[terbooter]

Решил тоже реализовать что-то подобное. Мне нужно чтобы событие от детей всплывало до "рутовой" модели.
Таким образом модель лист может не иметь ссылку на родителя.
Вот такая зарисовочка

package ru.terbooter.farm.model {
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.utils.Dictionary;
	import ru.terbooter.farm.model.events.HelperEvent;
	/**
	 * ...
	 * @author terbooter.ru
	 */
	public class ModelBase extends EventDispatcher {
 
		private var dictionary:Dictionary;
 
		public function ModelBase() {
 
		}
 
		/**
		 * От каждого ребенка событие будет всплывать
		 * до рутовой модели
		 * @param	child
		 */
		protected function addChild(child:ModelBase):void {
			if (!this.dictionary) {
				this.dictionary = new Dictionary(true);
			}
 
			child.addEventListener(HelperEvent.LISTEN_TO, helperListener);
			//TODO
			this.dictionary[child] = { };
 
		}
 
		protected function removeChild(child:ModelBase):void {
			//TODO
		}
 
		/**
		 * Перед основным событием диспатчим вспомогательное,
		 * которое расскажет паренту, какой тип события слушать,
		 * чтобы передать его дальше по цепочке
		 * @param	event
		 * @return
		 */
		override public function dispatchEvent(event:Event):Boolean {
			var helper:HelperEvent = new HelperEvent(HelperEvent.LISTEN_TO);
			helper.eventToListen = event;
			super.dispatchEvent(helper);
			return super.dispatchEvent(event);
		}
 
		private function helperListener(e:HelperEvent):void {
			var dispatcher:EventDispatcher = EventDispatcher(e.target);
			dispatcher.addEventListener(e.eventToListen.type, bubbleListener);
		}
 
		private function bubbleListener(e:Event):void {
			//TODO
			this.dictionary[e.target][e.type] = 1;
			this.dispatchEvent(e);
		}
 
 
	}
 
}