как удалить нажав на кнопку весь экземпляр класса, в котором находится эта кнопка

[nelco]

создаю в основном классе

private var _floatingCont = new FloatingCont

объект этого класса, который содержит одну кнопку:

public class FloatingCont extends Sprite
	{
		public var _closeButton:Button = new Button("закрыть");
 
		public function FloatingCont()
		{	
			addChild(_closeButton);
			_closeButton.addEventListener(MouseEvent.CLICK, closeButtonLstner);
 
		}
 
		private function closeButtonLstner(e:MouseEvent):void 
		{
			this.parent.removeChildAt(1); 
		}
 
	}
 
}

мне нужно, чтобы при нажатии на эту кнопку удалялся этот объект _floatingCont, т.е. кнопка и функция от кнопки - получается, внутри этого объекта, который нужно удалить.
parent.removeChildAt(1) удаляет, но нужно чтобы можно было указывать само имя объекта _floatingCont... parent.removeChild(_floatingCont) как-нибудь так
или как мне перенести слушатель от кнопки в класс-родитель? подскажите как правильно делают в таких случаях? кажется, так неправильно

[amesqit]

Чем вас не устраивает удаление в основном классе, самому себя убивать классу не очень хорошая практика. Не он себя родил, не ему себя и убивать. Лучше сделать в классе FloatingCont деструктор и вызывать его из основного класса, его создавшего

public class FloatingCont extends Sprite
	{
		public var _closeButton:Button = new Button("закрыть");
 
		public function FloatingCont()
		{	
			addChild(_closeButton);
			_closeButton.addEventListener(MouseEvent.CLICK, closeButtonLstner);
 
		}
 
		public function destroy():void
		{
			_closeButton.removeEventListener(MouseEvent.CLICK, closeButtonLstner);
		}
 
		private function closeButtonLstner(e:MouseEvent):void 
		{
			dispatchEvent(new Event("kill_me_please"))
		}
 
	}
 
}

а в основном классе

		public function Main()
		{	
			_floatingCont = new FloatingCont()
			_floatingCont.addEventListener("kill_me_please", killHandler)
			addChild(floatingCont )
 
		}
		private function killHandler(e:Event):void
		{
			var target:FloatingCont = FloatingCont(e.target);
			target.destroy() 
			target.removeEventListener("kill_me_please", killHandler)
			removeChild(target)
		}

[nelco]

спасибо, понял, только через диспатчинг событий, получается? думал, что можно, может, из самого класса как-нибудь самого себя удалить правильно. как вы не путаетесь со всеми этими слушателями и ссылающимися друг на друга классами, я удивляюсь... :\ надеюсь, что у меня тоже так получится не путаться со временем, какой слушатель от чего и т.д. (ведь со временем этих всех объектов, слушателей - будет очень много в коде одного класса)

[amesqit]

Это не правильно с точки зрения логики. У классов создателей могут быть свои планы, для какой-то цели они создали объект, ждут от него каких-то результатов деятельности, какие-то события, когда он им станет не нужен они должны от него избавиться, а тут он взял и сам себя убил, никому ничего не сказав. Так порядочные объекты не поступают. Для окончательного удаления объекта сборщиком мусора, нужно чтобы не было на него ссылок, сам объект не знает кто за ним следит, поэтому лучше чтобы он сказал о своем намерении убить себя, чтобы следящие за его поведением объекты смогли благополучно про него забыть.

[КорДум]

(ведь со временем этих всех объектов, слушателей - будет очень много в коде одного класса)

Что будет громким таким звоночком, что архитектура приложения неверна.

как вы не путаетесь со всеми этими слушателями и ссылающимися друг на друга классами

Собственно, вот это предложение уже в какой-то степени говорит о неправильной архитектуре, если все друг на друга ссылаются. Программа в идеальном идеале должна представлять собой дерево, где каждая веточка сообщает узлу о какой-то информации, узел либо отправляет эту информацию другому узлу на уровень выше, либо говорит другой своей веточке эту переданную и, возможно, как-то модифицированную информацию.

[amesqit]

Сообщение от nelco

спасибо, понял, только через диспатчинг событий, получается? думал, что можно, может, из самого класса как-нибудь самого себя удалить правильно. как вы не путаетесь со всеми этими слушателями и ссылающимися друг на друга классами, я удивляюсь... :\ надеюсь, что у меня тоже так получится не путаться со временем, какой слушатель от чего и т.д. (ведь со временем этих всех объектов, слушателей - будет очень много в коде одного класса)

Классы минимально должны ссылаться друг на друга, и знать они должны ровно то что от них надо. Что-то вроде того, что есть Класс Машина, у машины есть колесо, колесо не знает на какой машине оно стоит, колесо может крутиться, а еще у него может лопнуть шина. Лопнувшая шина - событие. Оно говорит что у машины надо поменять колесо и оно будет заменено другим колесом. Одна сущность должна знать о другой только минимально необходимую информацию, тогда и путаницы никакой нет. Вот если у машины исчезнет колесо само из-за того, что шина лопнет, будет беда, т.к. про то что колесо на месте знает еще и например водитель, и ему ни к чему такие сюрпризы. Лучше всего конечно когда про это колесо не знает никто кроме машины, и нужно стремиться к тому чтобы связи между сущностями были минимальными, чтобы для водителя с летающей или гусеничной машиной абсолюно ничего не изменилось, но это уже тема интерфейсов.