фон текстового поля

[zelik]

я имел ввиду, если захочется изменить длину "бегущей строки" (т.е. ) длину маски

var pole_txt:TextField = container.createTextField("pole_txt", xpos, yscale-10, ypos+10, 180, 25);
....
 
	} else {
			pole_txt._x = yscale-10;
		}

не знаю, может не прав...

[KiL33]

Исправил, смотри последний вариант, я его заменил.

Добавлено через 3 часа 52 минуты
Тебе сегодня просто сказочно везёт. Мой IQ редко поднимается за -1, но сегодня у меня просто мозговой штурм, поэтому вот ещё один апдейт к бегущей строке.

Исправил косяки и доработал..

Чёб ето в полной мере использовать, тебе нужно создать кнопочку и в библиотеке, в Linkage обозвать её как str.

txt файл должен выглядеть так

message1=Это первое сообщение.&message2=Demiart - Photoshop Форум - лучший форум о Photoshop в RUнете!!!

//Бегущая строка на все случаи жизни!:)
//Автор: KiL33 
 
//Загрузили в messageURL какой-то txt
messageURL = "text.txt";
//Какое сообщение показываем первым
message_num = 1;
//Размер бегуще строки в процентах
size_mc = 120;
//Длина бегущей строчки
xscale = 280;
//Скорость бегущей строчки
speedLine = 2;
//Позиция бегущей строки по _x
xpos = 110;
//Позиция бегущей строки по _y
ypos = 10;
//Границы текстового поля true-показать; false-убрать
txt_border = true;
//Цвет текста___после 0x[ваш Цвет]
txt_color = 0x00000;
 
//Cоздаём пустой МувиКлип
var fon:MovieClip = this.createEmptyMovieClip("fon_mc", 1);
fon._xscale = size_mc;
fon._yscale = size_mc;
//Создаем Мувики для аттача стрелок на сцену
var mc:MovieClip = fon.attachMovie("str", "str", 998, {_alpha:100, _x:xpos+xscale-15, _y:ypos+35});
var mc2:MovieClip = fon.attachMovie("str", "str2", 999, {_alpha:100, _x:xpos+xscale-25, _y:ypos+35});
mc2._xscale = -100;//Переворачиваем кнопку
//Кнопка Следующее сообщение
mc.btn.onPress = next_message;
function next_message():Void {
	counter++;
	success();
}
//Кнопка Предыдущее сообщение
mc2.btn.onPress = prev_message;
function prev_message():Void {
	counter--;
	success();
}
//Аттачим мувик выступающий в роли фона
var mc_fon:MovieClip = fon.attachMovie("fon", "fon", 1, {_alpha:100, _x:xpos, _y:ypos+10});
mc_fon._xscale = xscale;
var container:MovieClip = fon.createEmptyMovieClip("text_mc", 2);
//Создаём текстовое поле в которое будет грузиться из нашего txt информация
var pole_txt:TextField = container.createTextField("pole_txt", xpos, xscale+xpos, ypos+10, 180, 25);//180,25
 
//Настраеваем поля
pole_txt.autoSize = true;//автоматическое выравнивание текстого поля
pole_txt.html = true;//наше текстовое поле понимает html тэги
pole_txt.selectable = false;//выделение текста
pole_txt.border = txt_border;//границы поля
pole_txt.textColor = txt_color;//цвет текста
//Создаём мувик-маску для скрытия уходящих за пределы маски букв
var maska:MovieClip = fon.createEmptyMovieClip("maska_mc", 3);
//Рисуем в мувиКлипе прямоугольник
maska.beginFill(0xFF0000);
maska.moveTo(10,10);
maska.lineTo(xscale,10);
maska.lineTo(xscale,55);
maska.lineTo(10,55);
maska.lineTo(10,10);
maska.endFill();
maska._x = xpos;
maska._y = ypos;
//Сделали мувик маской и применили к text_mc
fon_mc.setMask(maska);
//Загружаем текст из text.txt
var myVars:LoadVars = new LoadVars();
//Если загрузка закончена
myVars.onLoad = success;
function success():Void {
	if (typeof (myVars["message"+counter]) != "string") {
		counter = message_num;
	}
	pole_txt.text = myVars["message"+counter];
	//Получили длину текстового поля
	var_num = "-"+pole_txt._width;
	go();
}
myVars.load(messageURL);
//Функция запускающая onEnterFrame и соответственно движение нашей бегущей строчки.
function go():Void {
	container.onEnterFrame = function() {
		if (pole_txt._x>var_num) {
			pole_txt._x -= speedLine;
		} else {
			pole_txt._x = xscale+xpos;
			counter++;
			success();
		}
	};
}

[KiL33]

А вообщем вот исходник__

[zelik]

А какие косяки были в предыдущей версии, а то я уже ее под свои нужны наладил..?

Еще один вопрос, правда, не в тему.
Есть 2 картинки (jpg), например, небо и воздушный шарик.
Нужно, чтобы шарик то был на небе, то не было.
Т.к. шарик не прямоугольник, то с картинкой будет идти фон прямоугольника, в который вписан шарик. Как-нибудь можно сгруппировать небо и шарик?

[KiL33]

А какие косяки были

После "Прекрасной ночи.." я уже не помню, где я там накосячил, но вложенный сейчас вариант исправляет ещё пару косяков)))

Добавил:
- Цвет подложки(фон текста)
- Прозрачность подложки(фон текста)
- Управление навигацией <> true-показать кнопочки; false-убрать
- Исправил косяки

Мне не всегда получается понять твои вопросы с первого раза..вот и сейчас тоже самое)))

шарик не прямоугольник

Это нонсенс, НЕВЕРЮ!))

[zelik]

Извиняюсь за свой корявый язык... Так уж выходит.
Я посылаю пример. Там просто две картинки, и вопрос понятен невооруженный взглядом (как убрать фон у "доски с гвоздями".

[KiL33]

Есть три выхода..

1. Либо ctrl+b и обрисовка картинки по контуру
2. Если устроит, можно картинку преобразовать в мувиКлип и в свойствах(properties) Мувика установить Blend>Multiply
3. Использовать blendMode, смотри в хелпе всё есть

[zelik]

Спасибо!
Еще раз убедился, что о флеше ничего не знаю...

Есть еще вопрос. Но, видимо, для этого начну новую тему.
До встречи
Еще раз спасибо за все!