Загрузка изображения на стену пользователя

[O.K.]

У меня мистически заработала стена после смены кода на

mpLoader.addFile(img_to_post, "photo.jpg", "photo");

но теперь этим же скриптом пытаюсь грузить в альбом - не пашет!
работало раньше вот так

mll.addFile(byteArray, "file1.jpg", "photo", 'image/jpg');

но это для стены не работало, теперь это и для альбома не пашет...

Добавлено через 38 часов 16 минут
Хоть меняй название, хоть не меняй - всёравно на стену грузит - в альбом нет

[RAlfDog]

Так для альбома там совсем по другому загрузка происходит, там API рассчитано на загрузку сразу нескольких файлов массивом.
Оно и конечно работать не будет.

Мой работающий код аплоада на сервер ВК и сохранения в альбом:

//
        static public function savePhotoToAlbum(pic:BitmapData = null, aid:String = null)
        {
            pic_to_post = pic;
 
            SenderVKAPI.dispatcher.addEventListener(SenderVKAPIEvent.COMPLETE_EVENT, _onGetUploadServer);
            SenderVKAPI.sendPost("photos.getUploadServer", ["aid"], [aid]);
        }
 
        static protected function _onGetUploadServer(ev:SenderVKAPIEvent)
        {
            SenderVKAPI.dispatcher.removeEventListener(SenderVKAPIEvent.COMPLETE_EVENT, _onGetUploadServer);
            var answer:XML = new XML(ev.answer);
            sendPicsToServer(pic_to_post, ParserVKAPI.photos_getUploadServer(answer));
        }
 
        static private function sendPicsToServer(pic:BitmapData, data:Array)
        {
            var img_to_post:ByteArray = PNGEncoder.encode(pic);
 
            mpLoader = new MultipartURLLoader();
            mpLoader.addFile(img_to_post, "file1.png", "file1");
            try {
 
                mpLoader.addEventListener(Event.COMPLETE, _onSendPicsToServerHandler);
                mpLoader.load(data[0]);
            } catch (e:Error) {
                trace(e);
            }
        }
 
        static protected function _onSendPicsToServerHandler(ev:Event)
        {
            var answer:String = mpLoader.loader.data;// ev.target.data;
 
            var data:Object = JSON.decode(answer);
            if (data.error) {
 
            }else{
 
                finalSavePhoto([data["server"], data["photos_list"], data["aid"], data["hash"]]);
            }
        }
 
        static public function finalSavePhoto(data:Array)
        {
            SenderVKAPI.dispatcher.addEventListener(SenderVKAPIEvent.COMPLETE_EVENT, _onfinalSavePhoto);
            SenderVKAPI.sendPost("photos.save", ["server", "photos_list", "aid", "hash"], data);
        }
 
        static public function _onfinalSavePhoto(ev:SenderVKAPIEvent)
        {
            SenderVKAPI.dispatcher.removeEventListener(SenderVKAPIEvent.COMPLETE_EVENT, _onfinalSavePhoto);
            var answer:XML = new XML(ev.answer);
            createEvent(ParserVKAPI.photos_save(answer));
        }
 
        //

[O.K.]

Всё разобрался, спасибо там просто на стену кидать "photo" а в альбом "file1"