Можно ли создать на сцене мувик из библиотеки загруженного SWF?

[FlashWizard]

Допустим я сделал мувиклип (он только в библиотеке), скомпилировал SWF. Теперь гружу этот SWF в другой. Можно ли в другом добавить этот мувиклип в список отображения родительского SWF? Спасибо.

[HardCoder]

Если этот мувик экспортирован в ActionScript, то да, а если нет - его в этом swf вообще не будет.

[FlashWizard]

Ну понятное дело, что экспортирован в AS он будет. Теперь как его добавить в список отображения? Т.е. как его достать из библиотеки загруженного SWF?

[HardCoder]

Ну, я делаю всегда вот так (хотя может есть и другие способы):
В подгружаемом swf создаете класс MC1:

package {
	import flash.display.Sprite;
 
	public class MC1 extends Sprite {
		public function someFunc():void {
			trace("I am MC1");
		}
	}
}

Потом в библиотеке "привязываете" ваш клип к этому классу, компилируете...
В главном приложении пишете:

package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.display.Loader;
 
 
	public class Main extends Sprite {
		private var loader:Loader;
		public function Main() {
			loader = new Loader  ;
			loader.load(new URLRequest("myswf/MySwf.swf"));
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE,completeHandler);
		}
		private function completeHandler(e:Event):void {
			var MC1:Class = loader.contentLoaderInfo.applicationDomain.getDefinition("MC1") as Class;
			var clip=new MC1();
			clip.someFunc()//выводит "I am MC1"
			addChild(clip);
		}
	}
}

И при создании переменной clip, не определяйте тип - сломается

[FlashWizard]

Ок, спасибо. А если в этом мувике используются допустим растровые картинки и другие мувики, которые также имеются в библиотеке подгружаемого, они тоже автоматически попадут в родительский SWF?

[HardCoder]

100 процентов

[FlashWizard]

Да, всё работает. Спасибо.

[bav]

Еще можно посмотреть в сторону swc, хотя, судя по всему, это не относиться напрямую к обсуждаемой теме.

[GBee]

И при создании переменной clip, не определяйте тип - сломается

DisplayObject по идее можно.

[HardCoder]

Сообщение от GBee

DisplayObject по идее можно.

Действительно можно, но я в примере написал метод somefunc() это так - если нужно будет обращаться к свойствам и методам этого класса. И тогда следующее: в строке

clip.someFunc();

компилятор ругается что нет такого метода в DisplayObject.