Вопрос от новичка - как вписать код в класс.

[SergVrn]

Здравствуйте.
Помогите решить вопрос.

Суть вопроса такая.
Нашел на сайте код.
Как этот код вписать в класс?
То есть на какую кнопку нажать, чтобы открылось окно класса и чтобы туда можно было бы записать код ?
(я обычно нажимаю F9 - но то меню, которое открывается - это судя по всему окно кадра, а не класса)

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.SoundTransform;
 
    public class Main extends Sprite {
        private var videoURL:String = "111.mp4";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var volume:Number;
 
        public function Main() {
            volume = 1;
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            stage.addEventListener(MouseEvent.CLICK, onClick);
        }
 
        private function onClick(e:MouseEvent):void{
            volume+=0.2;
            if(volume>1){
                volume = 0;
            }
            setVolume(volume);
        }
 
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
 
        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
 
        }
 
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
 
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
        private function setVolume(volume:Number):void {
            trace("setVolume: " + volume.toFixed(2));
            var transform:SoundTransform = stream.soundTransform;
            transform.volume = volume;
            stream.soundTransform = transform;
 
 
        }
    }
 }

[caseyryan]

Это и есть под класса. Его название (Main) нужно указать в поле document class

[SergVrn]

Ясно.
Спасибо.