определение угла

[dex157]

В as 1.0 был метод позволяющий узнать угол от одного объекта к другому, весь справочник по as 3.0 пролестал, но не нашел не чего подобного, не подскажите, есть ли такой метод, или все через синусы косинусы делать..?

[Jewelz]

недавно темка была

http://www.flasher.ru/forum/showthread.php?t=134488

[GentleFLASH]

Math.atan2(y, x) - вернет угол в радианах

[dex157]

Jewelz
спасибо за наводку
GentleFLASH
увы, работает только для четверти окружности

[udaaff]

В as 1.0 был метод позволяющий узнать угол от одного объекта к другому

И что там за метод был такой?

[dex157]

udaaff
вот не помню, но точно помню, что я не возился с тангенсами что бы узнать угол, там это как то очень просто выполнялось.. но, это было очень давно..)

[Psycho Tiger]

увы, работает только для четверти окружности

Какие подробности. Всю жизнь вертел так объекты на все 360, не задумываясь. Работало )

[dex157]

Psycho Tiger
Не могли бы накидать пробник..? )) что то не выходит у меня ввертеть.. и как я понял по описанию, измерения идут относительно угла stage, как мне другую точку задать, относительно которой нужно угол узнать..? 0о

[Psycho Tiger]

Да пожалуйста. Как базовый класс ставьте.

package  
{
	import flash.display.MovieClip;
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
 
	/**
	 * ...
	 * @author FluFme
	 */
	public class NewClass extends MovieClip
	{
		private var shape:Shape;
 
		public function NewClass() 
		{
			super();
			var spr:Sprite = new Sprite(); //для реакции мышки на всю зону покрытия
			spr.graphics.beginFill(0, 0);
			spr.graphics.drawRect(0, 0, 1000, 1000);
			spr.graphics.endFill();
			addChild(spr);
 
			shape = new Shape();
			shape.graphics.lineStyle(3, Math.random() * 0xFFFFFF);
			shape.graphics.moveTo(0, 50);
			shape.graphics.lineTo(0, 0);
			shape.graphics.lineTo( -20, 20);
			shape.graphics.moveTo(0, 0);
			shape.graphics.lineTo(20, 20);
			addChild(shape);
			shape.x = 200;
			shape.y = 200;
 
			stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
		}
 
		private function onMouseMove(e:MouseEvent):void 
		{
			e.updateAfterEvent();
			//+90 потому что стрелку нарисовал смотрящей вверх, а надо было рисовать в другую сторону )
			shape.rotation = Math.atan2(stage.mouseY - shape.y, stage.mouseX - shape.x) * 180 / Math.PI + 90;
		}
 
	}
 
}

[dex157]

Psycho Tiger
спасибо большое..! ) очень помогли..)