Форум Flasher.ru
Ближайшие курсы в Школе RealTime
Список интенсивных курсов: [см.]  
  
Специальные предложения: [см.]  
  
 
Блоги Правила Справка Пользователи Календарь Поиск рулит! Сообщения за день Все разделы прочитаны
 

Вернуться   Форум Flasher.ru > Flash > ActionScript 3.0 > Статьи

Версия для печати  Отправить по электронной почте    « Предыдущая тема | Следующая тема »  
Опции темы Опции просмотра
 
Создать новую тему Ответ
Старый 06.04.2010, 15:01
cpu вне форума Посмотреть профиль Отправить личное сообщение для cpu Найти все сообщения от cpu
  № 21  
Ответить с цитированием
cpu

Регистрация: Mar 2010
Сообщений: 223
Цитата:
Через контроллер. Точнее, как он решит, так и будет.
- получается контроллер имеет ссылку на модель. И меняет определенные данные через какой-нибудь set-метод?

Получается так:
1. View не имеет ссылок никуда, только рассылает события в контроллер.(данные введенные в input-поля хранит у себя, что бы их мог посмотреть контроллер через get-метод).
2. Контроллер имеет ссылку и на модель и на представление, и может работать с ними через их методы.
3. Модель отправляет события в контроллер если поменялись какие-то данные, и передает их ему через например set-методы. И наоборот.

В таком случае между View и model действительно нет прямой связи.
Но остается прямая связь между моделью и контроллером.

Старый 06.04.2010, 15:13
Art_133 вне форума Посмотреть профиль Отправить личное сообщение для Art_133 Посетить домашнюю страницу Art_133 Найти все сообщения от Art_133
  № 22  
Ответить с цитированием
Art_133
 
Аватар для Art_133

блогер
Регистрация: Feb 2007
Адрес: Москва
Сообщений: 538
Записей в блоге: 2
Отправить сообщение для Art_133 с помощью Skype™
Цитата:
Сообщение от MrPoma Посмотреть сообщение
Вызывает метод dispatchEvent. А поскольку объявлен он в супер-классе, пишут super.
Я думал что супер Клас имеется ввиду Класс который расширяет другой Класс. Здесь Controller не расширяет Viwer. Выходит что можно вызвать метод в классе где был объявлен экземпляр при помощи super?

Старый 06.04.2010, 15:26
etc вне форума Посмотреть профиль Найти все сообщения от etc
  № 23  
Ответить с цитированием
etc
Et cetera
 
Аватар для etc

Регистрация: Sep 2002
Сообщений: 30,784
cpu
1) view имеет ссылку на модель;
2) Контроллер на них обоих;
3) Модель отправляет события вьюверу. Вьювер — контроллеру.

Старый 06.04.2010, 15:31
Psycho Tiger вне форума Посмотреть профиль Отправить личное сообщение для Psycho Tiger Найти все сообщения от Psycho Tiger
  № 24  
Ответить с цитированием
Psycho Tiger
 
Аватар для Psycho Tiger

блогер
Регистрация: Jun 2005
Адрес: Господи пожалуйста не Новосибирск
Сообщений: 6,598
Записей в блоге: 17
Цитата:
Сообщение от Art_133 Посмотреть сообщение
Я думал что супер Клас имеется ввиду Класс который расширяет другой Класс. Здесь Controller не расширяет Viwer. Выходит что можно вызвать метод в классе где был объявлен экземпляр при помощи super?
Так и есть. Забудьте о super в этом примере. Пишите просто
Код AS3:
addEventListener(Event.COMPLETE, dispatchEvent);
Это просто что то типа подписи "а это писал тру-флешер"

Я пишу с super только потому что мне необходимо, чтобы вот этот самый addEventListener был именно таким, каким я хочу - каким его сделали Adobe и ничто мне не может гарантировать, что завтра я для каких то других нужд переопределю addEventListener и dispatchEvent и мой сегодняшний код не перестанет работать. Маловероятно, конечно, но всё же... это мой бзик и моё право, к тому же так правильней

По теме MVC: *сейчас переделаю то, что писал вчера с новыми знаниями и отпишусь*

Старый 06.04.2010, 16:03
cpu вне форума Посмотреть профиль Отправить личное сообщение для cpu Найти все сообщения от cpu
  № 25  
Ответить с цитированием
cpu

Регистрация: Mar 2010
Сообщений: 223
etc:
Цитата:
1) view имеет ссылку на модель;
Но ведь тогда view может напрямую менять данные в модели обойдя controller (и контроллер со своей бизнес-логикой остается неудел).
---------------------------------------------------------------
etc:
Цитата:
3) Модель отправляет события вьюверу. Вьювер — контроллеру.
Так как View имеет ссылку на модель, он может получит по этому событию данные из model для отображения, обойдя contoller(который опять неудел.)

=================================================================
P.S. Вообще какая главная цель MVC? Раньше я думал возможность подключать к программе множество представлений(view) и менять их хоть в горячую. Ну и создавать вложенные представления.

Старый 06.04.2010, 16:43
Psycho Tiger вне форума Посмотреть профиль Отправить личное сообщение для Psycho Tiger Найти все сообщения от Psycho Tiger
  № 26  
Ответить с цитированием
Psycho Tiger
 
Аватар для Psycho Tiger

блогер
Регистрация: Jun 2005
Адрес: Господи пожалуйста не Новосибирск
Сообщений: 6,598
Записей в блоге: 17
Цель MVC - отделить то, что на экране от того, что происходит логикой. Короче, если проект расчитывался как консольный, а потом вдруг трах тибидох и хотим 3д - надо будет менять лишь вьюшку.


Главный класс:
Код AS3:
package  
{
	import flash.display.Sprite;
 
	public class JustMain extends Sprite
	{
 
		public function JustMain() 
		{
			super();
			var controller:Controller = new Controller(this);
		}
 
	}
 
}
Контроллер:
Код AS3:
package  
{
	import flash.display.DisplayObjectContainer;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class Controller
	{
		private var _model:Model = new Model();
		private var _viewer:Viewer = new Viewer(_model);
		private var _container:DisplayObjectContainer;
		public function Controller(container:DisplayObjectContainer) 
		{
			_container = container;
			init();
		}
 
		private function init():void
		{
			_container.addChild(_viewer);
			_viewer.addEventListener(MouseEvent.CLICK, onViewerClick);
 
		}
 
		private function onViewerClick(e:MouseEvent):void 
		{
			_model.change(Math.random() * 400, Math.random() * 400);
		}
 
 
	}
 
}
Модель:
Код AS3:
package  
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
 
	public class Model extends EventDispatcher
	{
 
		//no getters/setters, just example
		public var x:Number = 0;
		public var y:Number = 0;
 
		public function Model() 
		{
			super(null);
 
		}
 
		public function change(x:Number, y:Number):void {
			this.x = x;
			this.y = y;
			super.dispatchEvent(new Event(Event.CHANGE));
		}
 
	}
 
}
Вьюшка:
Код AS3:
package  
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class Viewer extends Sprite
	{
		private var _model:Model;
		public function Viewer(model:Model) 
		{
			super();
			_model = model;
			init();
		}
 
		private function init():void
		{
			var someSprite:Sprite = new Sprite();
			someSprite.graphics.beginFill(0);
			someSprite.graphics.drawCircle(0, 0, 50);
			someSprite.graphics.endFill();
			super.addChild(someSprite);
			someSprite.addEventListener(MouseEvent.CLICK, super.dispatchEvent);
 
			_model.addEventListener(Event.CHANGE, onModelChange);
		}
 
		private function onModelChange(e:Event):void 
		{
			super.x = _model.x;
			super.y = _model.y;
		}
 
 
 
		public function get model():Model { return _model; }
 
		public function set model(value:Model):void 
		{
			_model = value;
		}
	}
 
}
И серия вопросов вновь Спасибо, что помогаешь.
1) Вот классы выше - теперь это правильное MVC?
2) Да, действительно - вьюшка может менять что нибудь у модели и контроллер сойдёт с ума - получается, у этой триады даже пиша вьюшку надо быть аккуратным, потому что можешь всё сломать?
3) А кто от кого наследуется? Я так понимаю: controller -> Object, model - EventDispatcher, viewer - DisplayObject. Так?
4) Модельку передавать в конструктор вьюшки это хорошая практика, или всё таки лучше через сеттер? (вопрос граничит с бредом, знаю )
5) На той же википедии и на некоторых других сайтах пишут, что контроллер - лишь связующее, а вся бизнес логика в модели. Они не правы или с флешем тонкость какая?
6) Склоняюсь к мнению, что чистый MVC не в гигантских проектах нафиг не нужен, хотя мне нравится идея о MC + V. Такое существует вообще, контроллер с интегрированой моделью? Если да, то как там поступаем? Если контроллер уже имеет прямую ссылку на вьюшку, а в нём же интегрированна модель - то смысла в событии нет, можно отправлять напрямую или же ради сохранения полиморфизма и перехода после к чистой MVC следует остановится на событиях?

Старый 06.04.2010, 17:38
cpu вне форума Посмотреть профиль Отправить личное сообщение для cpu Найти все сообщения от cpu
  № 27  
Ответить с цитированием
cpu

Регистрация: Mar 2010
Сообщений: 223
ФЛУД.
На днях пришла по почте "Приемы объектно-ориентированного проектирования. Паттерны проектирования" этих четырех авторов.
Там вроде написано про MVC, вечерком почитаю, отпишусь что они знают про MVC, люди вроде умные, из университетов)).

Старый 06.04.2010, 17:40
mexoboy вне форума Посмотреть профиль Отправить личное сообщение для mexoboy Найти все сообщения от mexoboy
  № 28  
Ответить с цитированием
mexoboy

Регистрация: Dec 2009
Сообщений: 48
cpu, неужто открыл для себя книгу "Банды четырех"?

Старый 06.04.2010, 17:48
cpu вне форума Посмотреть профиль Отправить личное сообщение для cpu Найти все сообщения от cpu
  № 29  
Ответить с цитированием
cpu

Регистрация: Mar 2010
Сообщений: 223
mexoboy пора когда-то это делать.)

Старый 06.04.2010, 17:52
Котяра вне форума Посмотреть профиль Отправить личное сообщение для Котяра Посетить домашнюю страницу Котяра Найти все сообщения от Котяра
  № 30  
Ответить с цитированием
Котяра
буду краток
 
Аватар для Котяра

модератор форума
Регистрация: Sep 2003
Адрес: Ближайшее Замкадье
Сообщений: 3,110
Записей в блоге: 28
Отправить сообщение для Котяра с помощью ICQ Отправить сообщение для Котяра с помощью Skype™
Цитата:
Сообщение от Psycho Tiger Посмотреть сообщение
2) Да, действительно - вьюшка может менять что нибудь у модели и контроллер сойдёт с ума - получается, у этой триады даже пиша вьюшку надо быть аккуратным, потому что можешь всё сломать?
передавать в вид только IModel в котором, например,есть один только метод addChangeModelEventListener
сломать конечно можно но это будет уже очень явно.
__________________
Отряд Котовскага

Создать новую тему Ответ Часовой пояс GMT +4, время: 19:21.
Быстрый переход
  « Предыдущая тема | Следующая тема »  
Опции темы
Опции просмотра

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.


 


Часовой пояс GMT +4, время: 19:21.


Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2024, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.