копирование объектов

[skyman000]

просмотрел на форуме как копировать объект
попытался воспроизвести

package 
{
	import flash.display.*;
	import flash.net.URLRequest;
	import flash.events.*;
	import flash.text.*;
 
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
 
			// создал текстовое поле
			var progressOut:TextField = new TextField();
			progressOut.autoSize = TextFieldAutoSize.LEFT;
			progressOut.border = true;
			progressOut.background = true;
			progressOut.selectable = false;
			progressOut.text = "Loa45645654";
 
			// сунул текстовое поле  в  спрайт
			var ho:Sprite = new Sprite();
			ho.addChild(progressOut);
 
 
 
			// попытался скопировать спрайт 
			var ClassR:Class = (ho as Object).constructor as Class;
			var dup:Sprite = new ClassR() as Sprite;
 
			// вывожу копию спрайта на экран и  получается фейл – экран пустой
			addChild(dup);
 
		}
	}
}

что я сделал не так?

спрайт должен быть виден
если поменять addChild(dup); на addChild(ho);
то я вижу оригинал а вот копии не видно...

[-De-]

Это не копирование. Это создание такого же класса. ho = new Sprite(); - значит, что ho - это спрайт. Потому dup - это тоже спрайт. Просто спрайт, по умолчанию пустой. Если бы ho - был наследник спрайта, в котором при создании в конструкторе бы добавлялся TextField, то вы бы при создании тоже получили бы наследника спрайта с текстфилдом.
Копирование делается так: создается класс такой же, как и копируемый (это сделано) и над ним совершаются такие же действия как и над копируемым (т.е. в вашем случае создается текстовое поле и добавляется).

[scarbo]

Main.as

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * ...
	 * @author Sscarbo
	 */
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
			var sprite0:CustomSprite = new CustomSprite();
			var sprite1:CustomSprite = sprite0.copy();
			this.addChild(sprite1);
		}
 
	}
 
}

CustomSprite.as

package  
{
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
 
	/**
	 * ...
	 * @author Sscarbo
	 */
	public class CustomSprite extends Sprite 
	{
		protected var progressOut:TextField;
 
		public function CustomSprite() 
		{
			super();
			this._createChildren();
		}
 
		public function copy():CustomSprite {
			return new CustomSprite();
		}
 
		protected function _createChildren():void {
			this.progressOut = new TextField();
			this.progressOut.autoSize = TextFieldAutoSize.LEFT;
			this.progressOut.border = true;
			this.progressOut.background = true;
			this.progressOut.selectable = false;
			this.progressOut.text = "Loa45645654";
			this.addChild(this.progressOut);
		}
	}
 
}

блин, опаздал.

[skyman000]

Большое спасибо за ответы
но я виноват я не уточнил для какой именно задачи мне надо создать копию

моя задача загрузить одну картинку и затем размножить ее.
Загрузить можно лишь 1 раз

вот примерно так

package 
{
	import flash.display.*;
	import flash.net.URLRequest;
	import flash.events.*;
	import flash.text.*;
	import flash.utils.ByteArray;
 
	public class Main extends Sprite 
	{
		public function Main():void 
		{			
			var loader:Loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.INIT, init);
			var urlR:URLRequest = new URLRequest("33.jpg");
			loader.load(urlR);	
		}
 
		function init(e:Event):void
		{
			var b:Bitmap = clone(e.target.content) as Bitmap;
			addChild(b);
		}
 
		function clone(source:Object):* {
			var copier:ByteArray = new ByteArray();
			copier.writeObject(source);
			copier.position = 0;
			return(copier.readObject());
		}
 
	}
}

но этот код не работает =(

как создать точно такую же Bitmap из имеющейся?
при условии что загрузить можно лишь раз

Добавлено через 31 минуту
короче я додумался сам =)

вы меня подтолкнули к верному пути

		function init(e:Event):void
		{
 
			var a1:Bitmap = this.clone(e.target.content);
			var a2:Bitmap = this.clone(e.target.content);
 
			addChild(a1);
			addChild(a2);
 
			a1.x += 100;
		}
 
		function clone(sz:Bitmap):Bitmap {
			var c:BitmapData = sz.bitmapData.clone();
			return new Bitmap(c);
		}

вот все заработало.

я просто думал есть какой то другой способ копирования)

[scarbo]

http://help.adobe.com/ru_RU/FlashPla...ml#clone%28%29

Добавлено через 3 минуты
Вообще для вашего случая, надо создать ResourceManager который все загружает и хранит в себе, остальные классы приложения его просто опрашивают. Тигра создавал в этом топике тему, можно ее найти, там есть хорошие идеи.

[skyman000]

я его как раз и пишу =)
и вот для полной картины мне не хватало как раз понять как копировать объекты

но сейчас почти все готово

а тему я поищу может что полезного найду