Ошибка при использовнии интерфейса

[Mihay]

Здравствуйте, учусь программированию ActionScript 3.0 по книге Колина Мука. Все шло хорошо, до тех пор пока я не стал изучать интерфейсы. Привожу свои коды, потом задам вопрос, если кто знает в чем причина ошибки, пожалуйста объясните! Заранее благодарю!

Задача состоит в следующем
1. Собрать объекты для сохранения
2. Преобразовать каждый объект в строку (вызвав метод serialize())
3. Перенести объекты на диск


Код интерфейса находиться в файле Serializable.as

package  logout
{
	public interface Serializable  //  Интерфейс содержит 1 метод
	{
        function serialize() : String; 
	}
}

Код класса, реализующего интерфейс Serializable находиться в файле serializer.as

package logout 
{
	// Класс реализует интерфейс Serializable
	public class serializer implements Serializable
	{
		private var serializationVars : Array; // Массив переменных, которые выводятся в строку (сериализируются)
        private var serializationObj : Serializable; // Указывет объект интерфейса, который сериализируется
		private var recordSeparator : String; // Строка разделителя между переменными
 
		public function serializer() 
		{
			// constructor code
			super();
			setSerializationObj(this) // Указывает объект для сериализации
		}
 
		public function setSerializationVars(vars : Array) : void // Указывает, какие переменные должны быть сериализованы
		{
			serializationVars = vars;
		}
 
        public function setSerializationObj(obj : Serializable) : void // Указывает объект для сериализации
		{
			serializationObj = obj;
		}
 
        public function setRecordSeparator(rs : String) : void // устанавлвивает строку разделителя между переменными
		{
			recordSeparator = rs;
		}
 
	    public function serialize() : String // возвращает строку, представляющую объект
		{
			var s : String = "";
			for (var i:int = serializationVars.length; i >= 0; i--)  // обратный отсчет выводимых переменных
			{
				s += serializationVars[i] + " = " + String(serializationObj[serializationVars[i]]);
				if (i > 0)
				{
					s += recordSeparator;
				}
			}
			return s;
		}
	}
}

Код класса моего объекта Points, который я хочу сериализовать, находиться в файле Points.as:

package logout {
 
	public class Points implements Serializable
	{
        public var xp : Number = 0;
		public var yp : Number = 0;
		private var Serializer : serializer;
		public function Points(xp : Number, yp : Number)
		{
			// constructor code
			super();
			Serializer = new serializer();
			Serializer.setRecordSeparator(" | "); 
			Serializer.setSerializationVars(["x = ", "y = "]);
			this.xp = xp;
			this.yp = yp;
			Serializer.setSerializationObj(this); 
		}
 
		public function serialize() : String
		{
			return Serializer.serialize();
		}
 
	}
}

И наконец главный класс main, который по идее должен сериализовать объект Points, находиться в файле main.as

package logout 
{
	import flash.display.Sprite;
	public class main extends Sprite
	{
        public var P : Points = new Points(12, 13); 
		public function main(): void 
		{
			// constructor code
			super();
			trace("Козел!!");
			trace(P.serialize());
		}
 
	}
 
}

В итоге в строке отладчика выводится следующее

Козел!!
ReferenceError: Error #1069: Не удалось найти свойство undefined в logout.Points; отсутствует значение по умолчанию.
at logout::serializer/serialize()
at logout::Points/serialize()
at logout::main()

Слово "Козел!!" я вывел специально для себя, чтоб убедиться что main.as -работает

Вопросы: Что за сообщения выводятся при выполнении программы??? Что я не так делаю с интерфейсом??? И вообще, где ошибки?????

[alexcon314]

Код нужно оформлять тэгами [as3][/as3].

[dendrit]

Вам стоит придерживаться стандартов наименования классов и переменных: классы всегда с большой буквы, переменные - с маленькой.

Ошибка в Serializer.setSerializationVars(["x = ", "y = "]);
Позже эти строки используются так: serializationObj[serializationVars[i]]
Т.е. в объекте Points код ищет переменные "x = " и "y = ". Таких, естественно нет. Есть только xp и xy.
Так наверняка заработает: Serializer.setSerializationVars(["xp", "yp"]);

P.S. "Козел" - весьма интеллектуально.

[dimarik]

Определитесь: "находиться" или "находится"? Это важно!!!!

[Mihay]

Сообщение от dendrit

Вам стоит придерживаться стандартов наименования классов и переменных: классы всегда с большой буквы, переменные - с маленькой.

Это я учту!

Сообщение от dendrit

Ошибка в Serializer.setSerializationVars(["x = ", "y = "]);
Позже эти строки используются так: serializationObj[serializationVars[i]]
Т.е. в объекте Points код ищет переменные "x = " и "y = ". Таких, естественно нет. Есть только xp и xy.
Так наверняка заработает: Serializer.setSerializationVars(["xp", "yp"]);

Не заработало.

Я так понимаю, что в setSerializationVars() - перечисление всех поясняющих строковых данных для метода serialize(). Например для Points(2, 5) serialize() при помощи setSerializationVars(["x = ", "y = "]) выведет x = 2 y = 5. А при помощи setSerializationVars(["xp", "yp"]) serialize() выведет хр 2 yp 5.

Или я, козел, чего-то недопонимаю?
В том или ином случае выдает те же ошибки!

Добавлено через 4 минуты

Сообщение от dimarik

Определитесь: "находиться" или "находится"? Это важно!!!!

Извините за не точность - класс или интерфейс * находится в файле *.as

Добавлено через 1 час 29 минут
Вы были правы насчет:

Сообщение от dendrit

Так наверняка заработает: Serializer.setSerializationVars(["xp", "yp"]);

Так должно было быть, теперь я понял суть Serializer.setSerializationVars(["xp", "yp"]).

НО не работало оно по одной банальной причине, которую я как программист C++ упустил.
В книге Колина Мука в коде метода serialize() (код в 1-ом сообщении) была допущена ошибка, на которую я не обратил внимания, а именно в строке for (var i:int = serializationVars.length; i >= 0; i--). Длина массива не serializationVars.length, а serializationVars.length-1, если по правилам 1-ый элеменет массива считается элемент с индексом 0. Переписав эту строку в такой вид for (var i:int = serializationVars.length-1; i >= 0; i--) - все заработало!!!! Козел - отменяется!!!!!!!!