Рисование, сохранение, отображение

[LA_]

Подскажите, плз, как человеку, только начинающему разбираться во флеше, как реализовать следующий функционал (что посмотреть, почитать, может, примеры кода):
1) дать возможность пользователю что-нибудь нарисовать (для простоты, например, одним цветом и одной толщиной)
2) сохранить нарисованное в строку
3) отобразить нарисованное из строки

[r_r_f_r]

package {
	import flash.display.Graphics;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.MouseEvent;
 
	public class DrawXA extends Sprite
	{
		private var _str:String = '';
 
		public function DrawXA()
		{
			super();
			stage.doubleClickEnabled = true;
			graphics.lineStyle(1,0xFF0000,1);
			stage.addEventListener(MouseEvent.DOUBLE_CLICK,onDoubleClick);
			stage.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown);
			stage.addEventListener(MouseEvent.MOUSE_UP,onMouseUp);
 
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
		}
 
		private function onMouseUp(e:MouseEvent):void
		{
			stage.removeEventListener(MouseEvent.MOUSE_MOVE,onMouseMove);
		}
 
		private function onDoubleClick(e:MouseEvent):void
		{
			if (!_str)
			{
				trace (_arCoor.join('|'));
			}
			else
			{
				var ar:Array = _str.split('|');
				var i:uint = 0;
				var gr:Graphics = graphics;
 
				while (i<ar.length)
				{
					if (ar[i] == -1)
					{
						gr.moveTo(ar[i+1],ar[i+2]);
						i += 3;
					}
					else
					{
						gr.lineTo(ar[i],ar[i+1]);
						i += 2;
					}
				}
			}
		}
 
		private var _arCoor:Array = new Array();
		private function onMouseMove(e:MouseEvent):void
		{
			_arCoor.push(e.stageX,e.stageY);
			graphics.lineTo(e.stageX,e.stageY);
		}
 
		private function onMouseDown(e:MouseEvent):void
		{
			_arCoor.push(-1);
			_arCoor.push(e.stageX,e.stageY);
			graphics.moveTo(e.stageX,e.stageY);
			stage.addEventListener(MouseEvent.MOUSE_MOVE,onMouseMove);
		}
	}
}

нажали мышку - рисуем, бросили - бросили рисовать. сделали даблклик - в консоль(trace()) вывели строку, копируем строку, вставляем в код в поле класса _str, запускаем делаем снова даблклик, и как говорится повторение мать учения.

[Dimax4d]

А по поводу сохранения - http://designreviver.com/tutorials/a...es-from-flash/

[LA_]

r_r_f_r, вау! спасибо огромное!
если какие-нить способы сжать данные рисунка? я так понимаю, что мы сохраняем в массив координаты каждой точки, для сложного рисунка строка может быть оооочень длинной

Dimax4d, тот способ, увы, не подходит, т.к. мне надо сохранять данные в строку, а не в jpeg

[Партизан]

Сообщение от LA_

я так понимаю, что мы сохраняем в массив координаты каждой точки, для сложного рисунка строка может быть оооочень длинной

Незначительно сжать можно... Но вряд ли вас это сильно спасет.

[r_r_f_r]

Писать в бинарном формате. Другого не дано.

[Felicast]

если какие-нить способы сжать данные рисунка

используйте ByteArray и его метод compress

Незначительно сжать можно

почему не значительно?
он же координаты хранить собирается, а не пиксели.
да даже если пиксели, они вполне себе хорошо сжимаются

[Партизан]

Насколько я понял, нужна строка... Ну можно сжать координаты в половину примерно... Если шаманить, можно %-ов 70 выжать... Но если я правильно понял, заморачиваться автор сильно не хочет... хз... в общем...
Согласен, даже 50% это значительно, но я другое несколько имел ввиду, сорри