Форум Flasher.ru
Ближайшие курсы в Школе RealTime
Список интенсивных курсов: [см.]  
  
Специальные предложения: [см.]  
  
 
Блоги Правила Справка Пользователи Календарь Поиск рулит! Сообщения за день Все разделы прочитаны
 

Вернуться   Форум Flasher.ru > Flash > FAQ

Версия для печати  Отправить по электронной почте    « Предыдущая тема | Следующая тема »  
Опции темы Опции просмотра
 
Создать новую тему Ответ
Старый 19.05.2006, 15:33
Nirth вне форума Посмотреть профиль Отправить личное сообщение для Nirth Посетить домашнюю страницу Nirth Найти все сообщения от Nirth
  № 1  
Ответить с цитированием
Nirth
4AM Games
 
Аватар для Nirth

блогер
Регистрация: Nov 2002
Адрес: Sofia
Сообщений: 6,264
Записей в блоге: 1
Отправить сообщение для Nirth с помощью ICQ Отправить сообщение для Nirth с помощью AIM Отправить сообщение для Nirth с помощью MSN Отправить сообщение для Nirth с помощью Yahoo Отправить сообщение для Nirth с помощью Skype™
По умолчанию [as3] Загрузка SWF и изображений в фильм

Класс flash.display.Loader используется для загрузки *.swf файлов, а так же для загрузки картинок(jpeg, gif и png), для начала загрузки используйте метод load(), загруженный объект добавится в список детей экземпляра Loader, так же в данном классе есть свойство contentLoaderInfo ( экземляр класса flash.display.LoaderInfo ), которое содержит в себе данные, которые нам могут понадобиться для прелоадера (на самом деле свойства данного класса, могут дать нам практически исчерпывающую информацию о контенте, например версию ActionScript и тд).
Пример

Код:
package {
	//импортируем нужные нам классы
	import flash.display.Sprite; // это базовый класс для нашего root'а
	import flash.display.Loader; // в экземпляр данного класса будем грузить картинку
	import flash.display.LoaderInfo; // из экземпляра данного класса, будем брать информацию
	import flash.text.TextField; // в текстовом поле, будем отображать процесс загрузки
	import flash.text.TextFieldAutoSize; // тут константы вариантов значения свойства textField.autoSize
	import flash.net.URLRequest; // экземпляр данного класса, будет хранить в себе адресс картинки
	import flash.events.Event; // это событие
	import flash.events.ProgressEvent; 
	
	public class Test extends Sprite {
		//создаем экземпляр Loader
		private var loader:Loader = new Loader();
		//создаем экземпляр TextField
		private var loadStatus:TextField = new TextField();
		//создаем экземпляр URLReques
		private var request:URLRequest = new URLRequest("img.jpg");
		
		// конструктор
		public function Test() {
			//Начинаем загрузку
			loader.load(request);
			// подписываем обработчики события
			loader.contentLoaderInfo.addEventListener(Event.OPEN,displayPreloader);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS,updatePreloader);
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE,displayImage);
		} 
		//наши обработчики событий
		private function displayPreloader(evt:Event):void {
			//добавляем текствое поле
			loadStatus.autoSize = TextFieldAutoSize.LEFT;
			addChild(loadStatus);
		}
		
		private function updatePreloader(evt:ProgressEvent):void {
			//изменяем информацию в процессе загрузки
			loadStatus.text = "loaded:"+evt.bytesLoaded+" from "+evt.bytesTotal;
		}
		
		private function displayImage(evt:Event):void {
			//удаляем текстовое поле, и добавляем само изображение
			removeChild(loadStatus);
			addChild(loader);
		}		
	}
}
__________________
Я перестал переписывать, начал редактировать, еще лет 15 и я стану писателем ^_^


Последний раз редактировалось dimarik; 26.03.2016 в 00:15.
Создать новую тему Ответ Часовой пояс GMT +4, время: 00:49.
Быстрый переход
  « Предыдущая тема | Следующая тема »  
Опции темы
Опции просмотра

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.


 


Часовой пояс GMT +4, время: 00:49.


Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2024, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.