Форум Flasher.ru - Выходные параметры класса

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 1.0/2.0 (http://www.flasher.ru/forum/forumdisplay.php?f=93)

- - Выходные параметры класса (http://www.flasher.ru/forum/showthread.php?t=123588)

Выходные параметры класса

Доброго времени суток. Ситуация следующая. Имеется пользовательский класс PicsLoader. Наверное зря все обработчики событий засунул, скорее всего внимание обращать надо только на onLoadInit.

Код AS1/AS2:

import flash.display.BitmapData;

class PicsLoader {

//объявляем переменные

        private var loader:MovieClipLoader;

        private var tmpMC:MovieClip;

        private var totalNum:Number;

        private var startedNum:Number;

        private var bmps:Array;

        private var totalBytes:Number;

        private var loadedBytesArr:Array;

        private var broadcastMessage:Function;

        public var addListener:Function;

//конструктор

        public function PicsLoader() {

                AsBroadcaster.initialize(this);

                loader = new MovieClipLoader();

                loader.addListener(this);

        }

//функция класса

        public function load(urls:Array, bmpArr:Array, containerName:String):Void {

                bmps = bmpArr;

                totalBytes = 0;

                loadedBytesArr = [];

                startedNum = 0;

                tmpMC = _root.createEmptyMovieClip(containerName, _root.getNextHighestDepth());

                totalNum = urls.length;

                for (var i = 0; i<totalNum; i++) {

                        loadedBytesArr.push(0);

                        loader.loadClip(urls[i], tmpMC.createEmptyMovieClip(String(i), i));

                }

        }

//дальше, как я понимаю, идут обработчики событий

        public function getProgress():Number {

                for (var i = 0, l = 0; i<loadedBytesArr.length; i++) {

                        l += loadedBytesArr[i];

                }

                return (startedNum>=totalNum) ? l/totalBytes : 0;

        }

        private function onLoadStart(mc):Void {

                totalBytes += loader.getProgress(mc).bytesTotal;

                startedNum++;

        }

        private function onLoadProgress(mc:MovieClip, l:Number):Void {

                loadedBytesArr[Number(mc._name)] = l;

        }

        private function onLoadInit(mc:MovieClip):Void {

                var bmp:BitmapData = new BitmapData(mc._width, mc._height);

                bmp.draw(mc);

                bmps[mc._name] = bmp;

                mc.removeMovieClip();

                checkEnd();

        }

        private function onLoadError(mc):Void {

                bmps[mc._name] = null;

                broadcastMessage("onPicLoadError", mc._name);

                mc.removeMovieClip();

                checkEnd();

        }

        private function checkEnd():Void {

                if (!(--totalNum)) {

                        broadcastMessage("onPicsLoaded");

                        tmpMC.removeMovieClip();

                }

        }

}

В FLA-файле производятся следующие действия

Код AS1/AS2:

var clipPath_mc = this;

var picsLoader:PicsLoader = new PicsLoader(); //создаём новый объект класса

picsLoader.addListener(this);

function onPicsLoaded() {

        trace(clipPath_mc.picArr[0]);//выводит Object [Object]

}

clipPath_mc.picUrlArr = [];//здесь сидят 2 ссылки на файлы JPEG (пути к ним)

clipPath_mc.picArr = []; //просто пустой массив

picsLoader.load(clipPath_mc.picUrlArr,clipPath_mc.picArr,"techPics");//вызов функции, определенной в пользовательском классе

trace(clipPath_mc.picArr[0]);//выводит undefined

Вдоль и поперёк изучил код класса, но похоже я недопонимаю базовых принципов (по крайней мере я так думаю). Я не могу никак понять, каким образом у нас назначаются данные в clipPath_mc.picArr. Ближе к сути:
1. В onLoadInit у нас создаётся bmp.draw(mc); Куда рисуется этот растр? 0_о Или у нас просто поверх нашего созданного объекта рисуется источник mc, но объект нигде не отображается?
2.(!(--totalNum)) Что это за 2 тире используется?
3. Каким образом этот класс назначает(передаёт) данные в массив clipPath_mc.picArr??? Вот это главная для меня загадка. Методом тыка убивал в onLoadInit строчку bmps[mc._name] = bmp; и оба раза trace выдавали undefined. (но это обстоятельство помогло мне только взяться за этот пост:quiet:)

1. В массив bmps
2. Это не тире, а два минуса (декремент), уменьшает значение числовой переменной на 1. Если стоит перед переменной, то сначала происходит уменьшение значение, а потом использование (если такое). Если после, то наоборот.
3. При вызове конструктора, вы передаете ссылку на picArr вторым параметром. В конструкторе эта ссылка приходит как bmpArr, и в первой же строчке присваивается переменно bmps.

Цитата:

Сообщение от iNils (Сообщение 811076)

Спасибо за ответ. Предположим со вторым пунктом я тупанул очень сильно (редко встречал операцию декремента, ещё чтобы и в начале вычиталась единица...) С первым тоже определился (то, что результат bmp.draw присваевается bmps я понял раньше, просто недопонимал результат работы именно функции draw.)
Но вот третий вопрос остался тайной. По идее в самом конструкторе у меня создаётся объект MCL и он же регистрируется как приёмник. Дальше в FLA-документе вызывается метод load, которому и передаётся picArr, значения которого в свою очередь присваиваются bmpArr. Это всё верно. Я не пойму на каком этапе объекты, сидящие в bmps вдруг становятся доступны в FLA-документе, да ещё и в массиве picArr!! bmps у нас объявлен в пределах класса, в самом классе picArr никак не переопределяется... Но оно работает, вот в чём загвоздка.:wacko:

Вот, пример добавил. Ещё такой вопрос возник. В рез-те загрузки у нас формируется сообщение

Код AS1/AS2:

broadcastMessage("onPicsLoaded");

Источник мы не указываем. Точно также как в теле программы мы не указываем приёмника.

Код AS1/AS2:

function onPicsLoaded() {

        trace(clipPath_mc.picArr[0]);//выводит Object [Object]

}

В итоге кем посылается событие и кем принимается? 0_о

На один и тот же объект может ввести множество ссылок с разными названиями. В класс вы передали ссылку на массив который был объявлен в fla, класс с ним и работает, но у ссылки просто другое имя.
Пример

Код AS1/AS2:

a = [0, 1, 2, 3];

b = a;

c = b;

trace (a)

trace (b)

trace (c)

a[0] = 1000

trace (a)

trace (b)

trace (c)

c[1] = 2000

trace (a)

trace (b)

trace (c)

Ого :eek:
Я привык, что присвоив переменной b значение a, мы его копируем, а не привязываем ссылкой...
А сейчас прочитал, что в AS вообще все переменные - это ссылки.)) Спасибо огромное за ответ. Так бы не разобрался.
Можно ещё вопрос для закрепления знаний?
Если в примере использовать строковый тип данных или числовой, то изменив переменную b, мы не поменяем переменные а и с. Это потому что, у таких объектов мы не можем менять свойства, поэтому создаётся новый "примитивный" объект?

Да. Примитивные типы (числа, строки и булевы) копируются, а объекты передают ссылки.

Ещё раз спасибо за разъяснения.