один интервал для разных функций

[Маруська]

Необходим код, который проигрывает анимацию в прямом или обратном порядке в зависимости от позиционирования мыши относительно середины кадра.
Пока хочу написать хотя бы для постоянного интервала в полсекунды, чтобы кадры переключались и вперёд и назад с этим интервалом.
В общем-то всё работает, но висит, когда мышь перемещается по сцене. как это пофиксить?

import flash.utils.setInterval;
stage.addEventListener(MouseEvent.MOUSE_MOVE,аnimating);
 
function аnimating(e:MouseEvent):void {
	clearInterval(intervalId)
	if(stage.mouseX<stage.width/2){ intervalId= setInterval (goNext,speed);}
	else{intervalId = setInterval(goPrev,speed);}		
	// Update after event to ensure no lag
	e.updateAfterEvent();
}
 
function goNext():void{
	 if (foranim.currentFrame < foranim.totalFrames)
       foranim.gotoAndStop(foranim.currentFrame + 1);
    else
        foranim.gotoAndStop(1);
		trace("going left "+foranim.currentFrame)}
 
function goPrev():void{
	 if (foranim.currentFrame >1)
       foranim.gotoAndStop(foranim.currentFrame - 1);
    else
        foranim.gotoAndStop(foranim.totalFrames);
		trace("going right "+foranim.currentFrame)}
var intervalId:uint	
var speed:int=50;

[Wolsh]

Ну, сейчас у Вас интервалы просто не успевают сработать, как уже отменяются (при движении мыши).
Попробуйте использовать Timer, меняя его delay без перезапуска.

[Vreden]

Добавьте условие в функцию animating, которое проверяет, изменилось ли направление и только тогда отменяйте setInterval и запускайте новый

[Маруська]

import flash.utils.setInterval;
import flash.utils.Timer;
import flash.events.TimerEvent;
stage.addEventListener(MouseEvent.MOUSE_MOVE,аnimating);
var delay:int=0;
var t:Timer = new Timer(delay);
t.addEventListener(TimerEvent.TIMER, selectSide)
 
 
function аnimating(e:MouseEvent):void {
	t.stop()
	t.delay=200-Math.round(150/(Math.round(stage.width/2)/Math.round(Math.abs(stage.mouseX-stage.width/2))));
	t.start()
	e.updateAfterEvent();
}
function selectSide(event:TimerEvent):void {
if(stage.mouseX<stage.width/2){ goNext()}
	else goPrev();}		
	// Update after event to ensure no lag
 
function goNext():void{
	trace('goNext '+ t.delay)
	 if (foranim.currentFrame < foranim.totalFrames)
       foranim.gotoAndStop(foranim.currentFrame + 1);
    else
        foranim.gotoAndStop(1);}
 
function goPrev():void{
	trace('goPrev '+t.delay)
	 if (foranim.currentFrame >1)
       foranim.gotoAndStop(foranim.currentFrame - 1);
    else
        foranim.gotoAndStop(foranim.totalFrames);}

с таймером тоже тормозит

Добавлено через 2 часа 15 минут
отказалась от mouseEvent - работает отлично - спасибо всем!

[Wolsh]

var w:Number = stage.stageWidth/2;
var delay:int=0;
var lastTime:uint = (new Date).time;
stage.addEventListener(Event.ENTER_FRAME, аnimating);
 
function аnimating(e:Event):void 
{
	delay = w - Math.round(Math.abs(stage.mouseX - w));
	var m:uint = (new Date).time;
	if ((m - lastTime) >= delay)
	{
		lastTime = m;
		go();
	}
}
 
function go():void 
{
	if(stage.mouseX < w)
	{ 
		if (foranim.currentFrame < foranim.totalFrames)
       		foranim.gotoAndStop(foranim.currentFrame + 1);
    	else
        	foranim.gotoAndStop(1);
	}
	else 
	{
		if (foranim.currentFrame >1)
       		foranim.gotoAndStop(foranim.currentFrame - 1);
    	else
        	foranim.gotoAndStop(foranim.totalFrames);
	}	
}