ByteArray фотографии для публикации на стене

[xpymbl4]

Использую класс, представленный здесь:
http://code.google.com/p/v-kontakte/...ostUploader.as
В метод upload передается параметр photo.
Моя задача - загружать в photo мувиклип (_mc), лежайщий на сцене.
Делаю так:

var bitmap:BitmapData = new BitmapData (_mc.width, _mc.height);
bitmap.draw(_mc);
var pngEncoder:PNGEncoder = new PNGEncoder();			
photo = pngEncoder.encode(bitmap);

И в результате загрузки сервер отдает callback.photo только в том случае, если в _mc нет ничего кроме простого заполненного Shape. Если в _mc много всяких объектов + например jpeg картинка, то уже не работает.
Подскажите пожалуйста, как вы формируете из мувиклипа красивую качественную картинку, отправляемую на стену.

[udaaff]

То, что у вас в битмап отрисовывается, то и должно отправляться, т.е. проверьте, что именно рисуется. Премудростей тут, вроде как, никаких нету.

[Mur4ik]

Может проблема в использовании PNGEncoder, если используете класс от адоба, то encode это статический метод и экземпляр класса создавать для этого не нужно. Т.е достаточно написать

photo = PNGEncoder.encode(bitmap);

[xpymbl4]

_mc содержит подгруженное изображение.
Не работает draw.
Читаю форум. Ищу ответ. Спасибо

Добавлено через 25 минут
Может кто уже формировал картинку из мувиклипа, в котором содержится подгруженное изображение?
Доступа к файлу политики, откуда грузится изображение - нет.
Существует ли выход из сложившейся ситуации?

[Mur4ik]

Существует.

Абстрактный пример

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.system.ApplicationDomain;
	import flash.system.LoaderContext;
 
	public class FuckCrossDomain extends Sprite
	{
		private var _loader:Loader;
 
		public function FuckCrossDomain() 
		{
			if (stage) initInstance(null);
			else addEventListener(Event.ADDED_TO_STAGE, initInstance);
		}
 
		private function initInstance(event:Event):void
		{
			_loader = new Loader();
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_completeHandler);
 
			_loader.load( new URLRequest("http://ссылка/на/картинку.jpg") );
		}
 
		private function loader_completeHandler(event:Event):void 
		{
			_loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, loader_completeHandler);
 
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_loadBytesCompleteHandler);
			_loader.loadBytes(_loader.contentLoaderInfo.bytes, new LoaderContext(false, ApplicationDomain.currentDomain));
		}
 
		private function loader_loadBytesCompleteHandler(event:Event):void 
		{
			_loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, loader_loadBytesCompleteHandler);
 
			// и вот туту уже можно с _loader или _loader.content рисовать в битмапдату без 
 
			var bmd:BitmapData = new BitmapData(_loader.width, _loader.height, true, 0);
			bmd.draw(_loader.content);
 
			addChild( new Bitmap(bmd) );
		}
	}
}