Почему события мыши шлются за пределы получателя

[rumgot]

Приведенный ниже код работает аналогично карандашу из Paint.
Вопрос следующий
Как я понимаю переменная stage представлена на экране закрашенным прямоугольником.
Стока stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseListner); регистрирует приемник для событий мыши именно для этой переменной. Тогда почему рисование происходит и за пределами прямоугольника?

package 
{ 
	import flash.display.*;
	import flash.events.*;
 
	public class graf extends Sprite 
	{ 
		public function graf () 
		{ 
			var xx,yy :uint;
 
			xx=this.stage.stageWidth;
			yy=this.stage.stageHeight;
			this.stage.scaleMode=StageScaleMode.SHOW_ALL;
			this.graphics.lineStyle(1, 0xAAAAAA);
			this.graphics.beginFill(0xf0f0f0, 1);
			this.graphics.drawRect(0, 0, xx, yy); 
			this.graphics.endFill();
 
			this.stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseReg);
			this.stage.addEventListener(MouseEvent.MOUSE_UP, mouseUnreg);
		}
 
		public function mouseListner(e:flash.events.MouseEvent):void
		{
			this.graphics.lineTo(e.stageX, e.stageY);
		}
 
		public function mouseReg(e:flash.events.MouseEvent):void
		{
			this.graphics.moveTo(e.stageX, e.stageY);
			this.stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseListner);
		}
 
		public function mouseUnreg(e:flash.events.MouseEvent):void
		{
			this.stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseListner);
		}
 
	}
}

[samana]

Но вообще-то stage- это как бы ссылка на вашу сцену, а сцена везде, даже за пределом некого прямоугольника.

[iNils]

stage из MOUSE_DOWN и MOUSE_MOVE убрать (в MOUSE_UP оставить) и тогда событие будет генерироваться только внутри graf (кстати, класс пишутся с большой буквы).

[rumgot]

stage из MOUSE_DOWN и MOUSE_MOVE убрать (в MOUSE_UP оставить) и тогда событие будет генерироваться только внутри graf

Убрал - события перестали обрабатываться вообще. Нет никакой реакции на перемещение и клики мышью.

[iNils]

package { 
	import flash.display.*;
	import flash.events.*;
	public class Graf extends Sprite {
		private var _s:Sprite = null;
		public function Graf () { 
			var xx:uint
			var yy:uint;
 
			xx = stage.stageWidth;
			yy = stage.stageHeight;
 
			stage.scaleMode = StageScaleMode.SHOW_ALL;
			_s = new Sprite ();
			addChild (_s);
 
			_s.graphics.lineStyle (1, 0xAAAAAA);
			_s.graphics.beginFill (0xf0f0f0, 1);
			_s.graphics.drawRect (0, 0, xx, yy); 
			_s.graphics.endFill ();
 
			_s.addEventListener (MouseEvent.MOUSE_DOWN, mouseReg);
			stage.addEventListener (MouseEvent.MOUSE_UP, mouseUnreg);
		}
		public function mouseListner (event:MouseEvent):void {
			_s.graphics.lineTo (mouseX, mouseY);
		}
		public function mouseReg (event:MouseEvent):void {
			_s.graphics.moveTo (mouseX, mouseY);
			_s.addEventListener (MouseEvent.MOUSE_MOVE, mouseListner);
		}
		public function mouseUnreg (event:MouseEvent):void {
			_s.removeEventListener (MouseEvent.MOUSE_MOVE, mouseListner);
		}
	}
}

[samana]

У вас этот класс, показан как Document Class. Если вы хотите сделать из него отдельный класс, который можно добавить в Document Class, то добавьте в него событие - ADDED_TO_STAGE и как уже подсказал iNils убрать stage. В общем измените класс на:

package 
{ 
	import flash.display.*;
	import flash.events.*;
 
	public class Graf extends Sprite 
	{ 
		public function Graf () 
		{ 
			addEventListener(Event.ADDED_TO_STAGE, added);
		}
 
		private function added(e:Event):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, added);
			//.....................
			var xx:uint;
			var yy:uint;
 
			xx=this.stage.stageWidth;
			yy=this.stage.stageHeight;
			this.stage.scaleMode=StageScaleMode.SHOW_ALL;
			this.graphics.lineStyle(1, 0xAAAAAA);
			this.graphics.beginFill(0xf0f0f0, 1);
			this.graphics.drawRect(0, 0, xx, yy); 
			this.graphics.endFill();
 
			this.addEventListener(MouseEvent.MOUSE_DOWN, mouseReg);
			this.stage.addEventListener(MouseEvent.MOUSE_UP, mouseUnreg);
		}
 
		public function mouseListner(e:flash.events.MouseEvent):void
		{
			this.graphics.lineTo(e.stageX, e.stageY);
		}
 
		public function mouseReg(e:flash.events.MouseEvent):void
		{
			this.graphics.moveTo(e.stageX, e.stageY);
			this.addEventListener(MouseEvent.MOUSE_MOVE, mouseListner);
		}
 
		public function mouseUnreg(e:flash.events.MouseEvent):void
		{
			this.removeEventListener(MouseEvent.MOUSE_MOVE, mouseListner);
		}
 
	}
}

Соответственно в Main классе, просто:

var graf:Graf = new Graf();
addChild(graf)