"умное" позиционирование объектов, созданных массивом

[Dr_Bra]

Привет, всем!
Помогите разобраться, как можно организовать "умное" позиционирование объектов внутри контейнера.
С помощью массива и xml загрузили 10 объектов

private function xmlLoaded(e:Event):void
		{
			galeryLoader.removeEventListener(Event.COMPLETE, xmlLoaded);
 
			galeryXML = new XML(e.target.data);
			galery = galeryXML.imgs.attributes();
			numImgs = galery.length();
 
			getGalery();
			conversGalery();
		}

private function getGalery():void
		{
			var galeryArrey = new Array();
			for(var i:int = 0; i < numImgs; i ++)
			{
				imageLoader =  new Loader;
				imageLoader.load(new URLRequest(galery[i]));
				galeryArrey.push(imageLoader);					
				cont.addChild(imageLoader);
                                imageLoader.name = "img"+[i];//что бы потопм обратиться
				//trace(imageLoader.name);
			}
		}

не хватает представления, как написать метод сonversGalery!



Что бы этот метод (conversGalery) расставлял объекты в контейнере по принципу:
размещаем ровное число загруженных объектов по stage.StageWidth в строку, если объекты не помещаются в одну строку – продолжаем размещать строкой ниже.

создаем 2 переменные:

private var row:int = 0;//колличество строк 
private var column:int = 0;//колличество объектов в строке

колличество объектов в строке мы определим так:

column = w / 350;
// где w – это stage.StageWidth
//а 350 – это длинна загружаемых объектов

[goodguy]

при добавлении кадого следующего изображения добавлять к какой-то переменной 1, и если число больше количества колонок, то переходить на следующий ряд, а значение этой переменной обнулять. То есть что-то типа:

 
addChild(image);
curentImage += 1;
if (curentImage == columns) {
     curentImage = 0;
     curentColumn = 0;
     curentRow += 1;
 
}

Естественно, это гипотетический код. Вам нужно будет придумать свой, но мысль тут довольна простая.

Кстати, цикл для таких целей не подходит, так как он работат намного быстрее, чем любой загрузчик может загружать картинки. Поэтому следующую картинку надо будет грузить только тогда, когда загрузится предыдущая

[КорДум]

Второй вариант - вторым циклом. i-j еще никто не отменял.

[goodguy]

Второй вариант - вторым циклом

Грузить картинки циклом?
Я понимаю расставлять уже загруженные. Но загрузить таким образом получится только последнюю картинку

[КорДум]

Помогите разобраться, как можно организовать "умное" позиционирование объектов внутри контейнера.

Вопрос именно про позиционирование.

[goodguy]

Но если посмотреть на код, то там именно загрузка

[Dr_Bra]

Например, мы загрузили циклом все картинки, они у нас на сцене, перекрывают друг друга в левом верхнем углу. После чего мы вызываем метод, который бы упорядочил все загруженные объекты.
Для этого нам нужно обратиться по имени к каждой картинке, я предположил что так может сработать:

 imageLoader.name = "img"+[i];

но из метода сonversGalery не получается к загруженным картинкам по имени, например:

private function сonversGalery():void
{
img1.x = 50; // не находит переменную с именем img1
}

таким бы образом мы запускали второй массив с переменной j и сделали попытку все объекты выстроить, так как нам нужно

[Psycho Tiger]

Писал давно, реализация кривовата. Тем не менее со своей задачей справляется.

package artshlagin.utils 
{
	import flash.display.DisplayObject;
	/**
	 * ...
	 * @author Artem Shlagin
	 */
	public class Placer
	{
 
		public function Placer() 
		{
			throw new Error("Class is static");
		}
 
		/**
		 * Распологает объекты прямоугольником, слева-направо, сверху-вниз.
		 * @param	displayObjects 	Массив DisplayObject`ов, которые нужно расставить
		 * @param	columns 	Число объектов в строке
		 * @param	widthBetween 	Расстояние между объектами по горизонтали
		 * @param	heightBetween 	Расстояние между объектами по вертикали
		 * @param 	startX 	стартовое x
		 * @param 	startY 	стартовое y
		 * @param	centerLast 	Центрировать ли последние объекты при неполном заполнении строки
		 */
		public static function horizontalRectangle(displayObjects:Array, columns:int, widthBetween:Number, heightBetween:Number, startX:Number = 0, startY:Number = 0, centerLast:Boolean = true):void {
			var i:int = displayObjects.length;
			var obj:DisplayObject;
			if (centerLast) {
				var oddNum:int = i % columns;
				//todo
				if (oddNum === 1) {
					obj = displayObjects[--i] as DisplayObject;
					obj.x = ((widthBetween * columns - widthBetween) >> 1) +startX;
					obj.y = Math.floor((i) / columns) * heightBetween + startY;
					//return;
					if (!i) return;
				}
				if (oddNum > 0) {
					//надо центрировать нижние
					var width:Number = widthBetween * (columns);
					var spacesNum:int = columns - oddNum;
					var halfFreeSpace:int = spacesNum * widthBetween >> 1;
					var paddingEffect:int = halfFreeSpace / oddNum;
					var padding:Number = (widthBetween * spacesNum) >> 1;
					while (oddNum--) {
						obj = displayObjects[--i] as DisplayObject;
						if (!obj) throw new ArgumentError("displayObjects contain non-DisplayObjects, i="+i);
						obj.x = oddNum * widthBetween + padding - halfFreeSpace + paddingEffect * (oddNum + 2) + startX;
						obj.y = Math.floor(i / columns) * heightBetween + startY;
					}
				}
			}
			while (i--) {
				obj = displayObjects[i] as DisplayObject;
				if (!obj) throw new ArgumentError("displayObjects contain non-DisplayObjects, i="+i);
				obj.x = (i % columns) * widthBetween + startX;
				obj.y = Math.floor(i / columns) * heightBetween + startY;
			}
		}
 
	}
 
}

[goodguy]

Сообщение от Dr_Bra

Например, мы загрузили циклом все картинки, они у нас на сцене, перекрывают друг друга в левом верхнем углу. После чего мы вызываем метод, который бы упорядочил все загруженные объекты.

Dr_Bra, вы вообще читаете ответы в теме?
Циклом невозможно загрузить картинки. Поэтому он и не находит первую. Ее просто нет. Она начинает грузиться, тут же цикл убивает ее загрузчик, создает новый и т.д.

и еще:

 imageLoader.name = "img"+[i];

Тамки образом не получится строка. Это нужно будет отдельно конверитить в строку:

 imageLoader.name = String("img"+[i]);

[Psycho Tiger]

Не запоминайте это:

и еще:
Код AS3:

imageLoader.name = "img"+[i];

Тамки образом не получится строка. Это нужно будет отдельно конверитить в строку:
Код AS3:

imageLoader.name = String("img"+[i]);

Запоминайте это: при сложении любого элемента со строкой получается строка.

Циклом невозможно загрузить картинки. Поэтому он и не находит первую. Ее просто нет. Она начинает грузиться, тут же цикл убивает ее загрузчик, создает новый и т.д.

Это где Вы такое увидели?

@Dr_bra:

imageLoader.name = "img"+i;//что бы потопм обратиться

Далее, по getChildByName.
Однако ещё лучше воспользоваться Вашим же galeryArrey. (galleryArray)

galeryArrey[i].x = 100;