можно узнать ширину импортированной картинки ?

[dadli]

привет
с помошю етого скрипта я импортирую картинку во флеш:

var loader = new MovieClipLoader;
var obiect = new Object;
loader.loadClip("papka/pic0.jpg",clip);
 
obiect.onLoadProgress = function(clip,bytesLoaded,totalBytes) {
	_root.loadinganimation.gotoAndStop(Math.round(bytesLoaded/totalBytes*100));
}
obiect.onLoadComplete = function(clip) {
	delete loader;
	delete obiect;
}
loader.addListener(obiect);

вот вопрос:
можно ли узнатъ ширину, импортированнои картинки? если да как?

[i.o.]

obiect.onLoadComplete = function(clip) {
	trace(clip._width);
	trace(clip._height);
 
	delete loader;
	delete obiect;
}

[dadli]

i.o. спасибо )

[i.o.]

i.o. спасибо )

Пожалуйста.
Я по памяти. Точно ли это работает?)

[dadli]

ох, ( не работает к сожеленю, нули (0) пишет оутпут

[i.o.]

Вот из справочки пример:

var loadListener:Object = new Object();
 
loadListener.onLoadComplete = function(target_mc:MovieClip, httpStatus:Number):Void {
    trace(">> loadListener.onLoadComplete()");
    trace(">> =============================");
    trace(">> target_mc._width: " + target_mc._width);    // 0
    trace(">> httpStatus: " + httpStatus);
}
 
loadListener.onLoadInit = function(target_mc:MovieClip):Void {
    trace(">> loadListener.onLoadInit()");
    trace(">> =============================");
    trace(">> target_mc._width: " + target_mc._width);    // 315
}
 
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(loadListener);
 
var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mcLoader.loadClip("http://www.w3.org/Icons/w3c_main.png", mc);

Т.е. нужно подписаться еще и на onLoadInit

[dadli]

а так точно работает, onLoadInit помагло
огромное спасибо i.o.