Как узнать браузер?

[bav]

Что именно написано в ошибке #2060? Вот рабочий код:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.external.ExternalInterface;
 
    public class TestProject extends Sprite 
    {
        private const MARGIN:int = 5;
        private var field:TextField;
 
        public function TestProject():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
 
        private function init(event:Event = null):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
 
            field = new TextField();
            addChild(field);
            field.width = stage.stageWidth - MARGIN * 2;
            field.defaultTextFormat = new TextFormat("_typewriter");
 
            if (ExternalInterface.available) {
                var browser:String = ExternalInterface.call("function() { return navigator.appName; }");
                field.text = browser;
            }
            else
                field.text = "ExternalInterface is not available.";
        }
    }
}