Как можно поставить между двумя точками круг?

[Dip52]

Сообщение от Akopalipsis

Dip52 вообще не понятно..

Как можно создать третью точку, НО:
чтобы она была по середине между двумя точками 1 и 2 (как на картинке),
чтобы она была всегда между двумя точками, не только когда точки 1 и 2 имеют одинаковую координату x.

[Akopalipsis]

С ответом поспешил, Вам и угла будет достаточно, но только опять непонятно.
Понятно только то, что она должна быть под углом 90 градусов, относительно отрезка AB, но с какой стороны? И лучше всего, выучите косинусы и синусы, а то Вы всегда будете спрашивать. Это очень просто.

[Dip52]

Сообщение от Akopalipsis

С ответом поспешил, Вам и угла будет достаточно, но только опять непонятно.
Понятно только то, что она должна быть под углом 90 градусов, относительно отрезка AB, но с какой стороны? И лучше всего, выучите косинусы и синусы, а то Вы всегда будете спрашивать. Это очень просто.

С той стороны как на картинке. Даже если сам круг имеет другой угол.

[Akopalipsis]

Так?

package 
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.text.TextField;
 
	public class CirclePoint extends Sprite 
	{
 
		public function CirclePoint() 
		{
			stage.addEventListener(MouseEvent.MOUSE_DOWN, stage_mouseDownHandler);
		}
		private const DEG_TO_RAD:Number = 3.1415926535897932 / 180;
		private function stage_mouseDownHandler(event:MouseEvent):void 
		{
			if (this.numChildren) this.removeChildren();
 
 
			var A:Point = this.drawPoint(this.coords());
			var B:Point = this.drawPoint(this.coords());
			var C:Point = new Point();
 
 
			var textA:TextField = new TextField();
			textA.text = 'Точка А';
			textA.textColor = 0xFE2929;
			textA.x = A.x;
			textA.y = A.y;
			this.addChild(textA);
 
			var textB:TextField = new TextField();
			textB.text = 'Точка B';
			textB.textColor = 0xFE2929;
			textB.x = B.x;
			textB.y = B.y;
			this.addChild(textB);
 
			var radius:Number = Math.sqrt(Math.pow((B.x-A.x), 2) + Math.pow((B.y-A.y), 2)) / 2;
			var center:Point = new Point((A.x + B.x) / 2, (A.y + B.y) / 2);
			var bc:Point = new Point(B.x - center.x, B.y - center.y);
			var angle:Number = 90 * DEG_TO_RAD;
			var cos:Number = Math.cos(angle);
			var sin:Number = Math.sin(angle);
			C.x = center.x + bc.x * cos - bc.y * sin;
			C.y = center.y + bc.y * cos + bc.x * sin;
 
			var textC:TextField = new TextField();
			textC.text = 'Точка C';
			textC.textColor = 0xFE2929;
			textC.x = C.x;
			textC.y = C.y;
			this.addChild(textC);
 
			this.drawPoint(center);
			this.drawPoint(C);
			this.drawCircle(center, radius);
		}
		private function drawCircle(center:Point, radius:Number):void
		{
			var circle:Sprite = new Sprite();
			circle.graphics.lineStyle(1, 0xffffff);
			circle.graphics.drawCircle(center.x, center.y, radius);
			circle.graphics.endFill();
			this.addChild(circle);
		}
		private function coords():Point
		{
			var pX:int = Math.round(Math.random() * stage.stageWidth);
			var pY:int = Math.round(Math.random() * stage.stageHeight);
			return new Point(pX, pY);
		}
		private function drawPoint(p:Point):Point
		{
			var circle:Sprite = new Sprite();
			circle.graphics.beginFill(0xffffff);
			circle.graphics.drawCircle(0, 0, 5);
			circle.graphics.endFill();
			circle.x = p.x;
			circle.y = p.y;
			this.addChild(circle);
			return p;
		}
	}
 
}

[Dip52]

Да. А вот такая поставка третьей точки (или сам алгоритм) как-нибудь обозначается? Как, например, "уравнение окружности" может сделать "то-то".

[Akopalipsis]

Вроде бы нет... Хотя, это наверное складывание косинусов и синусов.

[Dip52]

Хорошо. Спасибо за помощь. Вы сильно помогли.

[samana]

Сообщение от Akopalipsis

Вроде бы нет... Хотя, это наверное складывание косинусов и синусов.

На самом деле косинусы и синусы тут не единственные помощники, можно было и без них обойтись. Например нахождения вектора от центра к первой точке (или ко второй), и последующее нахождение нормали этого вектора в любую из сторон.

[Akopalipsis]

samana если возможно, покажите как это сделать. До конца с нормированием я пока не разобрался.

[samana]

Сообщение от Akopalipsis

samana если возможно, покажите как это сделать. До конца с нормированием я пока не разобрался.

Что-то в этом духе. Вообще почитайте про вектора, это очень может помочь.
Тут надо водить мышкой. Круги разного цвета, показывают направление нормалей. Какой цвет, что показывает - смотрите в комментариях.

package  
{
	import flash.display.JointStyle;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.geom.Point;
 
	/**
	 * ...
	 * @author Samana
	 */
	public class Main extends Sprite 
	{
		private var center:Point=new Point(300,300);
		private var pointA:Point = new Point(300, 200);
		private var leftNormalPoint:Point=new Point();
		private var rightNormalPoint:Point = new Point();
		private var dist:Number = 0;
 
		public function Main() 
		{
			stage.addEventListener(MouseEvent.MOUSE_MOVE, stage_mouseMove);
		}
 
		private function stage_mouseMove(e:MouseEvent):void 
		{
			pointA.setTo(mouseX, mouseY);
 
			var vx:Number = pointA.x - center.x;
			var vy:Number = pointA.y - center.y;
			dist = Math.sqrt(vx * vx + vy * vy);
 
			leftNormalPoint.setTo(center.x+vy, center.y-vx);
			rightNormalPoint.setTo(center.x-vy, center.y+vx);
			drawPoints();
		}
 
		private function drawPoints():void 
		{
			graphics.clear();
			graphics.lineStyle(1, 0xCEBB31);
			graphics.drawCircle(center.x, center.y, dist);
			//серый центр
			graphics.beginFill(0x828282);
			graphics.drawCircle(center.x, center.y, 6);
			//зелёная точка А
			graphics.beginFill(0x00FF00);
			graphics.drawCircle(pointA.x, pointA.y, 4);
			//синая точка, левая нормаль
			graphics.beginFill(0x8000FF);
			graphics.drawCircle(leftNormalPoint.x, leftNormalPoint.y, 4);
			//красная точка,правая нормаль
			graphics.beginFill(0xFF0080);
			graphics.drawCircle(rightNormalPoint.x, rightNormalPoint.y, 4);
		}
 
	}
 
}