Рассылка событий

[kyrpyr]

Всем привет.

Проблема в том, что не могу реализовать свое событие(
в аттаче приложены исходники примера

работать все должно так - класс Test в конструкторе подписывается на событие CustomEvent.MYEVENT с обработчиком myEventHandler и выполняет функцию TheOtherClass.doSmth(), откуда и рассылается событие. Хотелось бы, чтобы TheOtherClass не наследовал EventDispatcher, а создавал экземпляр EventDispatcher, с помощью которого и делал рассылку (если это возможно конечно).

Подскажите плз....или может ктонибудь исправит исходники и выложит работающий вариант?

test.rar

[r_r_f_r]

Примерно так

package
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
 
	public class TheOtherClass implements IEventDispatcher
	{
		private var _eventDispatcher:EventDispatcher;
 
		public function OtherClassDis()
		{
			_eventDispatcher = new EventDispatcher(this);
		}
 
		public function addEventListener(type:String,
										listener:Function,
										useCapture:Boolean = false,
										priority:int = 0,
										useWeakReference:Boolean = false):void
		{
			_eventDispatcher.addEventListener(type,listener,useCapture,priority,useWeakReference);
		}
 
		public function dispatchEvent(event:Event):Boolean
		{
			return _eventDispatcher.dispatchEvent(event);
		}
 
		public function hasEventListener(type:String):Boolean
		{
			return _eventDispatcher.hasEventListener(type);
		}
 
		public function removeEventListener(type:String,listener:Function,useCapture:Boolean = false):void
		{
			_eventDispatcher.removeEventListener(type,listener,useCapture);
		}
 
		public function willTrigger(type:String):Boolean
		{
			return _eventDispatcher.willTrigger(type);
		}
	}
}

[BlooDHounD]

r_r_f_r, лучше в конструкторе сделать так:

this._eventDispatcher = new EventDispatcher( this );

тогда в таргете событий будет экземпляр класса TheOtherClass.

[r_r_f_r]

BlooDHounD, задремал малость, спасибо. Код подправил.

[kyrpyr]

а как рассылать тогда событие? так не работает

_eventDispatcher.dispatchEvent(new CustomEvent(CustomEvent.MYEVENT));

[BlooDHounD]

у меня работает.

[kyrpyr]

странно все это....если не сложно, посмотри исходник, я уж прям и не знаю, в чем дело, всю голову поломал....
test.rar

[r_r_f_r]

		public function Test() {
			var to:TheOtherClass = new TheOtherClass();
			to.addEventListener(CustomEvent.MYEVENT, myEventHandler);
			to.doSmth()
		}
 
		private function myEventHandler(evt:CustomEvent):void {
			trace("евент достиг цели!")
		}

Тебе нужно подписать именно объект to.

[_Smirnoff]

kyrpyr, а зачем испльзовать композицию в TheOtherClass в отношении EventDispatcher. Или вы хотите TheOtherClass унаследоваь от другого класса.

[kyrpyr]

Тебе нужно подписать именно объект to.

Точно, спасибо

kyrpyr, а зачем испльзовать композицию в TheOtherClass в отношении EventDispatcher. Или вы хотите TheOtherClass унаследоваь от другого класса.

именно так я и хотел сделать

с экземпляром класса все ясно, а как поступить, если функция doSmth статическая и вызывается соответственно от имени класса?