Форум Flasher.ru - Хорошее MVC

Страница 1 из 16

Показывать 40 сообщений этой темы на одной странице

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- Статьи (http://www.flasher.ru/forum/forumdisplay.php?f=101)

- - Хорошее MVC (http://www.flasher.ru/forum/showthread.php?t=138349)

Psycho Tiger

05.04.2010 18:00

Хорошее MVC

UPD: Прошло больше, чем полгода. Много воды утекло, многое осмыслили и многое поняли.
Если Вы зашли сюда почитать об MVC, не зная что это или не зная, как его применять в простейших случаях, то на правах саморекламы рекомендую почитать мои статьи об MVC.
Часть первая.
Часть вторая.
В основном они содержат мысли из этой темы и всего остального, что в то время мне удалось найти про "ручной" MVC.

Оригинальное сообщение:
Раньше делал жалкие подобия (хотя сложно назвать и подобиями) - например, вьюшка создает модель, то есть совсем всё плохо - теперь хочу начать делать грамотно. Наслушавшись etc про то, что PureMVC гавно и wxvxw про то что MVC вообще не может быть фреймворком (с последним согласен полностью - не понимаю, как архитектуру можно обернуть в универсальный фреймворк) встаёт вопрос - а как сделать правильное MVC? Гугл внятного ответа не дал, лишь что модель хранит и обрабатывает все данные, вьюшка отображает, а контроллер связывает эти 2 штуки.
Собственно, помимо просьбы дать статьи на правильный MVC ещё прошу объяснить вот какие моменты:
1) Кто кого создаёт? (для простоты будем отправной точкой брать базовый класс) - базовый класс создаёт контроллер, который создаёт вьюшку и модель, или как вообще? (может написал глупость, просто совершенно не понимаю кто кого - лишь для наглядности примера, что я хочу узнать)

2) У кого должны быть на кого ссылки и у кого не должны быть?

3) Понимаю, что главная сцена - это одна большая вьюшка, а в ней другие вьюшки от других моделей и т.д. Но вот эти "внутренние" MVC, откуда у них ноги растут? Или базовый класс, в который всё добавляется не должен быть построен по структуре MVC? Опять могу говорить глупости, вопрос может быть тупо из за непонимания механизма.

4) M+VC, VM+C - в чем разница?

5) В случае появления базы данных, кто с ней работает и кто имеет на неё ссылки?

Вообще в идеале было бы здорово какой нибудь элементарный пример, например таскание мячика. Где то видел блог про "хорошее" MVC тут на флешере, но найти не смог :(
Спасибо, что прочитали до конца, буду рад любой помощи.

fljot

05.04.2010 18:10

хз)

Новая хрень появилась — RobotLegs зовётся, попробуй подёргать её за всякое.

http://www.robotlegs.org/
http://shaun.boyblack.co.za/blog/200...ework-but-why/

etc	05.04.2010 20:04

1) Контроллер создает и модель и вьюшку;
2) http://www.flasher.ru/forum/showpost...54&postcount=2
3) Рутовый класс создает рутовый же контроллер и передаёт ссылку на самого себя как на контейнер вьюшек. Всё;
4) M+VC — контроллер интегрирован во вьювер. В общем-то, это контрол. VM+C — вьювер с интегрированной моделью. В принципе это ItemRenderer, по идее;
5) Отображает вьювер, изменяет контроллер. И у того и другого есть ссылки на базу.

Psycho Tiger

05.04.2010 20:28

1) Так, хорошо. А если вьюшку создаёт он сам, то как её добавить? Диспатчить кастомное событие?

2) Да, медитировал на схему ещё давно, однако она мне кажется слишком сложной и поспешной для выводов, но я попробую сформулировать постулаты, и чтобы не утруждать вас лишней писаниной буду рад просто плюсикам над правильными высказываниями:
а) Самый главный контроллер создаёт ещё кучи контроллеров
б) Контроллер так как создал модель имеет ссылкой и вьюшку, и модель
в) Вьюшки порождают вьюшки... А кто их контроллер и где их модель?

Дальше, если представить что Data=модель
г) view events - событие о том, что вьюшку нужно обновить? Обычное бабблинг событие? Но ведь бабблинг событие ~31 раз в секунду достаточно ресурсоемко - как же быть?

4) это мне понятно, мне не понятно с точки зрения реализации. M+VC - связь с моделью напрямую из вьюшки так? А каокй толк в VM+C?

И появился новый вопрос - а где происходит вся логика? В Модели? То есть модель - эта вся логика, а контроллер призван помочь вьюшке отобразить это, верно?

etc	05.04.2010 21:33

1) Добавить куда? Есть ссылка на контейнер для вьюшек;
2)
а) Не всегда, младшие контроллеры могут ещё более младших создавать;
б) Не понял;
в) Снаружи, на них ссылаются. Вьюшке максимум отдается ссылка на модель-контейнер;
г) Нет, view events — события от вьювера. Например MouseEvent.CLICK. А какая связь между ENTER_FRAME и бабблингом, я не уловил;
4) Модель обычно не имеет ссылок ни на вьюшек, ни на контроллеры, она сама по себе. Равно как она и не содержит логики, логика находится в контроллера. Задача модели — хранить данные и уведомлять об изменении.

Psycho Tiger

05.04.2010 22:07

Спасибо, начинаю понимать.
1) Я так понимаю в контроллер всегда передаётся DisplayObjectContainer, говорящий куда пихнуть вьюшку?
б) я имею ввиду что раз контроллер создаёт и вьюшку, и модель то он сохраняет их ссылки. Ну в принципе вопрос риторический, не сохранять было бы глупо.
в) а как можно ссылаться снаружи на то, что было создано внутри? Диспатчится событие и на неё начинают ссылаться?
г) теперь понял что это, думал о другом =)

Такс, применив свои знания набросал это в коде, посмотри пожалуйста:
Базовый класс:

Код AS3:

package  

{

        import flash.display.Sprite;

 

        public class JustMain extends Sprite

        {

 

                public function JustMain() 

                {

                        super();

                        var controller:Controller = new Controller(this);

                }

 

        }

 

}

Контроллер:

Код AS3:

package  

{

        import flash.display.DisplayObjectContainer;

        import flash.events.Event;

        import flash.events.MouseEvent;

 

        public class Controller

        {

                private var _model:Model = new Model();

                private var _viewer:Viewer = new Viewer();

                private var _container:DisplayObjectContainer;

                public function Controller(container:DisplayObjectContainer) 

                {

                        _container = container;

                        init();

                }

 

                private function init():void

                {

                        _container.addChild(_viewer);

                        _model.addEventListener(Event.CHANGE, onModelChange);

                        _viewer.addEventListener(MouseEvent.CLICK, onViewerClick);

 

                }

 

                private function onViewerClick(e:MouseEvent):void 

                {

                        _model.change(Math.random() * 400, Math.random() * 400);

                }

 

                private function onModelChange(e:Event):void 

                {

                        _viewer.updatePositions(_model.x, _model.y);

                }

 

        }

 

}

Моделька:

Код AS3:

package  

{

        import flash.events.Event;

        import flash.events.EventDispatcher;

        import flash.events.IEventDispatcher;

 

        public class Model extends EventDispatcher

        {

 

                //no getters/setters, just example

                public var x:Number = 0;

                public var y:Number = 0;

 

                public function Model() 

                {

                        super(null);

 

                }

 

                public function change(x:Number, y:Number):void {

                        this.x = x;

                        this.y = y;

                        super.dispatchEvent(new Event(Event.CHANGE));

                }

 

        }

 

}

И вьюшка:

Код AS3:

package  

{

        import flash.display.Sprite;

        import flash.events.MouseEvent;

 

        public class Viewer extends Sprite

        {

 

                public function Viewer() 

                {

                        super();

                        init();

                }

 

                private function init():void

                {

                        var someSprite:Sprite = new Sprite();

                        someSprite.graphics.beginFill(0);

                        someSprite.graphics.drawCircle(0, 0, 50);

                        someSprite.graphics.endFill();

                        super.addChild(someSprite);

                        someSprite.addEventListener(MouseEvent.CLICK, super.dispatchEvent);

                }

 

 

                public function updatePositions(x:Number,y:Number):void {

                        this.x = x;

                        this.y = y;

                }

        }

 

}

По клику на кружок событие идёт в контроллер, оттуда просит модель изменить данные, модель данные меняет и говорит контроллеру, который обновляет вьюшку.

Возникает отсюда уже несколько вопросов:
1) Чтобы было совсем идеально-правильное MVC на твой взгляд, что нужно добавить, а что убрать?
2) Наверное, на столь простом примере не видно - но зачем такой полёт данных? Ведь если контроллер изменяет все данные, а моделька их всего лишь хранит - тогда, наверное, контроллеру уж точно видно что данные изменены и надо что то сказать вьюшке, зачем в моделе уведомлять об изменении?
3) А если я ф-цию change заменю 2-мя сеттерами, тогда я дважды вызову уведомление об обновлении, что плохо. Как быть?

Было бы очень здорово, если бы ты ткнул на конкретно этом примере, как сделать лучше.

dimarik

05.04.2010 22:43

Сильно не читал =) Схема от Дениса и Николая стоит у меня как обои на домашнем компе ).
Кто кого создает. Для нас самое важное - создание структуры MVC в рантайме. Кем это будет сделано - совершенно не важно. Важно, что вся тройка будет создана (инстанцированы все три составляющие). Сделайте DocumentClass как фабрику конкретной структуры MVC по какому-либо конфигу. И забудьте о том кто кого инстанцирует вначале. Просто вначале есть эта тройка. Теперь Модель под властью Контроллера. Он ее холит и леет. Именно он интерпретирует порой кривые данные от сервера. Именно он добавляет логику в наши "тонкие" клиенты, когда серверные разрабы пожимают плечами и разводят руки, мол, не можем, ибо хайлоад. Ну а вьюха, она и в африке вьюха. Красивое, но тупое создание. Слушает определенную часть модели и умеет делать всякие флешевые анимации красивостей, на которые работает добрая доля отдела художников, и звуки, от местного звукорежиссера. Но, помимо этого, без нее не было бы интерактивности. Мало смотреть, хочется и "подергать" ) Вьюха честно сообщает контроллеру о пользовательских кликах, нажатиях на кнопки, голосовом управлении и прочих мультитачах. Контроллер, получая инфу от вьюх, меняет модель.

Вью - композитные. Похожи на дисплай лист.
Модель - тоже.
Контроллеры. Здесь особо не баловался, самостоятельно организовывал в виде команд. Но что-то мне подсказывает, что сделать иерархию контроллеров тоже можно.

Psycho Tiger

05.04.2010 22:50

Да, спасибо, это мы уже всё разобрали =)
Почерпнул новое, однако же все вопросы выраженные постом раньше до сих пор остались нерешенными =(

cpu	06.04.2010 00:09

Я почему-то думал раньше, что самый сложный(главный) код в модели.
А оказывается контролер всему голова, а модель это практически база данных? Я правильно понял?

dimarik

06.04.2010 00:20

точно

Psycho Tiger

06.04.2010 00:39

Новый вопрос созрел: хочу сделать V+MC, что я делаю:
Создаю класс, ни от кого ни исследующийся, в котором будет происходить вся логика, который будет изменять свои же свойства. Ему в конструктор передаю host:DisplayObjectContainer и в него добавляю вьюшку, которую эти же классом создаю. Когда нужно что-то обновить, вызываю у вьюшки метод render() или нечто вроде такого метода с нужными мне параметрами. Для MC + V делаю правильно?

etc	06.04.2010 08:21

Psycho Tiger,
1) Типа того;
2) Модель снаружи приходит, у вьювера есть геттер-сеттер модели. То, что создает вьювер у себя внутри другие вьюшки отображающих элементы модели, контроллер не интересует. Максимум он подпишется у вьювера-контейнера на всплывающие события, либо сам контейнер ловит от вложенных вьюшек события и далее шлет результат (типичный пример — событие CHANGE у листа, которое формируется на основании событий SELECT у детей);

По классам: контроллер не занимается обновлением состояния вьювера. Он изменяет модель, модель шлет событие. Ссылка на модель передаётся контроллером вьюверу на стадии сборки триады. В случае критичности частоты вызова обновлений, можно написать и геттеры-сеттры «x», «y», так и метод setPosition. Симбиоз так сказать.

Ariel

06.04.2010 09:04

2ЦПУ; 2ДИМАРИК ::
"точно" ни разу не точно. Это только одна из реализаций, причем не самая чистая. Мука почитать (и на ВИКИ посмотреть) так выходит, что все данные+логика тройки - в модель. Это будет классическая имплементация MVC. И ходят оне парами как M+VC, т.е. при замене Вью меняем и Контроллер к нему. На эти темы уже копий переломано!...

Котяра

06.04.2010 09:47

Во всех реализациях MVC меня всегда смущали глобальности контроллера и модели. Если рассматривать модульную архитектуру приложения, то как мне кажется можно ввести понятие составной вью - который сам по себе может быть организован в виде mvc. Контроллер в таком вью является мостом между внутренними видами и внешним контроллером. Модель может быть как внутренняя так и ссылка на часть структуры внешней.
структура получается следующая:
M1 - C1 - V1(m2-v2-c2) а не M1(M2)- C1(C2)-V1(V2)
пример1:
Если рассматривать с точки зрения клиент - сервер, то клиент это тоже вид, который диспатчит интерактивные события и слушает изменения данных, либо прямые команды от сервера ( который в данном случае выполняет ф-ции контроллера и модели данных верхнего уровня)
пример 2:
готовая форма лобби вступления в игры. в качестве данных принимает список открытых игр - диспатчит событие присоединения к игре. как это внутри отображается не важно - там может быть куча отдельных окошек, списков комбобоксов итп, организованных по своим mvc правилам. Здесь контроллер выступате в роли слушателя внешней модели и меняет внутреннюю, также он слушает внутренние вьюшки - меняет внутреннюю модель и диспатчит внешние видовые события ( типа вступить в игру/ создать игру).
Для включения этого модуля(вида) в другую внешнюю MVC достаточно изменить "мостовую" часть контроллера. внтренняя структура остаётся неизменной.

А вообще я последнее время сильно охладел к MVC - как к универсальному решению) выхожу из стадии abstraction freek)
Хотя архитектуры проектов строю близко к МВЦ, но с учётом большей автономности модулей.
PS: А готовые фрэймворки - *****) более менее только mate использую, и то в силу его "необязательности".

Ariel

06.04.2010 10:07

Главное, шоб оно оправдывало себя. Шоб не было такого, когда в порядке обновления Модели, надо пропускать событие с Вашего под-под-Вида через тучу Контроллеров БЕЗ ИЗМЕНЕНИЙ. Шоб не было MVC ради самого MVC. Возможно у Вас Контроллер выполняет роль Bridge (в M1 - C1 - V1(m2-v2-c2) а не M1(M2)- C1(C2)-V1(V2) и в пример 2).
Также иногда Контроллер просто на фиг выбрасывают из тройки как лишний ("необязательность"!). Т.к. весь инпут сразу в модель летит и обновляет ее эффективно. Т.е., имеем главное: отделяем представление от данных.

Art_133

06.04.2010 13:08

Скажите пожалуйста, что делает эта строчка кода:

Код AS3:

someSprite.addEventListener(MouseEvent.CLICK, super.dispatchEvent);

Я так понимаю что она диспатчит событие на которое был подписан Вьювер в Классе-Контроллере? Выходит что super вызывает методы, переменные не только у родителей но и может передать событие в Класс где был создан экземпляр?
Обьясните пожалуйста... Первый раз вижу такое...

mexoboy

06.04.2010 14:17

Цитата:

Сообщение от dimarik (Сообщение 898232)

Слушает определенную часть модели и умеет делать всякие флешевые анимации красивостей, на которые работает добрая доля отдела художников, и звуки, от местного звукорежиссера.

По логике вещей MVC, представление никак не связано с моделью. За передачу параметров представлению отвечает только контроллер. А задача контролера как раз и заключается из выдергивания необходимой бизнес-логики из модели и передачи готовенького представлению.

cpu	06.04.2010 14:21

Ламерский вопрос.
При каких простых условиях говорят: "Вот это MVC!" ?
-----------------------------------------------------------------------------------

1. Т.е. что на что не должно иметь ссылок не при каких обстоятельствах?
-----------------------------------------------------------------------------------

2. Из Википедии:

Цитата:

Однако модель не зависит ни от представления, ни от поведения.

Тогда как изменить определенные данные в модели, если я нажал что-то во View?
-----------------------------------------------------------------------------------

MrPoma

06.04.2010 14:25

Цитата:

Сообщение от Art_133 (Сообщение 898349)

Скажите пожалуйста, что делает эта строчка кода:

Код AS3:

someSprite.addEventListener(MouseEvent.CLICK, super.dispatchEvent);

Вызывает метод dispatchEvent. А поскольку объявлен он в супер-классе, пишут super.

etc	06.04.2010 14:36

Цитата:

Сообщение от cpu (Сообщение 898364)

Тогда как изменить определенные данные в модели, если я нажал что-то во View?

Через контроллер. Точнее, как он решит, так и будет.

cpu	06.04.2010 15:01

Цитата:

Через контроллер. Точнее, как он решит, так и будет.

- получается контроллер имеет ссылку на модель. И меняет определенные данные через какой-нибудь set-метод?

Получается так:
1. View не имеет ссылок никуда, только рассылает события в контроллер.(данные введенные в input-поля хранит у себя, что бы их мог посмотреть контроллер через get-метод).
2. Контроллер имеет ссылку и на модель и на представление, и может работать с ними через их методы.
3. Модель отправляет события в контроллер если поменялись какие-то данные, и передает их ему через например set-методы. И наоборот.

В таком случае между View и model действительно нет прямой связи.
Но остается прямая связь между моделью и контроллером.

Art_133

06.04.2010 15:13

Цитата:

Сообщение от MrPoma (Сообщение 898367)

Вызывает метод dispatchEvent. А поскольку объявлен он в супер-классе, пишут super.

Я думал что супер Клас имеется ввиду Класс который расширяет другой Класс. Здесь Controller не расширяет Viwer. Выходит что можно вызвать метод в классе где был объявлен экземпляр при помощи super?

etc	06.04.2010 15:26

cpu
1) view имеет ссылку на модель;
2) Контроллер на них обоих;
3) Модель отправляет события вьюверу. Вьювер — контроллеру.

Psycho Tiger

06.04.2010 15:31

Цитата:

Сообщение от Art_133 (Сообщение 898380)

Так и есть. Забудьте о super в этом примере. Пишите просто

Код AS3:

addEventListener(Event.COMPLETE, dispatchEvent);

Это просто что то типа подписи "а это писал тру-флешер" :)

Я пишу с super только потому что мне необходимо, чтобы вот этот самый addEventListener был именно таким, каким я хочу - каким его сделали Adobe и ничто мне не может гарантировать, что завтра я для каких то других нужд переопределю addEventListener и dispatchEvent и мой сегодняшний код не перестанет работать. Маловероятно, конечно, но всё же... это мой бзик и моё право, к тому же так правильней :)

По теме MVC: *сейчас переделаю то, что писал вчера с новыми знаниями и отпишусь*

cpu	06.04.2010 16:03

etc:

Цитата:

1) view имеет ссылку на модель;

Но ведь тогда view может напрямую менять данные в модели обойдя controller (и контроллер со своей бизнес-логикой остается неудел).
---------------------------------------------------------------
etc:

Цитата:

3) Модель отправляет события вьюверу. Вьювер — контроллеру.

Так как View имеет ссылку на модель, он может получит по этому событию данные из model для отображения, обойдя contoller(который опять неудел.)

=================================================================
P.S. Вообще какая главная цель MVC? Раньше я думал возможность подключать к программе множество представлений(view) и менять их хоть в горячую. Ну и создавать вложенные представления.

Psycho Tiger

06.04.2010 16:43

Цель MVC - отделить то, что на экране от того, что происходит логикой. Короче, если проект расчитывался как консольный, а потом вдруг трах тибидох и хотим 3д - надо будет менять лишь вьюшку.

Главный класс:

Код AS3:

package  

{

        import flash.display.Sprite;

 

        public class JustMain extends Sprite

        {

 

                public function JustMain() 

                {

                        super();

                        var controller:Controller = new Controller(this);

                }

 

        }

 

}

Контроллер:

Код AS3:

package  

{

        import flash.display.DisplayObjectContainer;

        import flash.events.Event;

        import flash.events.MouseEvent;

 

        public class Controller

        {

                private var _model:Model = new Model();

                private var _viewer:Viewer = new Viewer(_model);

                private var _container:DisplayObjectContainer;

                public function Controller(container:DisplayObjectContainer) 

                {

                        _container = container;

                        init();

                }

 

                private function init():void

                {

                        _container.addChild(_viewer);

                        _viewer.addEventListener(MouseEvent.CLICK, onViewerClick);

 

                }

 

                private function onViewerClick(e:MouseEvent):void 

                {

                        _model.change(Math.random() * 400, Math.random() * 400);

                }

 

 

        }

 

}

Модель:

Код AS3:

package  

{

        import flash.events.Event;

        import flash.events.EventDispatcher;

        import flash.events.IEventDispatcher;

 

        public class Model extends EventDispatcher

        {

 

                //no getters/setters, just example

                public var x:Number = 0;

                public var y:Number = 0;

 

                public function Model() 

                {

                        super(null);

 

                }

 

                public function change(x:Number, y:Number):void {

                        this.x = x;

                        this.y = y;

                        super.dispatchEvent(new Event(Event.CHANGE));

                }

 

        }

 

}

Вьюшка:

Код AS3:

package  

{

        import flash.display.Sprite;

        import flash.events.Event;

        import flash.events.MouseEvent;

 

        public class Viewer extends Sprite

        {

                private var _model:Model;

                public function Viewer(model:Model) 

                {

                        super();

                        _model = model;

                        init();

                }

 

                private function init():void

                {

                        var someSprite:Sprite = new Sprite();

                        someSprite.graphics.beginFill(0);

                        someSprite.graphics.drawCircle(0, 0, 50);

                        someSprite.graphics.endFill();

                        super.addChild(someSprite);

                        someSprite.addEventListener(MouseEvent.CLICK, super.dispatchEvent);

 

                        _model.addEventListener(Event.CHANGE, onModelChange);

                }

 

                private function onModelChange(e:Event):void 

                {

                        super.x = _model.x;

                        super.y = _model.y;

                }

 

 

 

                public function get model():Model { return _model; }

 

                public function set model(value:Model):void 

                {

                        _model = value;

                }

        }

 

}

И серия вопросов вновь :) Спасибо, что помогаешь.
1) Вот классы выше - теперь это правильное MVC?
2) Да, действительно - вьюшка может менять что нибудь у модели и контроллер сойдёт с ума - получается, у этой триады даже пиша вьюшку надо быть аккуратным, потому что можешь всё сломать?
3) А кто от кого наследуется? Я так понимаю: controller -> Object, model - EventDispatcher, viewer - DisplayObject. Так?
4) Модельку передавать в конструктор вьюшки это хорошая практика, или всё таки лучше через сеттер? (вопрос граничит с бредом, знаю :D)
5) На той же википедии и на некоторых других сайтах пишут, что контроллер - лишь связующее, а вся бизнес логика в модели. Они не правы или с флешем тонкость какая?
6) Склоняюсь к мнению, что чистый MVC не в гигантских проектах нафиг не нужен, хотя мне нравится идея о MC + V. Такое существует вообще, контроллер с интегрированой моделью? Если да, то как там поступаем? Если контроллер уже имеет прямую ссылку на вьюшку, а в нём же интегрированна модель - то смысла в событии нет, можно отправлять напрямую или же ради сохранения полиморфизма и перехода после к чистой MVC следует остановится на событиях?

cpu	06.04.2010 17:38

ФЛУД.
На днях пришла по почте "Приемы объектно-ориентированного проектирования. Паттерны проектирования" этих четырех авторов.
Там вроде написано про MVC, вечерком почитаю, отпишусь что они знают про MVC, люди вроде умные, из университетов)).

mexoboy

06.04.2010 17:40

cpu, неужто открыл для себя книгу "Банды четырех"?

cpu	06.04.2010 17:48

mexoboy пора когда-то это делать.)

Котяра

06.04.2010 17:52

Цитата:

Сообщение от Psycho Tiger (Сообщение 898413)

2) Да, действительно - вьюшка может менять что нибудь у модели и контроллер сойдёт с ума - получается, у этой триады даже пиша вьюшку надо быть аккуратным, потому что можешь всё сломать?

передавать в вид только IModel в котором, например,есть один только метод addChangeModelEventListener
сломать конечно можно но это будет уже очень явно.

Psycho Tiger

06.04.2010 17:59

Цитата:

Сообщение от Котяра (Сообщение 898438)

Конечно, сломать можно всё делая это специально - когда говорил "сломать" подразумевалось конечно же "ненароком менял вьюшку, а полетела всё остальное".
С этим появляется ещё 2 вопроса:
7) Насколько это хорошая практика - делать по 40 разных событий для 40 изменений - то есть, если изменился угол поворота чей нибудь - не обновлять положение в пространстве, а лишь повернуть (то есть разбиение например updatePositionEvent на updateXYPositionEvent и updateRotationEvent)
8) Если передается только интерфейс, тогда вся инфа об обновлении должна поступить вместе с Event`ом, а не через геттеры от модели о нужной информации?

mexoboy

06.04.2010 18:22

Цитата:

Сообщение от etc (Сообщение 898387)

etc, ты ничего не путаешь? Представление и модель не должна иметь никаких связей (если мы говорим об оригинальном потерне MVC). Весь обмен данными идет через контроллер. В зависимости от типа модели (к примеру тонкой), контроллер может взять на себя роль прокси между моделью и представлением и обратно. Вся инициализация эвентов, логики, моделей - должна происходить в контроллере.

cpu	06.04.2010 18:50

mexoboy +1

dimarik

06.04.2010 23:43

Цитата:

Сообщение от Ariel (Сообщение 898310)

Привет! Ваш пост номер 13 и Вы выиграли поездку в кАННЫ на очередной фестиваль КО)
По сути. ТОЧНО есть точно.

Добавлено через 8 минут

Цитата:

Сообщение от cpu (Сообщение 898376)

1. View не имеет ссылок никуда, только рассылает события в контроллер

Просто рассылает события. Когда Вы кричите "Пожар!!", адресуете любому слышащему.

Добавлено через 10 минут

Цитата:

Сообщение от Котяра (Сообщение 898317)

А вообще я последнее время сильно охладел к MVC - как к универсальному решению) выхожу из стадии abstraction freek)

Для тебя уже поздно ) Ты заражён MVC.

Добавлено через 14 минут

Цитата:

Сообщение от Psycho Tiger (Сообщение 898413)

А мы дадим ей только читать )

Psycho Tiger

07.04.2010 00:01

Цитата:

А мы дадим ей только читать )

Ну да, спасибо, это один из самых малозначимых вопросов на данный момент =)

Подписываюсь к вопросу о том, что нужно ли вьюшке иметь ссылку на модель и если нет - как получать данные об обновлении.

dimarik

07.04.2010 00:02

Цитата:

Сообщение от mexoboy (Сообщение 898448)

etc, ты ничего не путаешь? Представление и модель не должна иметь никаких связей (если мы говорим об оригинальном потерне MVC).

Расскажите нам об оригинальном паттерне, пожалуйста.

Добавлено через 44 секунды

Цитата:

Сообщение от Psycho Tiger (Сообщение 898521)

Одназначна (с).

Ariel

07.04.2010 00:15

Гр-н Димарик реально радует своими ч0ткими и однозначными ответами.
P.S. Поездку в Канны присылайте пожалуйста по электрической почте.

Котяра

07.04.2010 09:56

Цитата:

Сообщение от Psycho Tiger (Сообщение 898442)

вот эти вопросы самые сложные ( во всяком случае для меня)
в своеё реализации mvc я диспатчил события для изменения любого отдельного свойства
подписывался также.
вот пример из рабочего проекта ( as2)

Код AS1/AS2:

class ru.k0t0vich.mvc.models.Model extends EventDispatcher

{

 

        public function Model(eventParentLink) 

        {

                eventParent = eventParentLink;

        }

 

        /**

         *  Диспатчим событие об изменении структуры

         * @param        field - имя поля (должно присутьствовать в  классе, иначе генерируется ошибка времени выполнения)

         */

        public function update(field:String):Void

        {

                if (field == undefined) field = "";

                var event: ModelEvent= new ModelEvent(ModelEvent.CHANGE+field);

                // Проверка на доступность свойства

                if (field != "")

                {

                        try

                        {

                        event.field = this[field];

                        }

                        catch (e:Error)

                        {

                                trace (e);

                        }

                        dispatchEvent(event);

                }

                else

                {

                        event.field = this;

                        dispatchEvent(event);

                }

 

 

        }

 

}

подписка во вью:

Код AS1/AS2:

                public function addChangeModelFieldListener(field:String,listener:Function,scope:Object):Void

                {

                        _model.addEventListener(ModelEvent.CHANGE + field, listener,scope);

                        // регистрируем для отписки от ВСЕХ событий модели

                        _modelFieldEventListenersArray.push( { event:ModelEvent.CHANGE + field, listener:listener,scope:scope } );

                }

пример подписки:

Код AS1/AS2:

        /**

         * Инициализацие хэндлеров изменения модели

         */

        private function initModelListeners()

        {

                addChangeModelFieldListener(SlotModelField.LINES, showLinesByModel, this);

                addChangeModelFieldListener(SlotModelField.FREESPINS, updateFreespinsCounter, this);

                addChangeModelFieldListener(SlotModelField.WIN, updateFreespinsCounter, this);

        }

косяков в такой реализации много ( нет строгой типизации итп) но многое лечится вводом класса констант SlotModelField. доступ к геттерам модели у меня кстати тоже так сделан,

Код AS1/AS2:

private function updateFreespinsCounter(e:ModelEvent):Void

        {

                freespinsCounterWindow.freespins = model[SlotModelField.FREESPINS];

                freespinsCounterWindow.cash = model[SlotModelField.WIN];

        }

хотя можно сделать в IModel геттеры этих свойств - я не сделал т.к. при добавлении публичных обновляемых свойств в модели пришлось бы редактировать уже 3 класса ( Model, ModelField и IModel) а не 2 (Model, ModelField)

модель обновляется таким образом:

Код AS1/AS2:

        public function get totalBet():Number { return _totalBet; }

 

        public function set totalBet(value:Number):Void 

        {

                _totalBet = value;                

                update(SlotModelField.TOTAL_BET);

        }

В общем практика показала относительное удобство такого подхода..
хотя могло бы быть и лучше..

PS: основная "неправильность" моего подхода была в методе update который создаёт эвент с динамическим типом field. Практика показала, что на самом деле это поле практически не используется при слушании событий, т.к. у вида есть ссылка на нужный геттер и он может его просмотреть самостоятельно, а не в качестве свойства события..
так-что можно смело переписать метод update так:

Код AS3:

         public function update(field:String):Void

        {

                if (field == undefined) field = "";

                var event: ModelEvent= new ModelEvent(ModelEvent.CHANGE+field);

                dispatchEvent(event);

 

        }

etc	07.04.2010 10:14

Цитата:

Сообщение от cpu (Сообщение 898394)

Но ведь тогда view может напрямую менять данные в модели обойдя controller

Может, только это не в его компетенции.

Цитата:

Сообщение от cpu (Сообщение 898394)

Так как View имеет ссылку на модель, он может получит по этому событию данные из model для отображения, обойдя contoller(который опять неудел.)

Ещё раз: может ещё не означает, что так и должен делать. Вы можете дома открыть газ в плите и зажечь спичку через пару-тройку минут, но почему-то этого не делаете.

mexoboy

07.04.2010 10:21

Цитата:

Сообщение от dimarik (Сообщение 898523)

Расскажите нам об оригинальном паттерне, пожалуйста.

Тут собственно все описано: http://www.books.ru/shop/books/352130

Часовой пояс GMT +4, время: 00:41.

Страница 1 из 16

Показывать 40 сообщений этой темы на одной странице

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.