ну, во-первых, на mx.graphics свет клином не сходится. Есть другие пакеты для этого. А во-вторых, причем здесь FD? Что мешает создать не AS3 Project, а к примеру Flex 4 Project? Удалить файл Main.mxml и вместо него создать Main.as. В остальном тот же процесс. Только флексовые пакеты будут доступны.
Код AS3:
package social.photos {
import social.api.com.adobe.images.PNGEncoder;
import flash.display.Bitmap;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.net.URLLoader;
import flash.net.URLLoaderDataFormat;
import flash.net.URLRequest;
import flash.net.URLRequestHeader;
import flash.net.URLRequestMethod;
import flash.utils.ByteArray;
import flash.utils.getTimer;
import social.vk.api.MD5;
import social.vk.api.serialization.json.Json;
import social.vk.APIConnection;
public class VKPhoto {
private var _vk: APIConnection = null;
private var _callback: Function = null;
private var _albumID: String = "";
private var _vkUploadServer: String = null;
private var _image: Bitmap = null;
private var _albumDescription: String = null;
private var _albumTitle: String = null;
private var _onUploadedFunction: Function = null;
private var _message: String = "";
private var _erCallback: Function = null
public function VKPhoto(vk:APIConnection) {
_vk = vk;
}
public static function saveAlbumPhoto(image:Bitmap, vk:APIConnection, callback:Function,
erCallback:Function,
albumTitle:String = "",
albumDescription:String = ""):void {
var vkPhoto:VKPhoto = new VKPhoto(vk);
vkPhoto.saveAlbumPhoto(image, callback, erCallback, albumTitle, albumDescription);
}
public static function saveWallPhoto(image:Bitmap, vk:APIConnection, callback:Function,
erCallback:Function, message:String = ""):void {
var vkPhoto: VKPhoto = new VKPhoto(vk);
vkPhoto.saveWallPhoto(image, callback, erCallback, message);
}
public function saveAlbumPhoto(image:Bitmap, callback:Function, erCallback:Function,
albumTitle:String = "",
albumDescription:String = ""):void {
_image = image;
_callback = callback;
_erCallback = erCallback;
_albumDescription = albumDescription;
_albumTitle = albumTitle;
_onUploadedFunction = onVkPhotoUploaded;
if (_callback == null || _image == null || _albumDescription == null) {
throw new ArgumentError("one of the arguments is null");
}
_vk.api("photos.getAlbums", { }, onAlbums, onVkError );
}
public function saveWallPhoto(image:Bitmap, callback:Function, erCallback:Function, message:String = ""):void {
_image = image;
_callback = callback;
_erCallback = erCallback;
_message = message;
_onUploadedFunction = onVkWallPhotoUploaded;
if (_callback == null || _image == null) {
throw new ArgumentError("one of the arguments is null");
}
requestVkWallUploadServer();
}
private function requestVkWallUploadServer():void { // получение сервера загрузки сообщения на стену
_vk.api("photos.getWallUploadServer", {}, onVkUploadServer, onVkError);
}
private function onAlbums(params:Object):void {
if (params is Array) {
var arr:Array = params as Array;
} else {
arr = [params];
}
var albumFound:Boolean = false;
for (var i:String in arr) {
if (arr[i].title == _albumTitle) {
_albumID = arr[i].aid;
albumFound = true;
break;
}
}
if (albumFound == false) {
_vk.api("photos.createAlbum",
{ title: _albumTitle, description: _albumDescription,
comment_privacy: 0, privacy: 0 },
onAlbumCreated, onVkError);
} else {
requestVkUploadServer();
}
}
private function requestVkUploadServer():void {
_vk.api("photos.getUploadServer", { aid: _albumID }, onVkUploadServer, onVkError);
}
private function onAlbumCreated(params:Object):void {
_albumID = params.aid;
requestVkUploadServer();
}
private function onVkUploadServer(params:Object):void {
_vkUploadServer = params.upload_url;
uploadVkPhoto();
}
private function uploadVkPhoto():void {
var imageStream:ByteArray = PNGEncoder.encode(_image.bitmapData);
var stream:ByteArray = new ByteArray();
var boundary:String = "----------Ij5ae0ae0KM7GI3KM7";
var imageName:String = MD5.encrypt(getTimer() + "") + ".png";
stream.writeUTFBytes("--" + boundary + '\r\nContent-Disposition: form-data; name="file1"; filename="' + imageName + '"\r\nContent-Type: image/png\r\n\r\n');
stream.writeBytes(imageStream);
stream.writeUTFBytes("\r\n--" + boundary + '--\r\n');
var header:URLRequestHeader = new URLRequestHeader ("Content-type", "multipart/form-data; boundary=" + boundary);
var urlRequest:URLRequest = new URLRequest(_vkUploadServer);
urlRequest.requestHeaders.push(header);
urlRequest.method = URLRequestMethod.POST;
urlRequest.data = stream;
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
urlLoader.addEventListener( Event.COMPLETE, _onUploadedFunction );
urlLoader.addEventListener( IOErrorEvent.IO_ERROR, photoUploadError );
try {
urlLoader.load( urlRequest );
} catch (e:Error) {
trace(e.getStackTrace());
}
}
private function onVkPhotoUploaded(e:Event):void {
e.target.addEventListener( Event.COMPLETE, _onUploadedFunction );
e.target.addEventListener( IOErrorEvent.IO_ERROR, photoUploadError );
var responce: Object = Json.decode(unescape(String(e.target.data)));
var server: String = responce.server;
var hash: String = responce.hash;
var photosList: String = responce.photos_list;
var aid: String = responce.aid;
_vk.api("photos.save", { photos_list: photosList, aid: aid, hash: hash, server: server },
onVkPhotoSaved, onVkError );
}
private function onVkWallPhotoUploaded(e:Event):void {
e.target.addEventListener( Event.COMPLETE, _onUploadedFunction );
e.target.addEventListener( IOErrorEvent.IO_ERROR, photoUploadError );
var responce: Object = Json.decode(unescape(String(e.target.data)));
var server: String = responce.server;
var hash: String = responce.hash;
var photo: String = responce.photo;
_vk.api("photos.saveWallPhoto", { photo: photo, hash: hash, server: server },
onWallPhotoSaved, onVkError );
}
private function onWallPhotoSaved(params:Object):void {
var imageID:String = params[0].id;
//trace("THIS IS IMAGE ID", imageID, "VKPhotoUploader");
_vk.api("wall.post", { message: _message, attachments: imageID },
function(o:Object):void {}, function(p:Object):void { } );
}
private function onVkPhotoSaved(params:Object):void {
if (_callback != null) {
_callback.call();
_callback = null;
}
dispose();
}
private function photoUploadError(e:IOErrorEvent):void {
e.target.addEventListener( Event.COMPLETE, _onUploadedFunction );
e.target.addEventListener( IOErrorEvent.IO_ERROR, photoUploadError );
if (_erCallback != null) {
_erCallback.call();
}
dispose();
}
private function onVkError(param:Object):void {
trace(Json.encode(param));
if (_erCallback != null) {
_erCallback.call();
}
dispose();
}
private function dispose():void {
if (_image) {
_image.bitmapData.dispose();
_image = null;
}
_erCallback = null;
_albumTitle = null;
_albumDescription = null;
_onUploadedFunction = null;
_message = "";
}
}
}
В общем, здесь нужно только некоторые пакеты поправить под свои нужды, и скачать какой-то PNGEncoder
Для загрузки фотки в альбом или на стену в контакт, достаточно лишь вызвать соответствующий статический метод
Этот класс 100% рабочий. Успешно используется в нескольких проектах.
Класс умеет создавать новый альбом, если альбома с указанным названием у пользователя еще нет. Все это происходит автоматически, и ни о чем дополнительно париться не надо.
27.08.2013, 10:21
пустое поле Photo в ответ на POST запрос
Линейный вид
