Разные swf и одно событие

[s3dworld]

Всем доброго дня!

Смотрите как у меня получается, есть два проект: loader и game. В обоих проектах имеется класс GameEvent, который наследуется от класса Event. Суть такова, что вначале запускается loader, он грузит game и когда он его загрузил, то он подписывается на событие:

addEventListener(GameEvent.READY,OnGameEventReady);
 
// ...
 
// Клип game.swf готов к работе
private function OnGameEventReady(_event:GameEvent):void
{
	removeEventListener(GameEvent.READY,OnGameEventReady);
 
	objGame.pGameLoader.funInviteFriends=VKDShowInviteBox;			
	objGame.startGame();
}

То есть я как бы ловлю от подгруженного клипа событие что тот выполнил определённый сценарий и после уже присваиваю его переменным нужные значения. То есть из loader я хочу обратиться к переменной в game, которая указывает на экземпляр класса в котором я хочу установить свои значения для переменных. И если я обращусь туда раньше чем этот экземпляр был создан, то произойдёт ошибка. Именно для этого я и хочу получать от game создал ли он экземпляр.

В самом же game 1 в 1 тот же самый код класса GameEvent:

package D 
{
	import flash.events.Event;
 
	// Событие игры
	public class GameEvent extends Event
	{
		public static const READY			:String		= "D_GameEvent";
 
		public var dataType:String=null;					// Тип события
 
		public function GameEvent(_dataType:String)
		{
			dataType=_dataType;
 
			super(dataType,true,false);
		}
 
	}
 
}

И когда game готов, делаю:

dispatchEvent(new GameEvent(GameEvent.READY));

Событие приходит в loader, но возникает ошибка преобразования (или как она там). Он не может отосланный класс преобразовать в принимаемый. Помогает тупая замена:

// Клип game.swf готов к работе
private function OnGameEventReady(_event:*):void
{
	removeEventListener(GameEvent.READY,OnGameEventReady);
 
	objGame.pGameLoader.funInviteFriends=VKDShowInviteBox;
 
	objGame.startGame();
}

Если для данной ситуации это терпимо (хоть и не правильно), то что будет когда мне надо будет у события извлекать параметры?!

Есть ли какой-то способ правильно получать событие?

Добавлено через 9 минут
Конечно можно так:

// Клип game.swf готов к работе
private function OnGameEventReady(_event:*):void
{
	removeEventListener(GameEvent.READY,OnGameEventReady);
 
	var event:GameEvent=_event as GameEvent;
 
	objGame.pGameLoader.funInviteFriends=VKDShowInviteBox;
	objGame.startGame();
}

Только на сколько это правильно.

[carrotoff]

И если я обращусь туда раньше чем этот экземпляр был создан, то произойдёт ошибка. Именно для этого я и хочу получать от game создал ли он экземпляр.

После того, как в game сработает Event.INIT, а уже тем более Event.COMPLETE, можно спокойно обращаться к его доступным методам и свойствам. Потому не вижу необходимости в GameEvent.READY

По поводу вопроса: не знаю как у вас там всё так интересно устроено, что получаете ошибку преобразования, но

_event:*

так не стоит делать. Раз ваш GameEvent наследуется от Event, то и приводите к этому типу
_event:Event.
А потом кастуйте к вашему типу GameEvent.

_event as GameEvent;

ну как у вас в принципе и сделано

[Stitch512]

В обоих проектах имеется класс GameEvent

Если два разных файла с классами то и классы по сути будут разными, даже если одинаково называются. Для нормальной работы нужно чтобы loader и game при компиляции использовали один и тот же файл.

Вынесите общие классы для обеих проектов в одну библиотеку и подключите ее в оба проекта.

И если возникла ошибка преобразования типа то

var event:GameEvent=_event as GameEvent;

также не поможет, ошибки не будет, но event будет равен null

И кстати, не критично, но с символа "_" принято начинать внутренние поля класса (private или protected) в не локальные переменные или аргументы функций.

[dimarik]

Сообщение от Stitch512

Если два разных файла с классами то и классы по сути будут разными, даже если одинаково называются. Для нормальной работы нужно чтобы loader и game при компиляции использовали один и тот же файл.

Да пофиг на файлы. Аппдомены разные. Вот и вся суть. Загружайте game в Application.currentDomain и будет вам щастие.