еще один баг...

[searinox]

Может мне кто-то пояснить что я делаю неправильно? Или я наткнулся на очередной баг флеша?
как обычно, для наглядности приведу код:

package test
{
    public class SendMessage
    {
        public static const TITLE_ID:uint = 2;
    }
}
 
package test
{
    public class ForwardMessage
    {
        public static const TITLE_ID:uint = 7;
    }
}
 
package test
{
    public class MessageController
    {
		private var messageClass:Class;
 
        public function init(messageType:Class):void
        {
			messageClass = messageType;
        }
 
		//Не работает. titleId всегда 0.
		public function getTitleId():uint
		{
			var titleId:uint = messageClass.TITLE_ID;
			return titleId;
		}
 
 
		// Тоже не работает(Ни одно из условий не удовлетворяется), догадываюсь почему, нохотелось бы услышать правильный ответ.
		public function getTitleId1():uint
		{
			var titleId:uint = 666;
			if(messageClass is SendMessage)
			{
				titleId = SendMessage.TITLE_ID;
			}
			else if(messageClass is ForwardMessage)
			{
				titleId = ForwardMessage.TITLE_ID;
			}
			return titleId;
		}
 
		//Работает.
		public function getTitleId2():uint
		{
			var titleId:uint = 666;
			if(messageClass == SendMessage)
			{
				titleId = SendMessage.TITLE_ID;
			}
			else if(messageClass == ForwardMessage)
			{
				titleId = ForwardMessage.TITLE_ID;
			}
			return titleId;
		}
 
    }
}
 
package test
{
    import test.SendMessage;
    import test.ForwardMessage;
 
    public class Main
    {
 
 
        public function Main()
        {
			var control:MessageController = new MessageController();
			control.init(SendMessage);
			trace(control.getTitleId());  // 0
			trace(control.getTitleId1()); // 666
			trace(control.getTitleId2()); // 2
			control.init(WriteMessage);
			trace(control.getTitleId());  // 0
			trace(control.getTitleId1()); // 666
			trace(control.getTitleId2()); // 7
        }
    }
}

Вопрос, как написать правильно что бы не нужно было использовать ифы(работал getTitleId() метод).

[maincode]

//Не работает. titleId всегда 0.
public function getTitleId():uint
{
	var titleId:uint = messageClass.TITLE_ID;
	return titleId;
}

Здесь у меня выдает нормальное значение, попробуйте так messageClass["TITLE_ID"]. И какой компилятор используете ?

if(messageClass is SendMessage)

Т.к. messageClass у вас это сам класс поэтому данная конструкция не возвращает true, is покажет true в том случае, если messageClass будет экземпляром класса SendMessage, т.е. если написать так:

var message:SendMessage = new SendMessage();
if (message is SendMessage) {
   // true
}

Или так:

var message:* = new messageClass();
if (message is SendMessage) {
   // true
}

[cleptoman]

private const HASH:Dictionary = new Dictionary();

...
в констуркторе

HASH[SendMessage] = SendMessage.TITLE_ID;
HASH[ForwardMessage] = ForwardMessage.TITLE_ID;

...

public function getTitleId2():uint{
 return HASH[messageClass] || 666;
}

Добавлено через 2 минуты
небольшая поправочка...с нулем может последняя конструкция некорректно сработать. т.е. если ожидается нуль как возвращаемое значение..так просто его не дождетесь

[AlexLucas]

У меня всё работает. Вы где-то опечатались. У вас в примере сначала ForwardMessage, а в Main вызывается WriteMessage.
messageClass не кастуется к другому классу потому что они все типа Class.

messageClass is Class //даст true

[searinox]

Сообщение от maincode

//Не работает. titleId всегда 0.
public function getTitleId():uint
{
	var titleId:uint = messageClass.TITLE_ID;
	return titleId;
}

Здесь у меня выдает нормальное значение, попробуйте так messageClass["TITLE_ID"]. И какой компилятор используете ?

if(messageClass is SendMessage)

Т.к. messageClass у вас это сам класс поэтому данная конструкция не возвращает true, is покажет true в том случае, если messageClass будет экземпляром класса SendMessage, т.е. если написать так:

var message:SendMessage = new SendMessage();
if (message is SendMessage) {
   // true
}

Или так:

var message:* = new messageClass();
if (message is SendMessage) {
   // true
}

Использую обычный флекс 4.1 компайлер. Как ни крути но не получается получить что-то отличное от 0 в 1 методе.
На счет Дикшионари - мне совершенно не подходит.